MaximoAccess

Caro Usuário, antes de postar pela primeira vez, leia as regras do fórum.

https://www.maximoaccess.com/t48-regras-do-forum

Obrigado

Administração


Participe do fórum, é rápido e fácil

MaximoAccess

Caro Usuário, antes de postar pela primeira vez, leia as regras do fórum.

https://www.maximoaccess.com/t48-regras-do-forum

Obrigado

Administração

MaximoAccess

Gostaria de reagir a esta mensagem? Crie uma conta em poucos cliques ou inicie sessão para continuar.

Dicas Ms Access, Exemplos Ms Access, Codigos VBA Ms Access, SQL Ms Access


3 participantes

    [Resolvido]Importar imagem para o access e converter formato

    avatar
    mm_edilson
    Novato
    Novato


    Respeito às regras : Respeito às Regras 100%

    Sexo : Masculino
    Localização : Brasil
    Mensagens : 7
    Registrado : 29/03/2012

    [Resolvido]Importar imagem para o access e converter formato Empty [Resolvido]Importar imagem para o access e converter formato

    Mensagem  mm_edilson 15/12/2017, 13:03

    Olá, amigos, estou fazendo um sisteminha em ACCESS, e estou com uma dúvida. Preciso selecionar uma imagem jpg, converter em bmp e inserir no campo tipo objeto ole da minha tabela.

    Tentei o código abaixo, mas não sei qual o comando colocar para fazer isso:

    Código:
    Private Sub Selecionar_Click()
    Call BrowsingWindow
    End Sub

    Sub BrowsingWindow()

    Dim Dlg As FileDialog
    Dim txtFilePath As String
    Dim varFile As Variant

    Set Dlg = Application.FileDialog(msoFileDialogFilePicker)
    With Dlg
    .Title = "Selecione uma imagem para salvar"
    .AllowMultiSelect = False
    If .Show = True Then

    For Each varFile In .SelectedItems
    txtFilePath = varFile
    Next

    'aqui preciso que a extensão da imagem selecionada seja renomeada de .jpg para .bmp e que seja inserida no campo IMG da tabela.

    Else
    Exit Sub
    End If
    End With

    End Sub
    Alvaro Teixeira
    Alvaro Teixeira
    Moderador Global
    Moderador Global


    Respeito às regras : Respeito às Regras 100%

    Sexo : Masculino
    Localização : Portugal
    Mensagens : 7914
    Registrado : 15/03/2013

    [Resolvido]Importar imagem para o access e converter formato Empty Re: [Resolvido]Importar imagem para o access e converter formato

    Mensagem  Alvaro Teixeira 16/12/2017, 14:55

    Olá Edilson Santiago,

    Veja se tópico abaixo ajuda na parte de arquivar OLE, veja o exemplo ImgensTabela2003pe.mdb
    https://www.maximoaccess.com/t23187-fotos-em-fomulario-continuo-access-2003

    Quanto a converter, veja links externos (copiar e colar no browser):
    devhut.net/2017/05/14/vba-wia-convert-the-image-format
    officeaccelerators.wordpress.com/2013/11/24/vba-code-to-convert-jpeg-file-to-bmp


    Abraço
    avatar
    Clebergyn
    Super Avançado
    Super Avançado


    Respeito às regras : Respeito às Regras 100%

    Sexo : Masculino
    Localização : Brasil
    Mensagens : 785
    Registrado : 29/08/2012

    [Resolvido]Importar imagem para o access e converter formato Empty Re: [Resolvido]Importar imagem para o access e converter formato

    Mensagem  Clebergyn 12/7/2022, 03:41

    Bom dia, so para contribuição mesmo, tentem este código abaixo, comigo funcionou

    Código:

    Public Enum wiaFormat
        BMP = 0
        GIF = 1
        JPEG = 2
        PNG = 3
        TIFF = 4
    End Enum
     
    '---------------------------------------------------------------------------------------
    ' Procedure : WIA_ConvertImage
    ' Author    : Daniel Pineault, CARDA Consultants Inc.
    ' Website  : http://www.cardaconsultants.com
    ' Purpose  : Convert an image's format using WIA
    ' Copyright : The following is release as Attribution-ShareAlike 4.0 International
    '            (CC BY-SA 4.0) - https://creativecommons.org/licenses/by-sa/4.0/
    ' Req'd Refs: Uses Late Binding, so none required
    '
    ' Windows Image Acquisition (WIA)
    '            https://msdn.microsoft.com/en-us/library/windows/desktop/ms630368(v=vs.85).aspx
    '
    ' Input Variables:
    ' ~~~~~~~~~~~~~~~~
    ' sInitialImage : Fully qualified path and filename of the original image to resize
    ' sOutputImage  : Fully qualified path and filename of where to save the new image
    ' lFormat      : Format to convert the image into
    ' lQuality      : Quality level to be used for the conversion process (1-100)
    '
    ' Usage:
    ' ~~~~~~
    ' Call WIA_ConvertImage("C:\Users\Public\Pictures\Sample Pictures\Chrysanthemum.jpg", _
    '                      "C:\Users\MyUser\Desktop\Chrysanthemum_2.jpg", _
    '                      JPEG)
    '
    ' Revision History:
    ' Rev      Date(yyyy/mm/dd)        Description
    ' **************************************************************************************
    ' 1        2017-01-18              Initial Release
    ' 2        2018-09-20              Updated Copyright
    '---------------------------------------------------------------------------------------
    Public Function WIA_ConvertImage(sInitialImage As String, _
                                    sOutputImage As String, _
                                    lFormat As wiaFormat, _
                                    Optional lQuality As Long = 85) As Boolean
        On Error GoTo Error_Handler
        Dim oWIA                  As Object    'WIA.ImageFile
        Dim oIP                  As Object    'ImageProcess
        Dim sFormatID            As String
        Dim sExt                  As String
     
        'Convert our Enum over to the proper value used by WIA
        Select Case lFormat
            Case 0
                sFormatID = "{B96B3CAB-0728-11D3-9D7B-0000F81EF32E}"
                sExt = "BMP"
            Case 1
                sFormatID = "{B96B3CB0-0728-11D3-9D7B-0000F81EF32E}"
                sExt = "GIF"
            Case 2
                sFormatID = "{B96B3CAE-0728-11D3-9D7B-0000F81EF32E}"
                sExt = "JPEG"
            Case 3
                sFormatID = "{B96B3CAF-0728-11D3-9D7B-0000F81EF32E}"
                sExt = "PNG"
            Case 4
                sFormatID = "{B96B3CB1-0728-11D3-9D7B-0000F81EF32E}"
                sExt = "TIFF"
        End Select
     
        If lQuality > 100 Then lQuality = 100
     
        'Should check if the output file already exists and if so,
        'prompt the user to overwrite it or not
     
        Set oWIA = CreateObject("WIA.ImageFile")
        Set oIP = CreateObject("WIA.ImageProcess")
     
        oIP.Filters.Add oIP.FilterInfos("Convert").FilterID
        oIP.Filters(1).Properties("FormatID") = sFormatID
        oIP.Filters(1).Properties("Quality") = lQuality
     
        oWIA.LoadFile sInitialImage
        Set oWIA = oIP.Apply(oWIA)
        'Overide the specified ext with the appropriate one for the choosen format
        oWIA.SaveFile Left(sOutputImage, InStrRev(sOutputImage, ".")) & LCase(sExt)
        WIA_ConvertImage = True
     
    Error_Handler_Exit:
        On Error Resume Next
        If Not oIP Is Nothing Then Set oIP = Nothing
        If Not oWIA Is Nothing Then Set oWIA = Nothing
        Exit Function
     
    Error_Handler:
        MsgBox "The following error has occurred" & vbCrLf & vbCrLf & _
              "Error Number: " & Err.Number & vbCrLf & _
              "Error Source: WIA_ConvertImage" & vbCrLf & _
              "Error Description: " & Err.Description & _
              Switch(Erl = 0, "", Erl <> 0, vbCrLf & "Line No: " & Erl) _
              , vbOKOnly + vbCritical, "An Error has Occurred!"
        Resume Error_Handler_Exit
    End Function
    Alvaro Teixeira
    Alvaro Teixeira
    Moderador Global
    Moderador Global


    Respeito às regras : Respeito às Regras 100%

    Sexo : Masculino
    Localização : Portugal
    Mensagens : 7914
    Registrado : 15/03/2013

    [Resolvido]Importar imagem para o access e converter formato Empty Re: [Resolvido]Importar imagem para o access e converter formato

    Mensagem  Alvaro Teixeira 12/7/2022, 08:15

    Olá Edilson Santiago,

    Obrigado por dar o feedback e partilhar a solução.
    Esse código que partilhou é do Daniel Pineault o mesmo do primeiro link que partilhei na mensagem nr. 2.

    Fico feliz por ter resolvido.

    Abraço

    Conteúdo patrocinado


    [Resolvido]Importar imagem para o access e converter formato Empty Re: [Resolvido]Importar imagem para o access e converter formato

    Mensagem  Conteúdo patrocinado


      Data/hora atual: 28/3/2024, 18:38