[Resolvido]Mascarar Senha

Gostaria de uma ajuda dos amigos do forum que é o seguinte

Uso o seguinte código em um botão para acessar um relatório com senha, gostaria que a senha não aparecesse, fosse mascarada com ***** ao digitaraté.


Dim perguntas As String
On Error GoTo Err_Comando51_Click
Dim Senhas As String
Senhas = "11090" 'senha de acesso
If InputBox(" Digite sua senha de acesso ao relatório.") = Senhas Then
DoCmd.OpenReport "RVendasDiariaPorDataDasVendasAPrazo"
DoCmd.Close acForm, "Senha GNC"
Else
MsgBox "Senha Inválida tente novamente.", vbCritical, "A T E N Ç Â O"
End If
Exit_Comando51_Click:
Exit Sub
Err_Comando51_Click:
MsgBox Err.Description
Resume Exit_Comando51_Clic

Sou grato pela atenção

Poderás, ao invés de usar uma input box um formulário para inserir a senha. E no formulário definir a máscara.

Norbs, é possivel sim, pois tem um exemplo que baixei(procure por MsgBoxEx) aqui no forum que esta assim, mas não consegui fazer no meu.

Naldo
Ponha aqui o seu BD que eu retorno

Recomendo não utilizar senhas predefinidas por código, procure adicionar senhas das tabelas, pois será mais fácil a alteração.

Procurem por inputboxdk que tem alguns tópicos com instruções para colocar máscara de senha em inputbox.

Amigos, através de APIs é possível, pois é com elas que o exemplo do JPaulo funciona.
Vejam o link.
Eu confesso que não sou fã de api's, até mesmo porque, com a nova versão do Windows, elas serão alteradas e teremos que mopdificar nosso código para acompanhar a alteração...

O uso de um formulário é uma boa alternativa para o não uso de api's...

O link do exemplo do JPaulo é esse:

http://maximoaccess.forumeiros.com/t344-login-com-mascara-de-password-na-inputbox?highlight=inputbox

Norbs
Será isto

Tentei usar o exemplo do assis mas da erro, e não consegui adaptar no botão ao clicar e no evento ao abrir o form.
Alguém poderia me dar uma luz de como adptar no meu form.

Sou grato pela atenção de todos

Poste aqui seu aplicativo te tentaremos implementar para você.

Boa noite colega Naldo, tudo tranquilo....eu uso este procedimento em meus bds e funciona.
Assim acrescente este codigo ao abrir do seu relatorio

Private Sub Form_Open(Cancel As Integer)

Dim UsrResposta

UsrResposta = InputBoxDK("Insira a senha para abrir o formulário", "Senha requerida", "Digite sua senha aqui!")
If UsrResposta <> "NaLdO" Then 'este valor entre aspas é a senha
MsgBox "Senha incorreta", vbCritical, "Senha incorreta"
Cancel = True
End If
End Sub

e crie um modulo e salve com o nome de asterisco(pode salvar com outro nome este é sugestão)

Option Compare Database

'Password masked inputbox
'Allows you to hide characters entered in a VBA Inputbox.
'
'Code written by Daniel Klann
'http://www.danielklann.com/
'March 2003

'// Kindly permitted to be amended
'// Amended by Ivan F Moala
'// http://www.xcelfiles.com
'// April 2003
'// Works for Xl2000+ due the AddressOf Operator
'////////////////////////////////////////////////////////////////////

'API functions to be used
Private Declare Function CallNextHookEx Lib "user32" (ByVal hHook As Long, _
ByVal ncode As Long, ByVal wParam As Long, lParam As Any) As Long

Private Declare Function GetModuleHandle Lib "kernel32" Alias "GetModuleHandleA" ( _
ByVal lpModuleName As String) As Long

Private Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" ( _
ByVal idHook As Long, ByVal lpfn As Long, ByVal hmod As Long, ByVal dwThreadId As Long) _
As Long

Private Declare Function UnhookWindowsHookEx Lib "user32" (ByVal hHook As Long) As Long

