[Resolvido]Filtro caixa de seleção

Boa noite


Estou tendo dificuldade para filtrar o mesmo campo varias vezes.

Hoje tenho um formulário com 2x caixa de seleção. Eu apliquei o seguinte codigo na caixa:


Private Sub cida_AfterUpdate()

If Me.cida.Value = 0 Then
Me!frmSubEmAndamento.Form.FilterOn = False

Else

If Me.cida = -1 Then
f2 = "[TextoMedida] = '" & "Emer" & "'"
Else
   f2 = ""
End If
   Me.Filter = f2
   Me.FilterOn = True

Me!frmSubEmAndamento.Form.Filter = f2
Me!frmSubEmAndamento.Form.FilterOn = True

End If


End Sub


quando filtro apenas uma caixa tudo funciona, o problema que quando clico na outra ele substitui o filtro já existente, eu gostaria de manter o filtro atual e aplicar mais um. Alguém poderia ajudar nesse caso?

Uma caixa de seleção tem dois estados...

Após o Else não há necessidade de verifica o outro estado.. basta apena colocar o código que será executado quando a opção for diferente de 0

No código que postou so faz referencia a uma caixa de seleção.. a outra não está no código...

De mais detalhes.. cite  nome da outra caixa.. e o que pretende filtrar..

Cumprimentos.

Bom dia

A ideia é filtrar apenas a coluna TextoMedida, que da referencia a região. Cada caixa de seleção tem o nome de cida,cida1,cida2... O problema que não consigo fazer essa referencia no codigo, eu quero filtrar conforme vou selecionando as caixas.

Grato pela ajuda

Um pitaco;

Você pode criar uma função para isso, e no evento VBA depois de atualizar cada checkbox fazer a chamada à função, algo assim;

Public Function MultiFiltros()
   Dim mFilter As String
   mFilter = ""

   If Me.cida.Value = -1 Then
      mFilter = mFilter & "[TextoMedida] LIKE '" & "*" & "Emer" & "*'"
   End If
   
   If Me.OutroCheckBox.Value = -1 Then
      If Len(mFilter) > 0 Then mFilter = mFilter & " AND "
      mFilter = mFilter & "[OutraCaixa] LIKE '*" & "JPaulo" & "*'"
   End If

   If Len(mFilter) > 0 Then
      Me!frmSubEmAndamento.Form.Filter = mFilter
      Me!frmSubEmAndamento.Form.FilterOn = True
   Else
      Me!frmSubEmAndamento.Form.FilterOn = False
   End If
   Me.Requery
End Function

Chamar a função:

Private Sub cida_AfterUpdate()
    Call MultiFiltros
End Sub

Grato pela ajuda mas isso ainda não atende. A ideia desse filtro é fazer varios filtros na mesma coluna, exemplo:


Caixa1 - Filtro Emer
Caixa2 - Filtro Emer2

Assim que eu selecionar caixa 1 e 2 vai me mostrar filtrado Emer e Emer2, essa informação esta na mesma coluna (TextoMedida). Caso eu tire a selação da caixa 2 ele tira o filtro emer2.

Grato

E como é que o amigo Lucas pode dizer que ainda não o atende, se você não sabe intrepertar o exemplo que lhe passei ?

Repare que em todos os filtros ele vai concatenando;

If Len(mFilter) > 0 Then mFilter = mFilter & " AND "
mFilter = mFilter & "[OutraCaixa] LIKE '*" & "JPaulo" & "*'"

Agora é só você mexer e alinhar ao seu proposito.

Olá Jpaulo

Antes de postar eu sempre testo as dicas passadas por vocês, e foi assim que ficou no meu controle:


Public Function MultiFiltros()
Dim mFilter As String
mFilter = ""

If Me.cida.Value = -1 Then
mFilter = mFilter & "[TextoMedida] LIKE '" & "*" & "Em Execução" & "*'"
End If

If Me.cida1.Value = -1 Then
If Len(mFilter) > 0 Then mFilter = mFilter & " AND "
mFilter = mFilter & "[TextoMedida] LIKE '*" & "Aguardando" & "*'"
End If

If Len(mFilter) > 0 Then
Me!frmSubEmAndamento.Form.Filter = mFilter
Me!frmSubEmAndamento.Form.FilterOn = True
Else
Me!frmSubEmAndamento.Form.FilterOn = False
End If
Me.Requery
End Function

quando eu clico em uma caixa ele faz o filtro mas quando clico na segunda caixa ele fica em branco e some o filtro anterior.

Anexe por favor aqui, parte do seu banco ou um pequeno exemplo que envolva o seu problema.

Acabei de reproduzir aqui e tem de substituir o AND por OR, faça o teste por favor;

Public Function MultiFiltros()
Dim mFilter As String
mFilter = ""

If Me.Cida.Value = -1 Then
mFilter = mFilter & "[TextoMedida] LIKE '" & "*" & "Em Execução" & "*'"
End If

If Me.Cida1.Value = -1 Then
If Len(mFilter) > 0 Then mFilter = mFilter & " Or "
mFilter = mFilter & "[TextoMedida] LIKE '*" & "Aguardando" & "*'"
End If

If Len(mFilter) > 0 Then
Me!frmSubEmAndamento.Form.Filter = mFilter
Me!frmSubEmAndamento.Form.FilterOn = True
Else
Me!frmSubEmAndamento.Form.FilterOn = False
End If
Me.Requery
End Function

Agora funcionou =DD... muito obrigado pela ajuda.

Obrigado pelo retorno o forum agradece.