[Resolvido]Aplicar instrução BackColor, ForeColor e SetFocus com um For

Boa tarde pessoal
Estou tentando fazer função para verificar se existem campos vazios através de Array e  For no botão Salvar
Campos:
TxtCidade
TxtProjeto
TxtProdutor
TxtDataEntrega
TxtPeriodo
 
Ao clicar no Botão salvar ele vai percorrer os campos através de um For, se existir algum campo sem preencher ele sai e aponta o campo, com BackColor, ForeColor e SetFocus.
Minha duvida é, como eu aponto o campo através da variável para os comandos BackColor, ForeColor e  SetFocus?

Function FindOut()
ReDim ar(5) As Variant 'Arry


ar(0) = Nz(Me.TxtCidade.Value)
ar(1) = Nz(Me.TxtProjeto.Value)
ar(2) = Nz(Me.TxtProdutor.Value)
ar(3) = Nz(Me.TxtDataEntrega.Value)
ar(4) = Nz(Me.TxtPeriodo.Value)




Dim i As Integer
For i = 0 To 4
    'MsgBox ar(i)
    If ar(i) = "" Then
        MsgBox "Preencha o Campo!", vbInformation, "ATENÇÃO"
        '>>---------> (BackColor)
        '>>---------> (ForeColor)
        '>>---------> (SetFocus)
        Exit Function
    End If
Next


End Function


Sub WarningColor(MyField As Object)
 MyObjectName.BackColor = RGB(0, 0, 156)
 MyObjectName.ForeColor = RGB(250, 250, 0)
End Sub

Código:

Function FindOut()
ReDim ar(5) As Variant 'Arry
Dim i As byte 'alterei o tipo, afinal, byte se encaixa melhor já que nunca haverá mais de vai até 255 campos (integer vai até 32000)

'salvando o nome dos campos ao invés do valor, assim poderei saber o nome do santo, ao invés de só o milagre
ar(0) = "TxtCidade"
ar(1) = "TxtProjeto"
ar(2) = "TxtProdutor"
ar(3) = "TxtDataEntrega"
ar(4) = "TxtPeriodo"

'uma ideia é ter outro loop aqui que reseta a formatação de todos os campos para o normal
'e só depois, conforme abaixo, o loop que muda a formatação

'loop pela matriz
For i = 0 To 4
    'MsgBox ar(i)
    'verificando o valor conforme o nome do campo
    If nz(me(ar(i)).value) = "" Then
        MsgBox "Preencha o Campo " & ar(i) & "!", vbInformation, "ATENÇÃO"
        me(ar(i)).backcolor = vbyellow
        me(ar(i)).forecolor = vbred
        me(ar(i)).setfocus
        Exit Function
    else
        me(ar(i)).backcolor = suacornormal
        me(ar(i)).forecolor = suacornormal
    End If
Next


End Function

Deu Certo Abrigado 

O fórum agradece o retorno. Sucesso.