[Resolvido]Ignorar parte de um código caso uma condição não seja satisfeita

Olá.

Numa função, utiliza a variável integer j. Durante a execução do código, o número é utilizado para várias divisões.
Em algumas situações, j pode ser igual a zero e, portanto, a divisão irá gerar erro de Divisão por Zero.

Utilizei a condição If ... Then para tentar executar as partes da função com a divisão por j caso a mesma seja igual a zero. Mesmo assim, o VBA faz a verificação.

Quero pular completamente a código parte do código que contenha a divisão por j, e ir diretamente até o fim.

Como posso fazer?

Olá,

O If... Then... Else... deveria resolver.

Tem como postar o código?

O código é muito extenso. Vou por uma parte deles

If j = 0 Then
'TODOS: Horas Extras/Noturnas/Ref.DSR
dblHrsEN = Nz(DSum("CalcDH + DsrDH", "qryMedias(RefDSR)", strWhere1 & "AND Not IsNull(TipoDH)"), 0)
'TODOS: Médias em Moeda + DSR
curMoed1 = Nz(DSum("ValorMoeda + DsrMoeda", "qryMedias(RefDSR)", strWhere1), 0)

Set rs3 = CurrentDb.OpenRecordset("SELECT CodTrabalhador,HrTrabMes,FormaPgto,Contrato " & _
"FROM tblTrabalhador WHERE CodTrabalhador =" & iTrab, dbReadOnly)
'Mensal/Quinzenal (Mensalista/Quinzenalista) = 10
If rs3!FormaPgto = conMQ And rs3!Contrato = conMen Then 'Or rs3!FormaPgto = conMQ And rs3!Contrato = conHor Then
curMoed2 = Nz(DSum("Valor", "qryMedias", strWhere1 & "AND Medias = True"), 0)
dblDias = 0
dblHras = 0
curX = salario(3, iTrab, iComp)
curY = (((salario(5, iTrab, iComp) * dblHrsEN) + curMoed1 + curMoed2) / j)
'MsgBox "Salario = " & salario(5, iTrab, iComp) & Chr(13) & "dblHrsEN = " & dblHrsEN & Chr(13) & _
"curMoed1 = " & curMoed1 & Chr(13) & "curMoed2 = " & curMoed2 & Chr(13) & "j = " & j Exit Function
'Semanal(Horista/Diarista) = 20
ElseIf rs3!FormaPgto = conMQ And rs3!Contrato = conHor Or _
rs3!FormaPgto = conS And rs3!Contrato = conDia Or _
rs3!FormaPgto = conS And rs3!Contrato = conHor Then
curMoed2 = Nz(DSum("Valor + DsrMoeda", "qryMedias", strWhere1 & "AND IsNull(TipoDH)"), 0)
dblDias = Nz(DSum("RefVr1 + DsrDH", "qryMedias", strWhere1 & "AND TipoDH = 'D'"), 0)
dblHras = Nz(DSum("RefVr1 + DsrDH", "qryMedias", strWhere1 & "AND TipoDH = 'H'"), 0)
curX = ((salario(5, iTrab, iComp) * dblHras) + (salario(4, iTrab, iComp) * dblDias)) / j
curY = (((salario(5, iTrab, iComp) * dblHrsEN) + curMoed1 + curMoed2) / j)
'Mensal/Quinzenal/Semanal(Comissionista) = 30
ElseIf rs3!Contrato = conCom Then
curMoed2 = Nz(DSum("Valor + DsrMoeda", "qryMedias", strWhere1 & "AND IsNull(TipoDH)"), 0)
y1 = (curMoed1 + curMoed2) / j 'Base de Cálculo para 13º Salário
y2 = y1 / rs3!HrTrabMes 'Valor Hora
y3 = y2 / 30 'Valor Dia
dblHras = Nz(DSum("RefVr1 + DsrDH", "qryMedias", strWhere1 & "AND TipoDH = 'H'"), 0)
dblDias = Nz(DSum("RefVr1 + DsrDH", "qryMedias", strWhere1 & "AND TipoDH = 'D'"), 0)
curX = y1 + (((dblHrsEN + dblHras) / j) * y2) + ((dblDias / j) * y3)
curY = 0
End If

'Rubricas da Rescisão para cálculo das médias
If Not IsNull(iResci) Then curMedResc = Nz(DSum("Valor", "qryResci_Verbas", "CodRescisao1=" & _
iResci & "AND Medias = True"), 0) / j
End If

