[Resolvido]Loop pula segunda linha do subform

Boa tarde galera.
Me deparei com uma coisa que está esquentando minha mente.
Quando clico em um botão no form principal o código pega todos os registros do subform e grava em um campo do form Master.
Até ai tudo bem, claro, se não estivesse pulando sempre a segunda linha do subform.
Segue o código:

Código:



Dim x As Integer
' If Me.Dirty Then
 x = MsgBox("Deseja salvar as alterações do Registro?", vbQuestion + vbYesNo, "Gravar Dados")
   
    Me.tag_coluna1 = Null
    Me.tag_coluna2 = Null
   
    Dim rs As DAO.Recordset
    Set rs = Me.documentos_detalhes.Form.RecordsetClone

    With rs
        Do While Not rs.EOF
          If IsNull(Me.tag_coluna1) Or Me.tag_coluna1 = "" Then
          Me.tag_coluna1 = rs!descricao
          ElseIf IsNull(Me.tag_coluna2) Or Me.tag_coluna2 = "" Then
          Me.tag_coluna2 = rs!periodo
            Else
          Me.tag_coluna1 = Me.tag_coluna1 & "," & rs!descricao
          Me.tag_coluna2 = Me.tag_coluna2 & "," & rs!periodo
        End If
        rs.MoveNext
        Loop
    End With
    rs.Close
    Set rs = Nothing
'    DoCmd.Close acForm, "documentos"
 
 If x = vbNo Then
 Me.Undo
 End If


Ou seja, toda vez que clico em gravar, ele simplesmente ignora a segunda linha do sub e grava o restante normal, da 1º e 3º em diante.
Abraço

Tenta assim:

Código:

Dim x As Integer
' If Me.Dirty Then
 x = MsgBox("Deseja salvar as alterações do Registro?", vbQuestion + vbYesNo, "Gravar Dados")
   
    Me.tag_coluna1 = Null
    Me.tag_coluna2 = Null
   
    Dim rs As DAO.Recordset
    Set rs = Me.documentos_detalhes.Form.RecordSource
    rs.MoveFirst

        Do While Not rs.EOF
          If IsNull(Me.tag_coluna1) Or Me.tag_coluna1 = "" Then
             Me.tag_coluna1 = rs!descricao
          ElseIf IsNull(Me.tag_coluna2) Or Me.tag_coluna2 = "" Then
             Me.tag_coluna2 = rs!periodo
          Else
             Me.tag_coluna1 = Me.tag_coluna1 & "," & rs!descricao
             Me.tag_coluna2 = Me.tag_coluna2 & "," & rs!periodo
          End If
        rs.MoveNext
        Loop

    rs.Close
    Set rs = Nothing

'    DoCmd.Close acForm, "documentos"

If x = vbNo Then Me.Undo

Bom dia.
Obrigado por sua auda Caio, não respondi antes, pois estava adoentado.

Está causando Erro "Tipos incompatíveis" nesta linha:


Set rs = Me.documentos_detalhes.Form.RecordSource

Modifiquei ela para:

Set rs = Me.documentos_detalhes.Form.RecordsetClone

Mas continua o mesmo problema.

Olá a todos,

Verifique assim:

Código:

Dim x As Integer
' If Me.Dirty Then
 x = MsgBox("Deseja salvar as alterações do Registro?", vbQuestion + vbYesNo, "Gravar Dados")
   
    Me.tag_coluna1 = Null
    Me.tag_coluna2 = Null
   
    Dim rs As DAO.Recordset
    Set rs = Me.documentos_detalhes.Form.RecordsetClone

    With rs
        Do While Not rs.EOF
              If Len(Me.tag_coluna1 & "") = 0 Then
                    Me.tag_coluna1 = rs!descricao
              ElseIf Len(Me.tag_coluna2 & "") = 0 Then
                    Me.tag_coluna2 = rs!periodo
              Else
                    Me.tag_coluna1 = Me.tag_coluna1 & "," & rs!descricao
                    Me.tag_coluna2 = Me.tag_coluna2 & "," & rs!periodo
              End If
            rs.MoveNext
        Loop
    End With
    rs.Close
    Set rs = Nothing
'    DoCmd.Close acForm, "documentos"
 
    If x = vbNo Then
      Me.Undo
    End If

Verifique também as condições se estão corretas ou tem dados para processar.
Se o problema persistir, será melhor montar um pequeno exemplo e partilhar a base de dados para se testar.

Abraço a todos

Boa tarde Teixeira.
Eu já havia testado desta forma e sem sucesso também.

Estou postando a parte que contém o problema.

O que estou fazendo é pegar todos os dados do subform e registrar em campos Tag1 e Tag2 do form principal.
Porquê isso?
Porque quando o usuário for buscar no form de consulta o sistema efetua a busca também por estes campos.
Compreendeu?

Fico no aguardo e obrigado pela ajuda.

Boa tarde amigos.
Alguma sugestão?
Obrigado

Olá Claudio,

Tive oportunidade de espreitar o projeto e apresenta erros de compilação.

No entanto verifique se não é isto:

Código:

       Do While Not rs.EOF
               If Len(Me.tag_coluna1 & "") = 0 Then
                    Me.tag_coluna1 = rs!descricao
               Else
                    Me.tag_coluna1 = Me.tag_coluna1 & "," & rs!descricao
               End If
              
               If Len(Me.tag_coluna2 & "") = 0 Then
                    Me.tag_coluna2 = rs!periodo
               Else
                    Me.tag_coluna2 = Me.tag_coluna2 & "," & rs!periodo
               End If
            rs.MoveNext
        Loop

Caso não seja isso, compile verifique e volte a partilhar sem erros de código.

Abraço

Boa noite Teixeira.
Perfeito irmão!!

Resolvido com este último código.
Obrigado pela força.
Agradeço ao Caio também pela atenção dispensada.

Olá Cláudio,

Obrigado pelo retorno, o fórum agradece.

Abraço a todos