[Resolvido]Área de transferência

Prezados procuro um comando que ao clicar em um botão eu possa copiar o valor do campo para a área de transferência.
Alguém pode me ajudar?

Direto do F1 em um módulo do Access:


Como: Enviar informações para a Área de Transferência

Usar o método RunCommand
Você pode usar o método RunCommand com a constante acCmdCopy para copiar o conteúdo do controle ativo de um formulário ou relatório para a Área de Transferência. O exemplo a seguir ilustra como copiar o conteúdo de uma caixa de texto chamada txtNotes para a Área de Transferência.

Private Sub cmdCopy_Click()
Me!txtNotes.SetFocus
DoCmd.RunCommand acCmdCopy
End Sub

Usar a API do Windows
Para usar chamadas da API do Windows para enviar para a Área de Transferência, cole o código a seguir na seção Declarações de um módulo padrão.

Declare Function GlobalUnlock Lib "kernel32" (ByVal hMem As Long) _
As Long
Declare Function GlobalLock Lib "kernel32" (ByVal hMem As Long) _
As Long
Declare Function GlobalAlloc Lib "kernel32" (ByVal wFlags As Long, _
ByVal dwBytes As Long) As Long
Declare Function CloseClipboard Lib "User32" () As Long
Declare Function OpenClipboard Lib "User32" (ByVal hwnd As Long) _
As Long
Declare Function EmptyClipboard Lib "User32" () As Long
Declare Function lstrcpy Lib "kernel32" (ByVal lpString1 As Any, _
ByVal lpString2 As Any) As Long
Declare Function SetClipboardData Lib "User32" (ByVal wFormat _
As Long, ByVal hMem As Long) As Long

Public Const GHND = &H42
Public Const CF_TEXT = 1
Public Const MAXSIZE = 4096

O procedimento a seguir ilustra como enviar informações para a Área de Transferência.

Function ClipBoard_SetData(MyString As String)
Dim hGlobalMemory As Long, lpGlobalMemory As Long
Dim hClipMemory As Long, X As Long

' Allocate moveable global memory.
'-------------------------------------------
hGlobalMemory = GlobalAlloc(GHND, Len(MyString) + 1)

' Lock the block to get a far pointer
' to this memory.
lpGlobalMemory = GlobalLock(hGlobalMemory)

' Copy the string to this global memory.
lpGlobalMemory = lstrcpy(lpGlobalMemory, MyString)

' Unlock the memory.
If GlobalUnlock(hGlobalMemory) <> 0 Then
MsgBox "Could not unlock memory location. Copy aborted."
GoTo OutOfHere2
End If

' Open the Clipboard to copy data to.
If OpenClipboard(0&) = 0 Then
MsgBox "Could not open the Clipboard. Copy aborted."
Exit Function
End If

' Clear the Clipboard.
X = EmptyClipboard()

' Copy the data to the Clipboard.
hClipMemory = SetClipboardData(CF_TEXT, hGlobalMemory)

OutOfHere2:

If CloseClipboard() = 0 Then
MsgBox "Could not close Clipboard."
End If

End Function

presumo que esteja Resolvido. Qualquer coisa reabra.

porque no meu ta dando esse erro ?

Caio.souza, faça uma pesquisa por "64 bits" e/ou "ptrSafe" no fórum. Há alguns tópicos que explicam as diferenças sintáticas entre 32 bits e 64 bits.

Nem precisa não, fiz o seguinte:
Ativei novamente a caixa de texto, e nas propriedades do formulário>permitir edições>NÃO!

Quero só que copie, mais não edite ou exclua o registro.

Ta supinpa!
valeu pela atenção.