Select Case intVal
'Diferente para cada cateroria de trabalhador...
Case 1 'Valor do 13º Salário
mediasDTer = curX
Case 2 'Médias
mediasDTer = curY
Case 3 'Contador de Avos (15 ou mais dias trabalhados): em caso de meses anteriores a dezembro,
'acrescenta a diferença. J é a quantidade de avos calculados
mediasDTer = j + 12 - Month(datFim)
Case 4 'Contador de Avos (15 ou mais dias trabalhados) para Rescisão
mediasDTer = j
Case 5 'Valor das Médias para Rescisão
mediasDTer = curY + curMedResc
End Select

Retire o End If antes de Select Case intVal e passe para a linha após o End Select, ou para o final do código.

Dependendo do código, poderia fazer também:

If j = 0 Then Exit Sub

Mas o código não deveria ser executado somente se j > 0?

Então o teste correto seria:

If j > 0 Then
'seu código

Eu necessito de End If no ponto em que está.
Você estava certo: eu estava cometendo um erro infantil.

If j > 0 Then - ao invés de - If j = o Then.

Peço uma ajuda suplementar: o código me trouxe outro erro inesperado.
Tenho dois Recordsets setados dentro condições If...Then...Else.
Quando elas não são satisfeitas, o Recordset não é setado.
Ao final, utilizo do código (abaixo de End Select)
rsX.close
Set rsX = Nothing

Quando não setando, .close gera erro. Qual a melhor opção para solucionar: apenas apagar rsX.close. Usar apenas Set rsX = Nothing realiza o mesmo procedimento que .close?

rsX.close = Fecha o RecordSet aberto
Set rsX = Nothing = Limpa a memoria

Você deve abrir o RecordSet antes do If, sem problema e depois do ultimo End If, fecha-lo.


Se pretender postar aqui todo o código, fica mais facil de ajudar.

Só uma observação, você sabe que o End If está fechando o If j = 0 e não o If Not IsNull(iResci) , certo?

Complementando o JPaulo, se vc quiser setar o recordset somente dentro do If, deve fechá-lo também dentro do If, normalmente logo antes do End If.

Só uma observação, você sabe que o End If está fechando o If j = 0 e não o If Not IsNull(iResci) , certo?

Sim, Claudio estou ciente.
Usando Close e Nothing antes de End If, os valores calculados dentro da condição If...Then serão chamados mesmo após o fechamento do Recordset. É possível ter um problema com isso?

Abaixo, código completo:

Código:

Function mediasDTer(n As Integer, intVal As Integer, iTrab As Integer, iComp As Date, _
                                                                            Optional iResci As Integer)
    Const conMQ = 1, conS = 3 'Pagamento: Mensal, Quizenal, Semanal
    Const conMen = 1, conHor = 2, conDia = 3, conCom = 4 'Contrato: Mensalista, Horista, Diarista, Comissionista
    Dim rs As DAO.Recordset, rs1 As DAO.Recordset, rs2 As DAO.Recordset, rs3 As DAO.Recordset
    Dim strWhere1 As String, strWhere2 As String, strSQL1 As String, strSQL2 As String
    Dim intMedSind As Integer, intDAfast As Integer, intDias As Integer, datIni As Date, datFim As Date
    Dim datAfIni As Date, datAfFim As Date, i As Integer, j As Integer, dblHras As Double, dblHrsEN As Double
    Dim dblDias As Double, curMoed1 As Currency, curMoed2 As Currency, curMedResc As Currency
    Dim curX As Currency, curY As Currency, y1 As Currency, y2 As Currency, y3 As Currency

    'Médias Sindicais
    intMedSind = Nz(DLookup("MesesMed", "qryMediasSind", "CodTrabalhador =" & iTrab), 0)
    'n=1: Folha de 13º Salário (1ª e 2ª Parcelas, Rescisão)
    If n = 1 Then
        If Month(iComp) >= 3 Then '1º OPÇÃO: Apenas os meses do ano
            If intMedSind > 0 Then
                datIni = DateSerial(Year(iComp), Month(iComp) - (intMedSind - 1), 1)
            Else
                datIni = DateSerial(Year(iComp), 1, 1)
            End If
            datFim = DateSerial(Year(iComp), Month(iComp) + 1, 0)
            strWhere1 = "CodTrabalhador=" & iTrab & " AND Competencia >=" & dataSQL(datIni) & _
                        " AND Competencia <=" & dataSQL(datFim)
            strWhere2 = "CodTrabalhador =" & iTrab & " AND AfastFim >=" & dataSQL(datIni) & _
                        " AND AfastIni <= " & dataSQL(datFim) 'strWhere2 = "CodTrabalhador =" & iTrab & "AND AfastFim >=" & dataSQL(datIni) & "OR CodTrabalhador =" & iTrab & " And AfastIni <= " & dataSQL(datFim)
        Else '2º OPÇÃO: Últimos 03 meses, podendo incluir meses do ano anterior
            datIni = DateSerial(Year(iComp), Month(iComp) - 3, 1)
            datFim = DateSerial(Year(iComp), (iComp) + 1, 0)
            strWhere1 = "CodTrabalhador=" & iTrab & " AND Competencia >=" & dataSQL(datIni) & _
                        " AND Competencia <=" & dataSQL(datFim)
            strWhere2 = "CodTrabalhador=" & iTrab & " AND AfastFim >=" & dataSQL(datIni) & _
                        " AND AfastIni <=" & dataSQL(datFim) '"CodTrabalhador=" & iTrab & "AND AfastFim >=" & dataSQL(datIni) & "OR CodTrabalhador=" & iTrab & "AND AfastIni <=" & dataSQL(datFim)
        End If
    'n=2: Folha Complementar
    ElseIf n = 2 Then
        If intMedSind > 0 Then
            datIni = DateSerial(Year(iComp) - 1, 12 - (intMedSind - 1), 1)
        Else
            datIni = DateSerial(Year(iComp) - 1, 1, 1)
        End If
        datFim = DateSerial(Year(iComp) - 1, 12, 31)
        strWhere1 = "CodTrabalhador=" & iTrab & " AND Competencia >=" & dataSQL(datIni) & _
                    " AND Competencia <=" & dataSQL(datFim)
        strWhere2 = "CodTrabalhador=" & iTrab & " AND AfastFim >=" & dataSQL(datIni) & _
                    " AND AfastIni <=" & dataSQL(datFim) '"CodTrabalhador=" & iTrab & "AND AfastFim >=" & dataSQL(datIni) & "OR CodTrabalhador=" & iTrab & "AND AfastIni <=" & dataSQL(datFim)
    End If
    strSQL1 = "SELECT Competencia,CDias FROM qryFolha13_ContarMes WHERE " & strWhere1
    Set rs1 = CurrentDb.OpenRecordset(strSQL1, dbReadOnly)
   
    'Contar Avos: dias trabalhados no mês menos faltas e dias de afastamento
    j = 0 'Contador inicial para os meses (rs1)
    Do While Not rs1.EOF
        i = 0 'Contador inicial para os meses (rs2)
            strSQL2 = "SELECT * FROM tblTrab_AfastReg WHERE " & strWhere2 & " ORDER BY AfastIni DESC"
            Set rs2 = CurrentDb.OpenRecordset(strSQL2, dbReadOnly)
            Do While Not rs2.EOF
                datAfIni = IIf(rs2!AfastIni < datIni, datIni, rs2!AfastIni)
                datAfFim = IIf(rs2!AfastFim > datFim, datFim, rs2!AfastFim)
                If Format(datAfIni, "mm/yyyy") = Format(rs1!Competencia, "mm/yyyy") Then
                    If Format(datAfIni, "mm/yyyy") = Format(datAfFim, "mm/yyyy") Then
                        intDAfast = Day(datAfFim) - Day(datAfIni) + 1
                    Else
                        intDAfast = Day(DateSerial(Year(datAfIni), Month(datAfIni) + 1, 0)) - Day(datAfIni) + 1
                    End If
                ElseIf Format(datAfFim, "mm/yyyy") = Format(rs1!Competencia, "mm/yyyy") Then
                    intDAfast = Day(datAfFim)
                Else
                    intDAfast = 0
                End If
                i = i + intDAfast
                rs2.MoveNext
            Loop

        intDias = IIf(rs1!cdias - i >= 15, 1, 0) 'MsgBox rs1!Cdias - i
        j = j + intDias
        rs1.MoveNext
    Loop
   
    'Caso a contagem de avos(j) seja zero.
    If j > 0 Then
        MsgBox "yy"
        'TODOS: Horas Extras/Noturnas/Ref.DSR
        dblHrsEN = Nz(DSum("CalcDH + DsrDH", "qryMedias(RefDSR)", strWhere1 & "AND Not IsNull(TipoDH)"), 0)
        'TODOS: Médias em Moeda + DSR
        curMoed1 = Nz(DSum("ValorMoeda + DsrMoeda", "qryMedias(RefDSR)", strWhere1), 0)
           
        Set rs3 = CurrentDb.OpenRecordset("SELECT CodTrabalhador,HrTrabMes,FormaPgto,Contrato " & _
                  "FROM tblTrabalhador WHERE CodTrabalhador =" & iTrab, dbReadOnly)
        'Mensal/Quinzenal (Mensalista/Quinzenalista) = 10
        If rs3!FormaPgto = conMQ And rs3!Contrato = conMen Then 'Or rs3!FormaPgto = conMQ And rs3!Contrato = conHor Then
            curMoed2 = Nz(DSum("Valor", "qryMedias", strWhere1 & "AND Medias = True"), 0)
            dblDias = 0
            dblHras = 0
            curX = salario(3, iTrab, iComp)
            curY = (((salario(5, iTrab, iComp) * dblHrsEN) + curMoed1 + curMoed2) / j)
           
        'Semanal(Horista/Diarista) = 20
        ElseIf rs3!FormaPgto = conMQ And rs3!Contrato = conHor Or _
                                            rs3!FormaPgto = conS And rs3!Contrato = conDia Or _
                                                                rs3!FormaPgto = conS And rs3!Contrato = conHor Then
            curMoed2 = Nz(DSum("Valor + DsrMoeda", "qryMedias", strWhere1 & "AND IsNull(TipoDH)"), 0)
            dblDias = Nz(DSum("RefVr1 + DsrDH", "qryMedias", strWhere1 & "AND TipoDH = 'D'"), 0)
            dblHras = Nz(DSum("RefVr1 + DsrDH", "qryMedias", strWhere1 & "AND TipoDH = 'H'"), 0)
            curX = ((salario(5, iTrab, iComp) * dblHras) + (salario(4, iTrab, iComp) * dblDias)) / j
            curY = (((salario(5, iTrab, iComp) * dblHrsEN) + curMoed1 + curMoed2) / j)
        'Mensal/Quinzenal/Semanal(Comissionista) = 30
        ElseIf rs3!Contrato = conCom Then
            curMoed2 = Nz(DSum("Valor + DsrMoeda", "qryMedias", strWhere1 & "AND IsNull(TipoDH)"), 0)
            y1 = (curMoed1 + curMoed2) / j  'Base de Cálculo para 13º Salário
            y2 = y1 / rs3!HrTrabMes 'Valor Hora
            y3 = y2 / 30 'Valor Dia
            dblHras = Nz(DSum("RefVr1 + DsrDH", "qryMedias", strWhere1 & "AND TipoDH = 'H'"), 0)
            dblDias = Nz(DSum("RefVr1 + DsrDH", "qryMedias", strWhere1 & "AND TipoDH = 'D'"), 0)
            curX = y1 + (((dblHrsEN + dblHras) / j) * y2) + ((dblDias / j) * y3)
            curY = 0
        End If

        'Rubricas da Rescisão para cálculo das médias
        If Not IsNull(iResci) Then curMedResc = Nz(DSum("Valor", "qryResci_Verbas", "CodRescisao1=" & _
            iResci & "AND Medias = True"), 0) / j
    End If
   
    Select Case intVal
        'Diferente para cada cateroria de trabalhador...
        Case 1 'Valor do 13º Salário
            mediasDTer = curX
        Case 2 'Médias
            mediasDTer = curY
        Case 3 'Contador de Avos (15 ou mais dias trabalhados): em caso de meses anteriores a dezembro,
              'acrescenta a diferença. J é a quantidade de avos calculados
            mediasDTer = j + 12 - Month(datFim)
        Case 4 'Contador de Avos (15 ou mais dias trabalhados) para Rescisão
            mediasDTer = j
        Case 5 'Valor das Médias para Rescisão
            mediasDTer = curY + curMedResc
    End Select
    rs1.Close
    rs2.Close
    rs3.Close
    Set rs1 = Nothing
    Set rs2 = Nothing
    Set rs3 = Nothing

Após o fechamento do Recordset, não poderá referenciar o mesmo.
Mas se estiver usando outras variáveis, poderá referenciá-las sem problemas.

Por exemplo:

Código:

Dim varTeste
If ... Then
    Set rs = CurrentDb.OpenRecordset("abc")
    varTeste = rs!Campo
    rs.Close
    Set rs = Nothing
End If

Após o End If, poderá usar varTeste, mas não poderá usar rs!Campo.

Ok, compreendi.
Muito obrigado pela ajuda.