[Resolvido]Não permite campo vazio

Boa tarde pessoal, venho aqui solicitar a ajuda de vocês mais uma vez, preciso de um modulo ou uma solução em que não permita campo vazio ao salvar os dados preenchido em um formulário, detalhes preciso chamar essa função no botão salvar.

desde ja sou muito grato a todos pela ajuda...

Boa Tarde !

Mas porque usar uma funcao ?


Se que verificar se o campo esta vazio use um If


if Isnull(Caixa de Texto) then
Msgbox"Campo Vazio"
else
Insert into ou update (o que voce desejar)
end if

Caro amigo Rafael, desde já grato pela atenção, mas dessa formar o meu código ficaria muito grande por no formulário tenho 22 campos assim teria que validar todos deixando o código muito grande, por isso é que preciso de um modulo e dessa forma só precisaria chamar a função no botão salvar do formulário.

Boa noite Bred, tente esse modulo

Public Function CpoExigido(ByVal UmForm As Form) As Boolean

Dim ctl As Control
Dim Num As Integer

On Error GoTo Err_CpoExigido

CpoExigido = False
Num = 0
For Each ctl In UmForm
If ctl.ControlType = acTextBox Or ctl.ControlType = acComboBox Then
If ctl = "" Or IsNull(ctl) Then
Num = 1
Exit For
End If
End If
Next ctl
If Num = 1 Then
MsgBox "O campo " & ctl.Name & " está vazio." & vbCr & _
"Verifique e preencha.", _
vbInformation, "Faltam dados..."
CpoExigido = True
Else
CpoExigido = False
End If

Exit_CpoExigido:
On Error Resume Next
If Not (ctl Is Nothing) Then
Set ctl = Nothing
End If
Exit Function

Err_CpoExigido:
Select Case Err
Case 0
Resume Next
Case Else
MsgBox Err.Description, vbInformation, "Erro: " & CStr(Err.Number)
End Select
End Function

Para chamar a função no evento antes de atualizar do Form.

Private Sub Form_BeforeUpdate(Cancel As Integer)
If CpoExigido(Me) Then Cancel = -1
End Sub

Fernando muito obrigado parceiro....... era isso mesmo que estava procurando, serviu como uma luva,. muito grato pela ajuda meu grande amigo.....

É isso ai meu amigo, obrigado pelo retorno..