[Resolvido] Importar arquivo .CSV - com acentuação

Ola bom dia

Apos pesquisar aqui no fórum encontrei um tópico do Alvaro Teixeira, que me resolveu quase o problema

o meu problema é que recebo um ficheiro .CSV - com acentuações e se fizer a importação direta não da erro, mas não importa nada.

Para resolver o problema tenho de abrir ficheiro no Excel e gravar como CSV (separado por virgula), conforme imagem que anexo, apos isso já importa os dados.

o que eu pretendia era importar direto

junto banco dados em anexo

( Tópico do Teixeira em baixo na mensagem 10 )

https://www.maximoaccess.com/t30892-resolvidoacentuacao-do-arquivo-csv-conversao-via-adodb-stream#213825

A ideia não é importar tudo por colunas ?

Se for funciona assim;

Código:

DoCmd.TransferText _
        TransferType:=acImportDelim, _
        SpecificationName:="", _
        TableName:="SuaTabela", _
        FileName:=Application.CurrentProject.Path & "\BookingReport-Original.csv", _
        HasFieldNames:=True

Bom dia

A ideia não é importar tudo por colunas ?

sim depois tinha que fazer isso

Estamos quase la, só falta as acentuações  

Assim;

João Paulo,
Muito obrigado
Um grande abraço

O código final ficou assim

Código:

Private Sub ImportarDadosExcel_Click()
'By JPaulo Maximo Access
'Alvaro Teixeira (2017) para MaximoAccess
'conversao via "Stream"
'Requer referencia a Microsoft ActiveX Data Objects (ADO)

    Dim i As Integer
    Dim objStream, strData
    Set objStream = CreateObject("ADODB.Stream")

    CurrentDb.Execute "DELETE * FROM DadosConvertidosExcel"

    objStream.Charset = "utf-8"
    objStream.Open
    objStream.LoadFromFile CurrentProject.Path & "\BookingReport-Original.csv"   'nome do excel a ser importado
    strData = objStream.ReadText()
    objStream.Close

    objStream.Charset = "ISO-8859-1"
    objStream.Open
    objStream.WriteText strData
    objStream.SaveToFile Application.CurrentProject.Path & "\TesteConv.txt", 2
    Set objStream = Nothing

    DoCmd.TransferText TransferType:=acImportDelim, SpecificationName:="", _
                       TableName:="DadosConvertidosExcel", _
                       FileName:=Application.CurrentProject.Path & "\TesteConv.txt", _
                       HasFieldNames:=True
    
    'apaga o txt para o utilizador final não saber
    Kill Application.CurrentProject.Path & "\TesteConv.txt"

    MsgBox "     Dados importados com sucesso     ", vbInformation, ".:: @RSV ::."

End Sub



Obrigado pelo retorno o fórum agradece.