[Resolvido]subformulario não salva

Ola, Pessoal tenho esse código que deveria pegar um determinado registro no subformulário a salvar no final da mesma tabela, por exemplo se tiver dois  itens no form ele pega o primeiro registro e salva 2 vezes o mesmo item, se tiver 10 registros ele pega o primeiro e salva 10 veses.

me ajudem...  o que esta errado.


O arquivo anexo faz exatamente o que eu preciso, mas não consegui adaptar

veja o form Clone dbo_jobs1

Dim db   As DAO.Database
 Dim rs   As DAO.Recordset

 Set db = CurrentDb()

 StrSql = "SELECT * FROM tbl_itens_orcamento WHERE numero_orcamento"
 Set rs = db.OpenRecordset(StrSql, dbOpenDynaset)

 With Me.frmSub_Orcamento.Form.RecordsetClone
   If (.RecordCount) Then
     .MoveFirst
       Do Until .EOF
       rs.AddNew        
 
               rs!Numero_orcamento = (DMax("numero_orcamento", "Tbl_orcamento"))
               rs!Referencia = Forms![frmOrcamento]![frmSub_Orcamento]!Referencia
               rs!quantidade = Forms![frmOrcamento]![frmSub_Orcamento]!quantidade
               rs!comp = Forms![frmOrcamento]![frmSub_Orcamento]!comp
               rs!larg = Forms![frmOrcamento]![frmSub_Orcamento]!larg
               rs!alt = Forms![frmOrcamento]![frmSub_Orcamento]!alt
               rs!modelo = Forms![frmOrcamento]![frmSub_Orcamento]!modelo
               rs!qualidade = Forms![frmOrcamento]![frmSub_Orcamento]!qualidade
               rs!preco = Forms![frmOrcamento]![frmSub_Orcamento]!preco
               rs!faca = Forms![frmOrcamento]![frmSub_Orcamento]!faca
               rs!cliche = Forms![frmOrcamento]![frmSub_Orcamento]!cliche
               rs!data = Forms![frmOrcamento]![frmSub_Orcamento]!data
               rs.Update

      .MoveNext
     Loop
   End If
 End With

 Set rs = Nothing
 Set db = Nothing
 End If

StrSql = "SELECT * FROM tbl_itens_orcamento WHERE numero_orcamento"

Onde está o que falta na cláusula Where ???

Deveria ser :
StrSql = "SELECT * FROM tbl_itens_orcamento WHERE numero_orcamento=" & Me.SeuCampoNumeroOrçamento 'Se numerico e estiver no formulario

Ou

StrSql = "SELECT * FROM tbl_itens_orcamento WHERE numero_orcamento='" & Me.SeuCampoNumeroOrçamento & "'" 'Se texto e estiver no formulario

Além disso, a referencia ao campos do sub, está mal;

O correto:
Forms![frmOrcamento]![frmSub_Orcamento].Form!Referencia

Amigo, fiz as correções conforme você passo mas continua, so salva o registro da primeira linha, varias vezes

Pode por favor anexar aqui parte do seu banco, por favor ?

Segue anexo

Seu código corrigido aqui;

Código:

Private Sub Comando105_Click()
Dim dbOrc As DAO.Database
Dim rs_orc As DAO.Recordset
Dim rs2 As DAO.Recordset
Dim rs3 As DAO.Recordset
   
    If MsgBox("Deseja Editar Orçamento?", vbYesNo + vbQuestion, "Inclusão do Orçamento na Venda") = vbYes Then
   
        Set dbOrc = CurrentDb
        Set rs_orc = dbOrc.OpenRecordset("Tbl_orcamento", dbOpenDynaset)
           
        With rs_orc
        .AddNew
        ![data] = Me.data
        ![cliente] = Me.cliente
        ![contato] = Me.contato
        ![email] = Me.email
        ![vendedor] = Me.vendedor
        ![prazo_entrega] = Me.prazo_entrega
        ![pagamento] = Me.pagamento
        ![Validade_orc] = Me.Validade_orc
        ![observacao] = Me.observacao
        .Update
        End With
       
        Set rs2 = dbOrc.OpenRecordset("SELECT * FROM Tbl_itens_orcamento WHERE numero_orcamento=" & Me.Numero_orcamento, dbOpenDynaset)
        Set rs3 = dbOrc.OpenRecordset("SELECT * FROM Tbl_itens_orcamento", dbOpenDynaset)
     
    If rs2.RecordCount = 0 Then Exit Sub 'se não encontrar registros, morre aqui
   
      rs2.MoveLast
      rs2.MoveFirst

      Do While Not rs2.EOF
                rs3.AddNew
                rs3!Numero_orcamento = Nz(DMax("numero_orcamento", "Tbl_orcamento"), 0)
                rs3![Referencia] = rs2![Referencia]
                rs3![quantidade] = rs2![quantidade]
                rs3![comp] = rs2![comp]
                rs3![larg] = rs2![larg]
                rs3![alt] = rs2![alt]
                rs3![modelo] = rs2![modelo]
                rs3![qualidade] = rs2![qualidade]
                rs3![preco] = rs2![preco]
                rs3![faca] = rs2![faca]
                rs3![cliche] = rs2![cliche]
                rs3![data] = rs2![data]
                rs3.Update
            rs2.MoveNext
            rs3.MoveNext
        Loop

rs_orc.Close: Set rs_orc = Nothing
rs2.Close:    Set rs2 = Nothing
rs3.Close:    Set rs3 = Nothing
dbOrc.Close:  Set dbOrc = Nothing
     
      Else
      Exit Sub
End If
End Sub



JPaulo, muito obrigado

Obrigado pelo retorno o forum agradece.