[Resolvido]Renomear vários arquivos em função dos registos da tabela

Pessoal,

Eu encontrei aqui no fórum uma sugestão de como renomear os arquivos, porém, gostaria de saber se é possível adaptar o código para que fosse renomeado o lote inteiro clicando no botão uma única vez, não sendo necessário clicar registro por registro para ele gerar cada arquivo renomeado.

Link original: https://www.maximoaccess.com/t5059-resolvidorenomear-arquivo

Código:

Private Sub Btn_Rename_Click()

On Error GoTo Err_Copiando_Click

Dim ArquivoDeOrigem, ArquivoDeDestino

ArquivoDeOrigem = "C:\Renomear Docts\" & Me!Grupo & ".pdf" ' Define o nome do arquivo de origem.
ArquivoDeDestino = "C:\Renomear Docts\" & Me("Renomear Boleto") & ".pdf"

'Define o nome do arquivo dedestino.
FileCopy ArquivoDeOrigem, ArquivoDeDestino ' Copia a origem no destino.

MsgBox "Arquivo renomeado com sucesso", vbInformation, "INFORMAÇÃO"

Exit_Copiando_Click:

Exit Sub

Err_Copiando_Click:

MsgBox "Arquivo não localizado", vbCritical, "ERRO"

Resume Exit_Copiando_Click

End Sub


Agradeço muito.
Att
Cy Rangel.

Olá Cinthia,

Também pode renomear arquivos com a função nativa do access "name".
Se tiver dúvidas, aperte a tecla F1 com o name selecionado no editor de VBA.

Abraço

Olá ahteixeira,

Muito obrigada pelo retorno, mas sou totalmente leiga na parte de escrever códigos. O que consigo fazer é apenas o básico, busco os códigos prontos e adapto eles na VBA que possuo. Nada mais do que isso, desculpe.


Att,
Cy Rangel.

Olá Cinthia,

Disponibilize um pequeno exemplo do que tem, e deixe detalhes do que pretende obter.
Assim vai ficar mais fácil para compreender e poder ajudar.

Abraço

Olá ahteixeira,

Espero que esteja bem!

Desculpe a demora em postar, mas sempre que me solicitam preciso fazer um arquivo modelo.

É exatamente assim que está funcionando o meu access "base original" atualmente.


Gostaria de que ao clicar em "Rename" ele já buscasse todos os arquivos que encontrar em "PDF" com o nº descrito na coluna "Grupo" e  renomear de uma única vez (haverá arquivos que ele não irá encontrar, então esse, ele precisará pular e seguir para o próximo da lista).


Muito obrigada pela atenção.

Olá Cinthia,

Para o que pretende é necessário percorrer os registos.
No exemplo que postou altere o código do botão por este:

Código:

Private Sub Btn_Rename_Click()
'ahteixeira 2020 para MaximoAccess
On Error GoTo Err_Rename_Click 'define tratamento erros

    Dim rs As Recordset 'dimensionar recordeset
    Set rs = CurrentDb.OpenRecordset("TBL_6_01_RenomearBoletos") 'atribuir base de dados abrir
    
    Do While Not rs.EOF 'correr os registos enquanto nao chega ao fim
        Name "C:\Renomear Docts\" & rs![Grupo] & ".pdf" As "C:\Renomear Docts\" & rs![Renomear Boleto] & ".pdf" 'renomear
        rs.MoveNext 'mover para o registo seguinte
    Loop 'seguinte
    
    rs.Close 'fechar recordeset
    Set rs = Nothing 'remover da memoria

    MsgBox "Operacao Concluida", vbInformation, ""
    
Exit_Rename_Click:
    Exit Sub

Err_Rename_Click: 'tratamento de erros
    If Err.Number = 53 Then
        Resume Next
    Else
        MsgBox Err.Number & "-" & Err.Description, vbCritical, "ERRO"
        Resume Exit_Rename_Click
    End If
End Sub


O código está comentado para melhor estudo.

Nota, ajustei o título do tópico para ser mais fácil para pesquisa no fórum.

Abraço

Ahteixeira, sem palavras, vocês são de mais!

Era exatamente o que eu precisava... E muito obrigada por ter comentado, quando vocês fazem isso, consigo aproveitar muito mais os códigos em outros projetos

Ficou Show \o/\o/\o/...


Aproveito para deixar uma dica... Se mais alguém for utilizar esse código, precisa antes ir dentro do VBA, clicar em "Ferramentas"/"Referências" e habilitar de acordo com a versão do office, a minha era "Microsoft Office 16.0 Access database engine Object Library".


Uma curiosidade: Quando o meu office atualizar, será que tmb precisarei entrar dentro dessas referências novamente e alterar a versão para a nova de cada access?

Olá Cinthia,

Obrigado pelo retorno, o fórum agradece.
Quanto à ultima questão, normalmente para versões superiores não é necessário atualizar a referencia.
No entanto se efetuar uma busca no fórum também existe forma de automatizar e verificar referencias.

Abraço e bons estudos com o MaximoAccess.

Nossa que bom! Meu Deus, o que não tem nesse fórum, rs?! Estou amando participar dele, muito completo e as pessoas muito atenciosas, além de assertivas. Obg por tudo e pelas dicas... Até mais ...