[Resolvido]Repetir valor de um campo em outros campos respeitando condição IF... ELSE

Estou usando o código a seguir para editar campos existentes na mesma tabela.

Código:

       
Private Sub Form_AfterUpdate()
        Dim db As Database
        Dim rs As Recordset
        Set db = CurrentDb()
        Set rs = db.OpenRecordset("tbl_ContasReceberPagar")
       
        If Tipo_De_Movimentação_De_Caixa = "1" And Financeiro = "1" Then
            Valor_da_Parcela = ValorDaParcelaRecebida
                           
            rs.Edit
            rs("Entradas") = Valor_da_Parcela
            rs("Saídas") = 0
            rs("EntradasCaixa") = Valor_da_Parcela
            rs("SaídasCaixa") = 0
            rs("EntradasReais") = Valor_da_Parcela
            rs("SaídasReais") = 0
            rs("EntradasBanco") = 0
            rs("SaídasBanco") = 0
            rs("EntradasPag") = 0
            rs("SaídasPag") = 0
            rs.Update
       
        rs.Close
        db.Close
        Me.[frm_SubformulárioContasReceberPagar-1].Requery

    Else...

    End If

End Sub


O código não está atualizando os campos. Todos continuam com valor zero.

Gostaria que o valor do campo ValorDaParcelaRecebida fosse inserido (ou repetido):

1) se MovimentoDeCaixa=1 (Entrada) e Financeiro=1 (Caixa) nos campos Entradas, EntradasCaixa e EntradasReais.
2) se MovimentoDeCaixa=2 (Saídas) e Financeiro=1 (Caixa) nos campos Saídas, SaídasCaixa e SaídasReais.

Os demais campos devem permanecer com valor zero.

Estou adotando esse procedimento, porque, se porventura, tentar reeditar corrigir um registro de Entradas para Saídas, os registros sejam invertidos.

Eu insiro os dados de recebimento em um subformulário de um formulário de Clientes/Fornecedores.

Podem me ajudar? Desde já obrigado.

Olá

Está um pouco dificil de ajudar assim, não vejo nenhum Loop ae.

Consegue enviar um pequeno exemplo em BD ?

JPaulo, obrigado por me responder. Estou enviando, anexo, o BD.

Entre, por gentileza, no frm_ContasReceberPagar. Ele vai lhe pedir um parâmetro: digite 43, que é uma operação de venda a prazo que está no BD. Esse frm tem um subformulário: frm_SubformulárioContasReceberPagar-1. É neste subformulário, no campo cbo_Financeiro, que introduzi o código de atualização da postagem inicial, e que não está funcionando. Pode testar lançando o recebimento da parcela 1/5: [DataDeRecebimento] 16/02/2022, [ValorDaParcelaRecebida] 30000 e [cbo_Financeiro] Caixa.

Há vários campos cujo formato é moeda que estão com valor 0. Eu gostaria que, ao escolher o tipo financeiro (Banco ou Caixa), as colunas de valores de entrada ou saída a seguir fossem atualizadas automaticamente pelo valor que está no campo [ValorDaParcelaRecebida] 30000. Os campos a serem preenchidos quando escolher o Financeiro=Caixa seriam [Entradas], [EntradasCaixa] e [EntradasReais]. Para isso preciso de um IF...ELSE, porque pode ser um recebimento/pagamento por Caixa ou por Banco, que vai usar diferentes campos desse subformulário.

Um grande abraço

Alguém pode me ajudar?

Ola Luis,

No subformulário "frm_SubformulárioContasReceberPagar-1", no combobox "Fianceiro", no evento "Após atualizar" , insira o código abaixo:

Código:


'-- Alexandre Fim - 11/03/2022
'-- Atualização dos campos conforme criterio do combo
Private Sub Financeiro_AfterUpdate()
   
    '1-Caixa / 2-Banco / 3-PagSeguro
   
    If Me.Financeiro.Value = 1 Or Me.Financeiro.Value = 2 Then
        Me.Entradas.Value = Me.ValorDaParcela.Value
        Me.EntradasCaixa.Value = Me.ValorDaParcela.Value
        Me.EntradasReais.Value = Me.ValorDaParcela.Value
    Else
        Me.Entradas.Value = 0
        Me.EntradasCaixa.Value = 0
        Me.EntradasReais.Value = 0
    End If


End Sub



Acredito que seja isso que vc precisa.

[]'s

Alexandre Fim

Ô Alexandre Fim, legal seu interesse. Para mim que tem pouco conhecimento de VBA é difícil explicar o problema.

Na verdade são duas condições IF: Tipo de Movimentação (1=Entrada; 2=Saída) e Financeiro(1=Caixa; 2=Banco; 3=PagSeguro).

Acho que os cenários possíveis são:

