[Resolvido]Dúvida ao executar função de vinculo

Boa noite, Mestre.

Estou novamente precisando da estimada ajuda dos amigos.
Estou tentando verificar o vinculo das tabelas de um back-end, após muitas consultas/pesquisa consegui localizar o código abaixo, criado pelo Mestre JPaulo, testei e atende as minhas necessidades, contudo não estou conseguindo fazer com que se td os vincuilos estiverem ok, que o formulário de login seja aberto e se ocorrer algum erro no vinculo, que o formulário de vinculo seja aberto para que o usuário informe o caminho do back-end.
Desde já agradeço a grande ajuda que os senhores tem prestado a todos os membros desse fórum.

Código:

Option Compare Database

Public Function VerificaTabelaVinculada()
'By JPaulo ® Maximo Access 2009
    On Error GoTo Err_VerificaTabelaVinculada
    Const conTabela As String = "tb_Usuario"

'A tabela vinculada terá um string de ligação cujo comprimento tem de ser > 0
    If Len(CurrentDb.TableDefs(conTabela).Connect) > 0 Then

'Sabemos que conTabela é uma tabela vinculada, mas será o vinculo é válido?
'A próxima linha de código irá gerar erros 3011 ou 3024, se não for valido"

        CurrentDb.TableDefs(conTabela).RefreshLink
'Se você chegar a este ponto, é porque você tem a tabela válida e vinculada.
    Else
'Se o comprimento da string de ligação for zero (0) então devolve a mensagem.
        MsgBox "*" & conTabela & "* é uma tabela normal, sem vinculo.", vbCritical, "Erro"
    End If

Exit_VerificaTabelaVinculada:
    Exit Function

Err_VerificaTabelaVinculada:
    Select Case Err.Number
        Case 3265
            MsgBox "*" & conTabela & "* não existe.", vbCritical, "Erro"
        Case 3011, 3024    'Tabela ligada não existe neste diretorio.
            MsgBox "*" & conTabela & "* tabela ligada não é valida.", vbCritical, "Erro"
        Case Else
            MsgBox Err.Description & Err.Number, vbExclamation, "Erro na função VerificaTabelaVinculada."
        End Select
   Resume Exit_VerificaTabelaVinculada
End Function


Assim;

Código:

Public Function VerificaTabelaVinculada()
'By JPaulo ® Maximo Access 2009
    On Error GoTo Err_VerificaTabelaVinculada
    Const conTabela As String = "tb_Usuario"

'A tabela vinculada terá um string de ligação cujo comprimento tem de ser > 0
    If Len(CurrentDb.TableDefs(conTabela).Connect) > 0 Then

'Sabemos que conTabela é uma tabela vinculada, mas será o vinculo é válido?
'A próxima linha de código irá gerar erros 3011 ou 3024, se não for valido"

        CurrentDb.TableDefs(conTabela).RefreshLink
'Se você chegar a este ponto, é porque você tem a tabela válida e vinculada.
    DoCmd.OpenForm "SeuFormLogin"
    Else
'Se o comprimento da string de ligação for zero (0) então devolve a mensagem.
        MsgBox "*" & conTabela & "* é uma tabela normal, sem vinculo.", vbCritical, "Erro"
    End If

Exit_VerificaTabelaVinculada:
    Exit Function

Err_VerificaTabelaVinculada:
    Select Case Err.Number
        Case 3265
            MsgBox "*" & conTabela & "* não existe.", vbCritical, "Erro"
                DoCmd.OpenForm "SeuFormNovoVinculo"
        Case 3011, 3024    'Tabela ligada não existe neste diretorio.
            MsgBox "*" & conTabela & "* tabela ligada não é valida.", vbCritical, "Erro"
                DoCmd.OpenForm "SeuFormNovoVinculo"
        Case Else
            MsgBox Err.Description & Err.Number, vbExclamation, "Erro na função VerificaTabelaVinculada."
        End Select
   Resume Exit_VerificaTabelaVinculada
End Function

Bom dia, Mestre JPaulo.

Até ai eu entendi, mais como eu declaro para que a função seja executada no momento em que o DB é inicializado para que esse teste seja realizado?
Já tentei fazer uma macro AutoExec, porém não sei que valor tenho que colocar.
Me desculpe pela ignorância, mas é que estou engatinhando no VBA do Accesss.
Desde já agradeço a valiosa ajuda prestada.

Consegui colocar o código para executar, apenas criando uma macro AutoExec, definindo para executar o código.
Agradeço a atenção de tds principalmente ao mestre JPaulo.

Fico feliz.

Obrigado pelo retorno o forum agradece.