[Resolvido]Somar campos

Caros, bom dia!

Tenho em meu projeto um modulo com a função contar dias e no evento ao clicar de um botão o código abaixo que separa e quantifica os dias da semana.
Alguém sabe como adapta-lo para que ele não some os dias separados e sim todos juntos?
Tentei ate manter separado e depois incluir uma outra caixa de texto e somar os valores porem da erro.

Alguém pode me ajudar???

Botão ara calcular:
Private Sub Calcular_Click()
On Error GoTo Error_Handler

If Len(Me.Inicio & vbNullString) = 0 Or Len(Me.Fim & vbNullString) = 0 Then
MsgBox "Insira a data inicial e final", vbOKOnly
Exit Sub
End If

Me.Segundas = ContaDia(Me.Inicio, Me.Fim, 2)
Me.Terças = ContaDia(Me.Inicio, Me.Fim, 3)
Me.Quartas = ContaDia(Me.Inicio, Me.Fim, 4)
Me.Quaintas = ContaDia(Me.Inicio, Me.Fim, 5)
Me.Sextas = ContaDia(Me.Inicio, Me.Fim, 6)

Exit_Here:
Exit Sub

Error_Handler:
MsgBox Err.Number & ": " & Err.Description
Resume Exit_Here
End Sub

Boa tarde,
Mostre a função ContaDia

Segue:

Function ContaDia(dtmInicio As Date, dtmFim As Date, intDay As VbDayOfWeek) As Long
'Conta o número de um dia específico entre duas datas
Dim dtmTemp As Date
Dim lngCount As Long
If dtmFim < dtmInicio Then
dtmTemp = dtmFim
dtmFim = dtmInicio
Else
dtmTemp = dtmInicio
End If
Do Until dtmTemp > dtmFim
If Weekday(dtmTemp) = intDay Then
lngCount = lngCount + 1
dtmTemp = DateAdd("d", 7, dtmTemp)
Else
dtmTemp = DateAdd("d", 1, dtmTemp)
End If
Loop
ContaDia = lngCount
End Function

Ola;

Pode fazer o simples;

Código:

Private Sub Command0_Click()
On Error GoTo Error_Handler

Dim i As Integer

If Len(Me.Inicio & vbNullString) = 0 Or Len(Me.Fim & vbNullString) = 0 Then
MsgBox "Insira a data inicial e final", vbOKOnly
Exit Sub
End If

i = ContaDia(Me.Inicio, Me.Fim, 2)
i = i + ContaDia(Me.Inicio, Me.Fim, 3)
i = i + ContaDia(Me.Inicio, Me.Fim, 4)
i = i + ContaDia(Me.Inicio, Me.Fim, 5)
i = i + ContaDia(Me.Inicio, Me.Fim, 6)

Me.txtTotal.Value = i

Exit_Here:
Exit Sub

Error_Handler:
MsgBox Err.Number & ": " & Err.Description
Resume Exit_Here
End Sub

Perfeito.

Muitissimo obrigada

Obrigado pelo retorno o forum agradece.