1) Se o Financeiro=1 e o Tipo de movimentação=1, os valores do campo [ValorParcelaRecebida] serão "repetidos" nas colunas de Entradas, EntradasCaixa e EntradasReais.

2) Se o Financeiro=1 e o Tipo de movimentação=2, os valores do campo [ValorParcelaRecebida] serão "repetidos" nas colunas de Saídas, SaídasCaixa e SaídasReais.

3) Se o Financeiro=2 e o Tipo de movimentação=1, os valores do campo [ValorParcelaRecebida] serão "repetidos" nas colunas de Entradas, EntradasBanco e EntradasBanco.

4) Se o Financeiro=2 e o Tipo de movimentação=2, os valores do campo [ValorParcelaRecebida] serão "repetidos" nas colunas de Saídas, SaídasBanco e SaídasReais.

5) Se o Financeiro=3 e o Tipo de movimentação=1, os valores do campo [ValorParcelaRecebida] serão "repetidos" nas colunas de Entradas, EntradasPag e EntradasBanco.

4) Se o Financeiro=3 e o Tipo de movimentação=2, os valores do campo [ValorParcelaRecebida] serão "repetidos" nas colunas de Saídas, SaídasPag e SaídasReais.

Se ainda puder me ajudar, Alexandre Fim, agradeço muitíssimo!

Mas onde vc informa/seleciona o Tipo de Movimentação?

Boas.....

Tipo caso de Select case !

Alexandre Fim, eu faço esses registro no frm_ContasReceberPagar. Por favor, 1) abra o frm_ContasReceberPagar; 2) ele vai pedir um parâmetro que é o ID_Operação de alguma de compra ou venda a prazo: eu sugeri que se digitasse 43, porque essa operação está no meu BD e é de uma venda a prazo. 3) Os dados das parcelas estão no subformulário dentro do frm_ContasReceberPagar. 4) Os campos que vou editar quando houver um pagamento/recebimento são DataDeVencimento, ValorDaParcelaRecebida e Financeiro. É no Financeiro que suponho que precise de um código para copiar os dados do ValorDaParcelaRecebida para os campos seguintes, observando as condições TipoDeMovimentação e Financeiro, conforme disse antes.

Eu enviei o banco de dados em uma das postagens anteriores.

Mais uma vez, obrigado, Alexandre Fim.

Me ajudem, por favor!

Olá Luiz,
Agora ficou mais fácil. Vou ajustar o sistema e em seguida disponibilizo aqui.

Obs.: Tem coluna repetida:

3) Se o Financeiro=2 e o Tipo de movimentação=1, os valores do campo [ValorParcelaRecebida] serão "repetidos" nas colunas de Entradas, EntradasBanco e EntradasBanco.

Ate +

Alexandre

Alexandre Fim, tem razão. Eu acabei repetindo.
Na vdd é Entradas, EntradasBanco e EntradasReais se Financeiro = 2 e Tipo_De_Movimentação = 1.

Olá Luiz,

Ao atualizar o combo Financeiro executa a seguinte rotina:

Código:



Private Sub Financeiro_AfterUpdate()
Dim iTipoMov As Integer
    '-- Tipo financeiro - 1-Caixa / 2-Banco / 3-PagSeguro
    '-- Tipo de Movimentação - 1-Entrada / 2-Saida
    
    '-- Carrega variável do tipo de movimentação da operação
    iTipoMov = Nz(DLookup("Tipo_De_Movimentação", "tbl_ContasReceberPagar", "[ID_Operação] = " & Me.ID_Operação & ""), 0)
    
    '-- Executa função com condição concatenada
    Call fnAtualizaCampos(Me.Financeiro.Value & iTipoMov)


End Sub



OBS: O sistema concatena o Tipo Financeiro com o Tipo de Movimentação:
Ex: Tipo Financeiro = 1 / tipo Movimentação = 2 ==> Resultado "12"...Com este resultado, entra como parametro(nMov) na função on o Select Case determina quais os campos devem ser preenchidos.


Função com as devidas condições, conforme tipo financeiro e tipo de movimentação:

Código:


