[Resolvido]Consulta a tabela no sql server

bom dia pessoal, mais uma vez estou a precisar de uma forçados companheiro do fórum.
meu problema é o seguinte:

tenho um formulário onde uso um listebox para para filtra os registro, esse liste box carrega os registro de uma tabela do sql server estou usando o código abaixo para quando clicar no registro desejado no listebox ele carregue os dados nas textebox mas o código esta me apresentando o seguinte erro:

"Erro em tempo de execução '3622':

Você deve utilizar a opção dbSeeChanges com OpenRecordset
ao acessa uma tabela SQLServer que possua uma Coluna IDENTITY."

o erro aponta para seguinte linha:

Set rs = db.OpenRecordset(strSQL)

Código:

Sub ListBox()
    Dim db As DAO.Database
    Dim rs As DAO.Recordset
    Dim strSQL As String
    Dim Linha As Integer
Linha = Me.lstFuncionarios.ListIndex + 0
Me.txtCodFuncionario = Me.lstFuncionarios.Column(0, Linha)
'On Error Resume Next
Me.txtCodFuncionario.Requery


    txtPesquisa.SetFocus
    If txtCodFuncionario.Value > 0 Then
        strSQL = "SELECT * FROM CFuncionario WHERE codFuncionario = '" & txtCodFuncionario.Value & "'"
   
        Set db = CurrentDb
        Set rs = db.OpenRecordset(strSQL)
        If Not rs.BOF Then
            Me.txtCargo = rs("cargo")
            Me.txtloja = rs("loja")
            Me.txtNomeFuncionario = rs("nomeFuncionario")
            Me.txtApelido = rs("apelido")
            Me.txtCpf = rs("cpf")
            Me.txtRg = rs("rg")
            Me.txtEndereco = rs("endereco")
            Me.txtNumero = rs("numero")
            Me.txtCep = rs("cep")
            Me.txtBairro = rs("bairro")
            Me.txtComplemento = rs("complemento")
            Me.txtCidade = rs("cidade")
            Me.txtUf = rs("uf")
            Me.txtDdd01 = rs("ddd01")
            Me.txtPrefixo01 = rs("prefixo01")
            Me.txtNumero01 = rs("numero01")
            Me.txtEmail = rs("email")
            Me.txtDataCadastro = rs("dataCadastro")
            Me.txtDataNascimento = rs("dataNascimento")
            Me.txtStatusFuncionario = rs("statusFuncionario")
        End If
        rs.Close
        Set rs = Nothing
        db.Close
        Set db = Nothing
    End If
    Me.txtPesquisa.SetFocus
End Sub

Set rs = db.OpenRecordset(strSQL, dbOpenDynaset, dbSeeChanges)

Caro amigo jpaulo, já tinha feito essa alteração mas não deu certo, ele me depurou o seguinte erro:
Ateração:

Código:

Set rs = db.OpenRecordset(strSQL, dbOpenDynaset, dbSeeChanges)

Erro em tempo de execução '3464':
Tipos de dados incompatíveis na expressão de critério.

Também já fiz essa outra e me depurou um outro erro:

Ateração:

Código:

Set rs = db.OpenRecordset("strSQL", dbOpenDynaset, dbSeeChanges)

Erro em tempo de execução '3464':

O mecanismo do banco de dados do Microsoft Ofice Access
não encontro a tabela de entrada ou consulta 'strSQL'.
Verifique se ela existe e se seu nome está digitado corretamente.

E nessa outra situação ele só exibe o primeiro registro da tabela:

Ateração:

Código:

Set rs = db.OpenRecordset("CFuncionario", dbOpenDynaset, dbSeeChanges)

Após testar todas essas alteração realizada, ainda assim não funcionou.

Faça o teste direto no Open;

Set rs = db.OpenRecordset("SELECT * FROM CFuncionario WHERE codFuncionario = '" & txtCodFuncionario.Value & "'", dbOpenDynaset, dbSeeChanges)

....................................................................................................................................

Microsoft:

Ao trabalhar com um banco de dados Microsoft Access usando tabelas vinculadas do Microsoft SQL Server, você pode receber a seguinte mensagem de erro:

You must use the dbSeeChanges option with OpenRecordSet when accessing a SQL Server table that has an IDENTITY column.

Solution: Set rst = CurrentDb.OpenRecordset("SELECT * From tblName", dbOpenDynaset, dbSeeChanges)

amigo jpaulo fiz a alteração que me indicou, e agora me retornou o seguinte erro:

Erro em tempo de execução '3464':

Tipo de dados incompatíveis na expressão de critério.

Provavelmente porque codFuncionario é numerico e não texto, se for numerico tem de retirar as aspas simples.

Meu grande amigo jpaulo, antes de mais nada queria muito lhe agradecer pela pela grande ajuda prestada, pois sem sua força de vontade em me ajuda, seria quase impossível resolver o mesmo. Emfim sou muito grato por tudo.

Depois da correção o código funcional fico assim:

Código:

Set rs = db.OpenRecordset("SELECT * FROM CFuncionario WHERE codFuncionario=" & Me.txtCodFuncionario, dbOpenDynaset, dbSeeChanges)

.

fica a dica para futuras duvidas, e mais uma vez muito obrigado amigo jpaulo.

Obrigado pelo retorno o forum agradece.