Private Declare Function SendDlgItemMessage Lib "user32" Alias "SendDlgItemMessageA" ( _
ByVal hDlg As Long, ByVal nIDDlgItem As Long, ByVal wMsg As Long, ByVal wParam As Long, _
ByVal lParam As Long) As Long

Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" (ByVal hwnd As Long, _
ByVal lpClassName As String, ByVal nMaxCount As Long) As Long

Private Declare Function GetCurrentThreadId Lib "kernel32" () As Long

'Constants to be used in our API functions
Private Const EM_SETPASSWORDCHAR = &HCC
Private Const WH_CBT = 5
Private Const HCBT_ACTIVATE = 5
Private Const HC_ACTION = 0

Private hHook As Long

Public Function NewProc(ByVal lngCode As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

Dim RetVal
Dim strClassName As String, lngBuffer As Long

If lngCode < HC_ACTION Then
NewProc = CallNextHookEx(hHook, lngCode, wParam, lParam)
Exit Function
End If

strClassName = String$(256, " ")
lngBuffer = 255

If lngCode = HCBT_ACTIVATE Then 'A window has been activated
RetVal = GetClassName(wParam, strClassName, lngBuffer)
If left$(strClassName, RetVal) = "#32770" Then 'Class name of the Inputbox
'This changes the edit control so that it display the password character *.
'You can change the Asc("*") as you please.
SendDlgItemMessage wParam, &H1324, EM_SETPASSWORDCHAR, Asc("*"), &H0
End If
End If

'This line will ensure that any other hooks that may be in place are
'called correctly.
CallNextHookEx hHook, lngCode, wParam, lParam

End Function

'// Make it public = avail to ALL Modules
'// Lets simulate the VBA Input Function
Public Function InputBoxDK(Prompt As String, Optional Title As String, Optional Default As String, _
Optional Xpos As Long, Optional Ypos As Long, Optional Helpfile As String, _
Optional Context As Long) As String

Dim lngModHwnd As Long, lngThreadID As Long

'// Lets handle any Errors JIC! due to HookProc> App hang!
On Error GoTo ExitProperly
lngThreadID = GetCurrentThreadId
lngModHwnd = GetModuleHandle(vbNullString)

hHook = SetWindowsHookEx(WH_CBT, AddressOf NewProc, lngModHwnd, lngThreadID)
If Xpos Then
InputBoxDK = InputBox(Prompt, Title, Default, Xpos, Ypos, Helpfile, Context)
Else
InputBoxDK = InputBox(Prompt, Title, Default, , , Helpfile, Context)
End If

ExitProperly:
UnhookWindowsHookEx hHook

End Function

O meu exemplo, que o Marcelo lhe passou não funciona ao seu proposito ?

JP, não consegui adaptar seu exemplo sem a tabela.

Boa tarde

Poste aqui o seu BD

Colegas o Naldo esta pedindo o seguinte.
Uso o seguinte código em um botão para acessar um relatório com senha, gostaria que a senha não aparecesse, fosse mascarada com ***** ao digitaraté.

Então Naldo e colegas o exemplo do Assis ou o que passei lhe servirá...
Para isso é só pegar os codigos e colocar no Botão que chama o relatorio ou o que for que chama o relatorio.....ele não precisa de usuario. Precisamos manter o foco do solicitante.....e eliminar as sugestoes por tentativas.....

cafpr, gostaria de resolver com uma sugestão simples e objetiva, esta funcionando corretamente, só estou com o contra tempo para mascarar com os ******.

Sou grato pela atenção de todos

Mais simples e objetiva do que as que já passamos, impossível.
Se você quer máscara na inputbox, deverá usar os códigos já propostos, que por sinal, já estão prontos, para uso...
Algo fora disso, não há como por máscara de outra forma (até onde sei).

Naldo

Pelo que vi tem um formulario chamado "Senha GNC" e é daqui que abre o relatório "RVendasDiariaPorDataDasVendasAPrazo"

Abra o meu form "Senha GNC" e Teste o botão.

A senha --- é 11090

Assis, deu certo por aqui.
Sou muito grato pela atenção de todos.

Que DEUS lhes ilumine.

Obrigado Naldo pelo retorno