Private Function fnAtualizaCampos(nMov As Integer)

    
    Select Case (nMov)
        
        Case 11
            Me.Entradas.Value = Me.ValorDaParcela.Value
            Me.EntradasCaixa.Value = Me.ValorDaParcela.Value
            Me.EntradasReais.Value = Me.ValorDaParcela.Value
            Me.EntradasBanco.Value = 0
            Me.EntradasPag.Value = 0
        
        Case 12
            Me.Saídas.Value = Me.ValorDaParcela.Value
            Me.SaídasCaixa.Value = Me.ValorDaParcela.Value
            Me.SaídasReais.Value = Me.ValorDaParcela.Value
            Me.SaídasBanco.Value = 0
            Me.SaídasPag.Value = 0
        
        Case 21
            Me.Entradas.Value = Me.ValorDaParcela.Value
            Me.EntradasBanco.Value = Me.ValorDaParcela.Value
            Me.EntradasReais.Value = Me.ValorDaParcela.Value
            Me.EntradasPag.Value = 0
            Me.EntradasCaixa.Value = 0
        
        Case 22
            Me.Saídas.Value = Me.ValorDaParcela.Value
            Me.SaídasBanco.Value = Me.ValorDaParcela.Value
            Me.SaídasReais.Value = Me.ValorDaParcela.Value
            Me.SaídasCaixa.Value = 0
            Me.SaídasPag.Value = 0
        
        Case 31
            Me.Entradas.Value = Me.ValorDaParcela.Value
            Me.EntradasPag.Value = Me.ValorDaParcela.Value
            Me.EntradasBanco.Value = Me.ValorDaParcela.Value
            Me.EntradasCaixa.Value = 0
            Me.EntradasReais.Value = 0
            
        Case 32
            Me.Saídas.Value = Me.ValorDaParcela.Value
            Me.SaídasPag.Value = Me.ValorDaParcela.Value
            Me.SaídasReais.Value = Me.ValorDaParcela.Value
            Me.SaídasCaixa.Value = 0
            Me.SaídasBanco.Value = 0
    End Select


End Function


NOTA: Alguns campos eu coloquei como ZERO, pois se o usuário escolher "Banco", os campos serão preenchidos, mas se ele voltar e escolher "Caixa", os campos referente à "Banco" também estarão preenchidos. Então, devem ser zerados conforme condição. (Acho que é isso...rsss)


É isso.

Se faltar alguma coisa, acredito que é só adaptar a rotina.

Segue versão.

Boa sorte.

[]'s

FIM

Alexandre Fim, acho que é isso. Foi na mosca!

Tinha um repetição no código de uma das saídas que corrigi e tá funcionando muito bem.

Você é o cara! Obrigado viu! Vou testar até amanhã e em seguida volto aqui para posicionar você e o Fórum sobre o resultado da solução.

Um abração.

Blza Luiz..
Boa sorte...
Abs

Alexandre Fim, só mais uma coisinha... Se não for atrapalhar.

Vamos supor que digite o registro errado: que eu apague então o ValorDaParcelaRecebida e o Financeiro. Como poderia voltar os valores para 0 novamente? O que precisaria acrescentar ao código?

Valeu demais. Ficou muito bom. 10 (deizzzzzzzzz)

Luiz,

O que daria pra fazer é incluir um botão no subformulário e, ao clicar, o Access verifica o registro selecionado no grid e aplica valor ZERO nos campos desejados, mas com mensagem de confirmação.

Vou fazer esse ajuste e te mando a versão.

[]'s

FIM

obrigado

Luiz,

A rotina para zerar os valores informados incorretamente está no campo "Valor Recebido".




Ao informar ZERO, entra na rotina abaixo e zera os campos (não sei quais campos são..fica a seu criterio para ajustes):

Código:



Private Sub ValorDaParcelaRecebida_AfterUpdate()


    If Me.ValorDaParcelaRecebida.Value <= 0 Then
        If MsgBox("Os valores informados serão zerados. Deseja prosseguir?", vbQuestion + vbYesNo, "Confirma(S/N)") = vbYes Then
            Me.Entradas.Value = 0
            Me.EntradasCaixa.Value = 0
            Me.EntradasBanco.Value = 0
            Me.EntradasPag.Value = 0
            Me.EntradasReais.Value = 0
            Me.Saídas.Value = 0
            Me.SaídasCaixa.Value = 0
            Me.SaídasBanco.Value = 0
            Me.SaídasPag.Value = 0
            Me.SaídasReais.Value = 0
            Me.Financeiro = ""
        End If
    End If

End Sub



NOTA: Fiz um ajuste no layout do formulário para o grid ficar um pouco mais visível, pois possui muitas colunas. Caso não queira, copie e cole a rotina no formulário original que vai funcionar do mesmo jeito.

NOTA2: Aquele ajuste que vc fez na outra rotina que estava repetido, NÃO ESTÁ contemplado nesta versão. Necessário fazer o ajuste.

Segue versão atualizada

É isso

[]'s

FIM

Cara, vc é incrível: nota 1000. Funcionando legal. Desculpe-me demorar a retornar.

Sobre a repaginação do formulário, não será necessária: todas as colunas de entradas e saídas ficarão ocultas.

Muitíssimo obrigado, Alexandre Fim.

Um grande abraço.

Valeu Luiz....O fórum agradece.
Sucesso !!!!
Abs
FIM