[Resolvido]Auditor ou Log

Amigos boa tarde!

Um tempo atrás encontrei um exemplo de um auditor que funciona tipo um log, onde fica salvo as alterações ocorridas, e adaptei a minha situação para ficar sabendo quais alterações e quem as fez.
Observando a funcionalidade encontrei um erro nos casos em o campo era diferente de nulo, ou seja preenchido e na situação atual passou a ser nulo (é apagado o conteúdo) não registra na tabela que audita.
Alguém poderia dá uma luz.

Segue o código:

Código:

Function WriteAudit(frm As Form, lngID As Long, resp As Long, Tabela As String)
On Error GoTo err_WriteAudit

    Dim ctlC As control
    
    Dim db As Database
    Dim RST As Recordset
    
    Set db = CurrentDb
    Set RST = db.OpenRecordset("tblAudit")
            
    For Each ctlC In frm.Controls
        If (TypeOf ctlC Is TextBox) Or (TypeOf ctlC Is ComboBox) Then    'If TypeOf ctlC Is TextBox Then
            If ctlC.Value <> ctlC.OldValue Or IsNull(ctlC.OldValue) Then
                If Not IsNull(ctlC.Value) Then
                    RST.AddNew
                    RST("ID") = lngID
                    RST("Responsavel") = resp
                    RST("CampoModificado") = ctlC.Name
                    RST("CampoOriginal") = ctlC.OldValue
                    RST("CampoAlterado") = ctlC.Value
                    RST("Tabela") = Tabela
                    RST("User") = GetUserName_TSB()
                    RST("PC") = fOSMachineName()
                    'rst("IP") = DameIpMaquina()
                    RST("DataModif") = Now
                    RST.Update
                End If
            End If
        End If
    Next ctlC
    
    
exit_WriteAudit:
    RST.Close
    db.Close
    Set RST = Nothing
    Set db = Nothing
    Exit Function
    
err_WriteAudit:
    MsgBox Str(Err)
    MsgBox Err.Description
    Resume exit_WriteAudit
    
End Function

Os créditos são de:

Candace Tripp
ctripp1@earthlink.net
http://www.candace-tripp.com/

Boa tarde
Tente

Código:

Function WriteAudit(frm As Form, lngID As Long, resp As Long, Tabela As String)
    On Error GoTo err_WriteAudit
    'créditos a Candace Tripp
    Dim ctlC As Control
   
    Dim db As Database
    Dim RST As dao.Recordset
   
    Set db = CurrentDb
    Set RST = db.OpenRecordset("tblAudit")
           
    For Each ctlC In frm.Controls
        If (TypeOf ctlC Is TextBox) Or (TypeOf ctlC Is ComboBox) Then    'If TypeOf ctlC Is TextBox Then
            If ctlC.value <> ctlC.OldValue Or IsNull(ctlC.OldValue) Then
                    RST.AddNew
                    RST("ID") = lngID
                    RST("Responsavel") = resp
                    RST("CampoModificado") = ctlC.Name
                    RST("CampoOriginal") = ctlC.OldValue
                    RST("CampoAlterado") = ctlC.value
                    RST("Tabela") = Tabela
                    'RST("User") = GetUserName_TSB()
                    RST("User") = NomeUtilizador
                    RST("PC") = fOSMachineName()
                    'rst("IP") = DameIpMaquina()
                    RST("DataModif") = Now
                    RST.Update
            End If
        End If
    Next ctlC
   
   
exit_WriteAudit:
    RST.Close
    db.Close
    Set RST = Nothing
    Set db = Nothing
    Exit Function
   
err_WriteAudit:
    MsgBox str(err)
    MsgBox err.Description
    Resume exit_WriteAudit
   
End Function


Caro Alexandre Neves, infelizmente não resolveu mas fui quebrando cabeça e deu certo dessa forma:

Código:

Function WriteAudit(frm As Form, lngID As Long, resp As Long, Tabela As String)
    On Error GoTo err_WriteAudit
    'créditos a Candace Tripp
    Dim ctlC As control
    
    Dim db As Database
    Dim RST As dao.Recordset
    
    Set db = CurrentDb
    Set RST = db.OpenRecordset("tblAudit")
            
    For Each ctlC In frm.Controls
        If (TypeOf ctlC Is TextBox) Or (TypeOf ctlC Is ComboBox) Then    'If TypeOf ctlC Is TextBox Then
            If (IsNull(ctlC.Value) And Not IsNull(ctlC.OldValue)) Or (IsNull(ctlC.OldValue) And Not IsNull(ctlC.Value)) Or _
                (Not IsNull(ctlC.Value) And Not IsNull(ctlC.OldValue) And ctlC.Value <> ctlC.OldValue) Then
                    RST.AddNew
                    RST("ID") = lngID
                    RST("Responsavel") = resp
                    RST("CampoModificado") = ctlC.Name
                    RST("CampoOriginal") = ctlC.OldValue
                    RST("CampoAlterado") = ctlC.Value
                    RST("Tabela") = Tabela
                    RST("User") = GetUserName_TSB()
                    'RST("User") = NomeUtilizador
                    RST("PC") = fOSMachineName()
                    'rst("IP") = DameIpMaquina()
                    RST("DataModif") = Now
                    RST.Update
            End If
        End If
    Next ctlC
    
    
exit_WriteAudit:
    RST.Close
    db.Close
    Set RST = Nothing
    Set db = Nothing
    Exit Function
    
err_WriteAudit:
    MsgBox Str(Err)
    MsgBox Err.Description
    Resume exit_WriteAudit
    
End Function

Dessa forma atende todas as codições:
Se o campo antigo for nulo e o atual informado ele grava,
Se o campo antigo não for nulo e o atual informado for anulado ele grava, ou seja está gravando qualquer situação que aconteça.
Agradeço demais pela ajuda.