[Resolvido]Aceitar espaço no nome da tabela na função

Olá, sei que não devemos deixar nome de objetos com espaços mas quero entender se é
possível nessa função, pois como esta não localiza tabelas com espaços no nome (tab escola).

Public Sub limpaBanco()
Dim db As DAO.Database
Dim tbl As DAO.TableDef
Dim field As DAO.field
Dim sql As String

Set db = CurrentDb

For Each tbl In db.TableDefs
'Looping por todas as tabelas que não sejam de sistema
If InStr(1, tbl.Name, "MSys") = False Then
'Debug.Print tbl.Name
sql = "delete from " & tbl.Name -----------------> aqui ela para, pois o nome tem espaços
db.Execute sql
End If
Next

'fecha e tira da memória a referência do objeto.
db.Close
Set db = Nothing
End Sub

Olá;

Tal como em qualquer código VBA, os nomes de objectos com espaços têm de estar dentro de colchetes;

Código:

Public Sub limpaBanco()
Dim db As DAO.Database
Dim tbl As DAO.TableDef
Dim field As DAO.field
Dim sql As String

Set db = CurrentDb

For Each tbl In db.TableDefs
'Looping por todas as tabelas que não sejam de sistema
If InStr(1, tbl.Name, "MSys") = False Then
'Debug.Print tbl.Name
sql = "DELETE * FROM " & "[" & tbl.Name & "]"
db.Execute sql
End If
Next

'fecha e tira da memória a referência do objeto.
db.Close
Set db = Nothing
End Sub


Nota:
Tópico movido para a sala "Módulos e VBA":

Valeu JPaulo, Funcionou.

Estava pensando em aspas simples com duplas, mas nunca aprendo a colocá-las.

Obrigado

Fico feliz.
Obrigado pelo retorno o fórum agradece.