[Resolvido]Passagem de parametros à uma função

Caros colegas,

Desculpem a ignorância, mas qual a sintaxe correta para passar dois campos data como parametros, para que uma função calcule uma idade, em um período passado? (preciso calcular a idade de um paciente por ocasião do seu primeiro atendimento). Já aproveitei a função para o calculo da idade, apresentada aqui neste fórum... estou tentando adapta-la para esta finalidade.

Na verdade, só preciso da diferença em anos, entre duas datas... talvez uma macro...

Hi Mário! Bienvenido ao Forum!

Você quer fazer isso em registros já gravados na tabela, é isso mesmo? Você pode abrir um RecordSet e usar a instrução Do While para fazer enquanto Not rs.EOF. Sem ver a estrutura, fica meio difícil dar todos os detalhes.

Adaptei sua rotina CalculaIdade([Data Nasc]) para executar o calculo com uma data passada... ficou porreta! Veja o código:

Function CalculaIdadeAt(DataAtend As Variant, DataNasc As Variant) As Variant
''Recebe a Data do Primeiro atendimento e devolve a Idade que o paciente tinha em Anos

On Error GoTo Idade_Err

''Evita o erro de data não preenchida
If IsNull(DataAtend) Then
CalculaIdadeAt = ""
Exit Function
End If
If IsNull(DataNasc) Then
CalculaIdadeAt = ""
Exit Function
End If

''Declarando Variáveis
Dim DataHoje As Variant, DiaHoje As Integer
Dim MesNasc As Integer, DiaNasc As Integer
Dim MesAtend As Integer, DiaAtend As Integer
Dim DifAnos As Integer, MesHoje As Integer

''Isola as partes (dia/mês) das duas datas
DiaNasc = DatePart("d", DataNasc)
MesNasc = DatePart("m", DataNasc)
DiaAtend = DatePart("d", DataAtend)
MesAtend = DatePart("m", DataAtend)

''Calcula a diferença de anos
DifAnos = DateDiff("yyyy", DataNasc, DataAtend)

''Verifica dia/mês de nascimento
If MesAtend < MesNasc Then
DifAnos = DifAnos - 1
ElseIf MesAtend = MesNasc Then
If DiaAtend < DiaNasc Then
DifAnos = DifAnos - 1
End If
Else
End If

''Valor final da função
CalculaIdadeAt = DifAnos

Idade_Fim:
Exit Function

Idade_Err:
MsgBox Err.Description
Resume Idade_Fim

End Function

De tanto apanhar, consegui descobrir como passar as duas datas como parametro para a função: =CalculaIdadeAt([DataAtend];[DataNasc])

OBRIGADO, meu amigo.

Acho que essa função não é de minha autoria, mas ao que parece resolveu, não? Vou passar o tópico a Resolvido, mas qualquer dúvida referente à esse assunto, pode voltar a abri-lo.