[Resolvido]Dúvida com Recordset

Boa noite a todos.

Estou iniciando hoje neste foram. Gosto muito de programação a a algum tempo atrás cheguei a criar alguns projetos com Access.
Estou a procura de ajuda para retornar e aprender mais sobre esta ferramenta.

De cara estou com um problema e precisando de ajuda.

O meu programa é uma programa financeiro, e o que eu pretendo neste momento é escrever um código que todas as vezes que eu abrir o formulário principal, caso eu tenha valores a pagar ou receber no dia, abra uma MsgBOX informando "Exisitem títulos a serem liquidados na data de hoje!! "

Escrevi este código:

Dim consulta As String
Dim Novo As Recordset

consulta = "SELECT * FROM tb_teste WHERE vencimento = 'Data' "

Set Novo = CurrentDb.OpenRecordset(consulta) 'Usando o método Open do objeto Recordset.

If bancoVirtual.RecordCount > O Then
MsgBox ("Foram encontrados competidores do Brasil!")
Else
End If
MsgBox ("Não foram encontrados competidores do Brasil!")
End Sub

Mas estou tendo o retorno de erro "13" e não consegui resolver.

Podem me ajudar?

Muito obrigados a todos.

Edison boa noite,

Seja bem-vindo ao fórum !

O erro "13-Type Mismatch" ocorre quando não contém tipos de dados que não são correspondidos corretamente.

Segue código ajustado. Copie e cole

Código:


Public Sub NomeDoSeuProcedimento()
On Error GoTo trata_erro
Dim consulta    As String
Dim Novo        As DAO.Recordset

    consulta = "SELECT * FROM tb_teste WHERE vencimento = #" & Format(Date, "mm/dd/yyyy") & "#"
   
    Set Novo = CurrentDb.OpenRecordset(consulta) 'Usando o método Open do objeto Recordset.
   
    '-- Alexandre Fim ----------------------------------------------
    '-- O recordset bancoVirtual não existe
    'If bancoVirtual.RecordCount > O Then
    '---------------------------------------------------------------

    If Not Novo.EOF Then '-- Se não for o final do arquivo (End Of File)
        MsgBox ("Foram encontrados competidores do Brasil!")
    Else
        MsgBox ("Não foram encontrados competidores do Brasil!")
    End If
   
   
    Novo.Close              '-- fecha recordset
    Set Novo = Nothing      '-- Destroi da memoria
   
    Exit Sub

'-- Tratamento de erro ------------------------------------------------------------------------
trata_erro:
    MsgBox "Erro ocorrido: " & Err.Number & " - " & Err.Description & "", vbCritical, "Erro"
    Exit Sub

End Sub




Tente isso. Acredito que irá funcionar.

Boa sorte

Att,

Alexandre Fim

Oi Alexndre.

Agradeço muito o retorno.

Agora pelo menos não esta dando erro, mas esta ocorrendo o seguinte, a mensagem vem sempre a mesma, independente da situação.

Edison,

Por gentileza, para ficar mais fácil e rápido de resolver, compartilhe aqui uma cópia do seu banco de dados, para melhor análise.

OBS: Na minha assinatura tem um link que ensina a postar anexos no fórum.

É isso

Att,

Alexandre Fim

Alexandre, segue BD conforme me solicitou.

Grato

Edison,

Não veio o anexo.
Verifique

Att,

Alexandre Fim

Segue BD

Edson,
Não veio novamente.

Vaja no link abaixo para postar anexos no forum:

https://www.maximoaccess.com/t32003-como-postar-anexos-e-imagens-no-site-maximoaccess-com


Att,

Alexandre Fim

Segue

Alexandre,

Apenas para facilitar.
Ao abrir o BD, é aberto a MSBOX.
"Foram encontrados valores a pagar ou receber na data de hoje"
referente o código que me enviou.

Fiz um menu suspenso e no botão consultas, ele me traz todos os valores da Tabela ContasReceberPagar na data de hoje.

E na data de hoje não existem valores.

OK?

Edison,

Substitua o código anterior por este:

Código:


Private Sub Form_Open(Cancel As Integer)

On Error GoTo trata_erro
Dim sSQL        As String
Dim rs        As DAO.Recordset

    sSQL = "SELECT COUNT(*) as cnt "
    sSQL = sSQL & " FROM tbl_ContasReceberPagar "
    sSQL = sSQL & " WHERE vencimento = #" & Format(Date, "mm/dd/yyyy") & "#"
   
    Set rs = CurrentDb.OpenRecordset(sSQL) 'Usando o método Open do objeto Recordset.

    If rs("cnt") = 0 Then
        MsgBox "NAO Foram encontrados Valores a Pagar / Receber da nada de hoje!", vbExclamation, "Mensagem"
    Else
        MsgBox "FORAM encontrados valores a pagar ou receber na data de hoje!", vbExclamation, "Mensagem"
    End If
   
   
    rs.Close              '-- fecha recordset
    Set rs = Nothing      '-- Destroi da memoria
   
    Exit Sub

'-- Tratamento de erro ------------------------------------------------------------------------
trata_erro:
    MsgBox "Erro ocorrido: " & Err.Number & " - " & Err.Description & "", vbCritical, "Erro"
    Exit Sub

End Sub



É isso

Att,

Alexandre Fim

Cara Alexandre.

Agradeço muito pela atenção.

Agora está funcionando perfeitamente.


Grande abraço.