[Resolvido]Transferir valores combobox para SQL

Boa tarde amigos, Estou fazendo um VBA para atualizar valores da tabela através de dos valores selecionados em uma combobox, mas ele nao está reconhecendo o valor dos IDs e não consigo identificar o problema.

O combobox está ilustrado no anexo 1.

E aqui o VBA:

Código:

Option Compare Database

Private Sub btnSalvarEntrega_Click()

 Dim ctlSource As control
 Dim strItem As Integer
 Dim strItems As String
 Dim intCurrentRow As Integer
 Dim valorCheques As Currency
 Dim strSql As String
 Dim strParm As String
 
 Set ctlSource = Me.lstCheques
 
 If MsgBox("Tem certeza que deseja incluir os cheques selecionados na relação de entrega?", vbYesNo, "Confirmar Entrega") = vbYes Then
 
 strSql = "UPDATE tbl_cadCheques SET tbl_cadCheques.StatusCheque = 2 WHERE (tbl_cadCheques.ID_CadCheques) =" & strItem
 
 For intCurrentRow = 0 To ctlSource.ListCount - 1
 If ctlSource.Selected(intCurrentRow) Then
 strItem = CInt(ctlSource.Column(0, intCurrentRow))
 strItems = strItems & ctlSource.Column(0, _
 intCurrentRow) & ";"
 valorCheques = valorCheques + ctlSource.Column(2, intCurrentRow)
 DoCmd.RunSQL strSql
 End If
 Next intCurrentRow
 
 Me.txtValor = valorCheques
 
 End If
 
 MsgBox "Os cheques " & strItems & " no valor total de " & Format(valorCheques, "Currency") & " foram processados.", vbInformation, "Processo concluído com sucesso!"
 
 Set ctlSource = Nothing

End Sub

Ao rodar o VBA recebo uma mensagem que nenhuma linha será afetada. Testei o codigo digitando os ID direto no VBA e dessa forma ele encontra linhas para atualizar.

Agradeço a ajuda!

Amigo, coloca uma msgbox antes do Update...
Msgbox StrItem

Veja se estao correto os dados, pois acredito quando o update e executado a variavel c Numero do Cheque ainda nao tem Valor algum...


Veja tambem nesse exemplo que fiz, para relatorio, porem o principio e o mesmo...
https://www.maximoaccess.com/t26544-imprimir-itens-selecionados-em-caixa-de-listagem-ou-digitados-em-caixa-de-texto

Veja e adapte pro seu update...

Alterei o código, colocando a instrução depois do strItem e funcionou!

Obrigado!!! coloco o código se alguém precisar:

Código:

Private Sub btnSalvarEntrega_Click()

 Dim ctlSource As control
 Dim strItem As Integer
 Dim strItems As String
 Dim intCurrentRow As Integer
 Dim valorCheques As Currency
 Dim strSql As String
 Dim strParm As String
 
 Set ctlSource = Me.lstCheques
 
 If MsgBox("Tem certeza que deseja incluir os cheques selecionados na relação de entrega?", vbYesNo, "Confirmar Entrega") = vbYes Then
 
 
 
 For intCurrentRow = 0 To ctlSource.ListCount - 1
 If ctlSource.Selected(intCurrentRow) Then
 strItem = CInt(ctlSource.Column(0, intCurrentRow))
 strItems = strItems & ctlSource.Column(0, _
 intCurrentRow) & ";"
 valorCheques = valorCheques + ctlSource.Column(2, intCurrentRow)
 strSql = "UPDATE tbl_cadCheques SET tbl_cadCheques.StatusCheque = 2 WHERE (tbl_cadCheques.ID_CadCheques) =" & strItem
 DoCmd.RunSQL strSql
 End If
 Next intCurrentRow
 
 Me.txtValor = valorCheques
 
 End If
 
 MsgBox "Os cheques " & strItems & " no valor total de " & Format(valorCheques, "Currency") & " foram processados.", vbInformation, "Processo concluído com sucesso!"
 
 Set ctlSource = Nothing

End Sub

Bacana meu amigo, ate a proxima se Deus quiser...

Nao esqueca de marcar o topico como resolvido...

Beleza! Até a próxima!!