[Resolvido]Substituir a virgula por ponto em código de conversão de valores

Bem amigos tenho esta função que me retorna um numero decimal

ex: 15,000000

preciso que ao final seja substituido a virgula por ponto...

Obs.. as quantidades de numeros após a virgula são variáveis em sua quantidade.. dependendo da Latitude ou Longitude que o originar


Function Convert(ByVal DMS As String, Hemisferio As Boolean) As Double
On Error Resume Next
Dim GG, mm, SS As String
Dim VarCoord As String
Dim Dec, DecTMP As Double
VarCoord = DMS
GG = Left(VarCoord, 2)
mm = Mid(VarCoord, 3, 2)
SS = Right(VarCoord, 2)
Dec = GG + mm / 60 + SS / 3600 'Nesta linha esta a expressão que me obtem o valor decimal
If Hemisferio Then
DecTMP = "-" & Dec
Convert = DecTMP
Else
Convert = Dec
End If
End Function


Grato pela ajuda

Já tentou usar o Replace?

Me.NomeCampo = Replace(Me.NomeCampo, ",", ".")

Esta apenas apagando a virgula amigão..

Me.txtLongDecimal = Convert(txtLongitude, ChkBoxSul = -1)
Me.txtLongDecimal = Replace(Me.txtLongDecimal, ",", ".")

O Campo na tabela não aceita.

Bom dia, Hary

Na tabela utilize o formato normal, com vírgula. No código, ao executar para o Google, substitua a vírgula pelo ponto.

Bom dia Alexandre! eis o código que uso para o google



Private Sub ListMaps_AfterUpdate()
Parametros_de_Inicializacao "SysAlert.par"
On Error GoTo ErrTrap

Dim db As DAO.Database
Dim StrPath As String
Dim NomeBD As String
Dim ws As DAO.Workspace
Dim rs As DAO.Recordset
Dim rsClone As DAO.Recordset
Dim msg As String
Dim strSQL As String
Dim str As String

NomeBD = "SysAlert_be.accdb"

Set ws = DBEngine.Workspaces(0)
Set db = ws.OpenDatabase(DirBancoDados & "\SysAlert_Be.accdb", False, False, "MS Access;PWD=senha")

strSQL = "SELECT WayPoints.[ID], WayPoints.[Descricao]," _
& "WayPoints.[Lat_Decimal], WayPoints.[Long_Decimal]," _
& "WayPoints.[HTML] FROM WayPoints IN '" & StrPath & "'" _
& " WHERE (((WayPoints.ID)=" & Me.ListMaps & "));"

If IsNull(Me.ListMaps) = False Then

Set rs = db.OpenRecordset(strSQL)

If rs.RecordCount <> 0 Then
If Len(rs.Fields("HTML")) > 0 Then str = str & rs.Fields("HTML")
Me.WebBrowser9.Visible = True
Me.WebBrowser9.Navigate str
Else
Me.WebBrowser9.Visible = False
End If
Set rsClone = Me.RecordsetClone
With rsClone
.FindFirst "[ID]=" & Me.ActiveControl
Me.Bookmark = rsClone.Bookmark
End With
Else
Me.WebBrowser9.Visible = False
End If
ExitHere:
If Not rs Is Nothing Then rs.Close
If Not rsClone Is Nothing Then rsClone.Close
Set rs = Nothing
Set rsClone = Nothing
Exit Sub
ErrTrap:
msg = "Error " & err.Number & " " & err.Description & " " & _
Me.Name & ">ListMaps_AfterUpdate"
MsgBox msg, vbCritical, "NÃO É POSSÍVEL EXIBIR O MAPA"
Resume ExitHere
End Sub



e este para fazer a junção do endereço com as coordenadas

Private Sub btnHTML_Click()
Dim txtPart1 As String, txtPart2 As String, txtPart3 As String
txtPart1 = "http://maps.google.com/maps?hl=en&q="
txtPart2 = ",%20"
txtPart3 = "&spn=0.001074,0.00228&t=h&z=25&output=embed"
Me.txtHTML = txtPart1 & Me.txtLongDecimal & txtPart2 & Me.txtLatDecimal & txtPart3

End Sub

Como fazer amigão?

Tente:

Me.txtHTML = txtPart1 & Replace(Me.txtLongDecimal, ",",".") & txtPart2 & Replace(Me.txtLatDecimal, ",",".") & txtPart3

Bem amigos fiz assim:


Private Sub btnHTML_Click()
Dim VarLat As String, VarLong As String, VarLat1 As String, VarLong1 As String
Dim txtPart1 As String, txtPart2 As String, txtPart3 As String

VarLat = Me.txtLatDecimal
VarLong = Me.txtLongDecimal
VarLat1 = Replace(VarLat, ",", ".")
VarLong1 = Replace(VarLong, ",", ".")

txtPart1 = "http://maps.google.com/maps?hl=en&q="
txtPart2 = ",%20"
txtPart3 = "&spn=0.001074,0.00228&t=h&z=25&output=embed"

Me.txtHTML = txtPart1 & VarLong1 & txtPart2 & VarLat1 & txtPart3
End Sub

Deu certo

Grato

Para ficar mais limpo o código:


Private Sub btnHTML_Click()
Dim VarLat As String, VarLong As String, txtPart1 As String, txtPart2 As String, txtPart3 As String

VarLat = Replace(Me.txtLatDecimal, ",", ".")
VarLong = Replace(Me.txtLongDecimal, ",", ".")

txtPart1 = "http://maps.google.com/maps?hl=en&q="
txtPart2 = ",%20"
txtPart3 = "&spn=0.001074,0.00228&t=h&z=25&output=embed"

Me.txtHTML = txtPart1 & VarLong & txtPart2 & VarLat & txtPart3
End Sub



Saudações

Não havia visto seu post Amigo Criquio...

Realmente mais eficaz e mais limpo dessa forma



Dim txtPart1 As String, txtPart2 As String, txtPart3 As String

txtPart1 = "http://maps.google.com/maps?hl=en&q="
txtPart2 = ",%20"
txtPart3 = "&spn=0.001074,0.00228&t=h&z=25&output=embed"

Me.txtHTML = txtPart1 & Replace(Me.txtLongDecimal, ",", ".") & txtPart2 & Replace(Me.txtLatDecimal, ",", ".") & txtPart3
End Sub

Grato

Tambem poderia-se colocar tudo em uma única linha, já que as partes são fixas:

Me.txtHTML = "http://maps.google.com/maps?hl=en&q=" & Replace(Me.txtLongDecimal, ",", ".") & ",%20" & Replace(Me.txtLatDecimal, ",", ".") & "&spn=0.001074,0.00228&t=h&z=25&output=embed"

Tanto faz

Daqui apouco colocamos so em pensamento... ainda não inventaram esse "código não"?

hehehe

é isso ai Amigão


Grato

Dá tambem para criar uma cbo com valores prédefinidos de zoom

para ter mais flexibilidade quanto ao zoom

o mesmo esta aqui


txtPart1 = "http://maps.google.com/maps?hl=en&q="
txtPart2 = ",%20"
txtPart3 = "&spn=0.001074,0.00228&t=h&z=25&output=embed"

Apenas Agradecendo. Me ajudou bastante.

Obrigado.

Leandro.