MaximoAccess

Caro Usuário, antes de postar pela primeira vez, leia as regras do fórum.

Obrigado

Administração do MaximoAccess

MaximoAccess

Gostaria de reagir a esta mensagem? Crie uma conta em poucos cliques ou inicie sessão para continuar.

Dicas Ms Access, Exemplos Ms Access, Codigos VBA Ms Access, SQL Ms Access

    Exportar Todos os Objetos do Banco para TXT

    chsestrem
    chsestrem
    Developer
    Developer

    Respeito às Regras 100%

    Sexo : Masculino
    Localização : Brasil
    Mensagens : 463
    Registrado : 01/03/2010

    Exportar Todos os Objetos do Banco para TXT Empty Exportar Todos os Objetos do Banco para TXT

    Mensagem  chsestrem em 2/5/2011, 23:03

    Código:
    Option Compare Database
    Option Explicit

    Public Sub ExportDatabaseObjects()
    On Error GoTo Err_ExportDatabaseObjects

    Dim db As Database
    Dim td As TableDef
    Dim d As Document
    Dim c As Container
    Dim i As Integer
    Dim sExportLocation As String

    Set db = CurrentDb()

    sExportLocation = "C:\Temp\" 'Pasta de Destino de Todos os Objetos do BD Ex: C:\Temp\

    For Each td In db.TableDefs 'Tables
    If Left(td.Name, 4) <> "MSys" Then
    DoCmd.TransferText acExportDelim, , td.Name, sExportLocation & "Table_" & td.Name & ".txt", True
    End If
    Next td

    Set c = db.Containers("Forms")
    For Each d In c.Documents
    Application.SaveAsText acForm, d.Name, sExportLocation & "Form_" & d.Name & ".txt"
    Next d

    Set c = db.Containers("Reports")
    For Each d In c.Documents
    Application.SaveAsText acReport, d.Name, sExportLocation & "Report_" & d.Name & ".txt"
    Next d

    Set c = db.Containers("Scripts")
    For Each d In c.Documents
    Application.SaveAsText acMacro, d.Name, sExportLocation & "Macro_" & d.Name & ".txt"
    Next d

    Set c = db.Containers("Modules")
    For Each d In c.Documents
    Application.SaveAsText acModule, d.Name, sExportLocation & "Module_" & d.Name & ".txt"
    Next d

    For i = 0 To db.QueryDefs.Count - 1
    Application.SaveAsText acQuery, db.QueryDefs(i).Name, sExportLocation & "Query_" & db.QueryDefs(i).Name & ".txt"
    Next i

    Set db = Nothing
    Set c = Nothing

    MsgBox "Todos os Objetos do Banco de Dados forma exportados para o Local: " & sExportLocation, vbInformation

    Exit_ExportDatabaseObjects:
    Exit Sub

    Err_ExportDatabaseObjects:
    MsgBox Err.Number & " - " & Err.Description
    Resume Exit_ExportDatabaseObjects

    End Sub


    .................................................................................
    Charles Sestrem
    http://www.vbabit.com.br

      Data/hora atual: 25/11/2020, 09:06