[Resolvido]Filtrar vários campos

Olá. Tenho um formulário que filtra um subformulário ao clicar no botão pesquisar. Tem 4 campos para filtrar e apliquei o seguinte código:

Private Sub btn_pesquisa_Click()

Dim Ok As Integer, cadTítulo As String, entCuadroMensaje As Integer
   Dim sFiltro1 As String
   Dim sFiltro2 As String
   Dim sFiltro3 As String
   Dim sFiltro4 As String

   sFiltro1 = "ESPECIALIDADE LIKE'*" & Me.pesquisa_especialidade & "*'"
   sFiltro2 = "LOCALIDADE LIKE'*" & Me.pesquisa_localidade & "*'"
   sFiltro3 = "PAÍS LIKE'*" & Me.pesquisa_país & "*'"
   sFiltro4 = "EMPRESA LIKE'*" & Me.pesquisa_firma & "*'"

If IsNull(Me.pesquisa_especialidade) And IsNull(Me.pesquisa_localidade) And IsNull(Me.pesquisa_país) And IsNull(Me.pesquisa_firma) Then
   DoCmd.Beep
   entCuadroMensaje = vbOKOnly + vbExclamation + vbDefaultButton1
   Ok = MsgBox("Escreva um campo.", vbOKOnly + vbInformation + vbDefaultButton1)
 
ElseIf Not IsNull(Me.pesquisa_especialidade) Or Not IsNull(Me.pesquisa_localidade) Or Not IsNull(Me.pesquisa_país) Or Not IsNull(Me.pesquisa_firma) Then

   Me.subformA.Form.Filter = sFiltro1
   ' Me.subformA.Form.Filter = sFiltro2
   ' Me.subformA.Form.Filter = sFiltro3
   ' Me.subformA.Form.Filter = sFiltro4

   Me.subformA.Form.FilterOn = True

Else
   Me.subformA.Requery
       If Me.subformA ....... Then

                  MsgBox "Não corresponde na base de dados", vbOKOnly + vbInformation + vbDefaultButton1
       End If
End If

End Sub

Contudo se no código tiver filtrar só com um campo , filtra corretamente, com 4 campos no código não funciona, com aviso no Me.subformA.Form.Filter .
Como corrigir?
Alguém sabe completar e corrigir o código caso nada corresponda na base de dados o que se escreveu na pesquisa?

Obrigado

Teste e retorne;

Código:

Private Sub btn_pesquisa_Click()
Dim Ok As Integer, cadTítulo As String, entCuadroMensaje As Integer
Dim strWhere As String

If IsNull(Me.pesquisa_especialidade) And IsNull(Me.pesquisa_localidade) And IsNull(Me.pesquisa_país) And IsNull(Me.pesquisa_firma) Then
  DoCmd.Beep
  entCuadroMensaje = vbOKOnly + vbExclamation + vbDefaultButton1
  Ok = MsgBox("Escreva um campo.", vbOKOnly + vbInformation + vbDefaultButton1)
 
ElseIf Not IsNull(Me.pesquisa_especialidade) Or Not IsNull(Me.pesquisa_localidade) Or Not IsNull(Me.pesquisa_país) Or Not IsNull(Me.pesquisa_firma) Then

If Nz(Me.pesquisa_especialidade, "") <> "" Then
    strWhere = strWhere & "[ESPECIALIDADE] LIKE'*" & Me.pesquisa_especialidade & "*' OR "
End If

If Nz(Me.pesquisa_localidade, "") <> "" Then
    strWhere = strWhere & "[LOCALIDADE] = LIKE'*" & Me.pesquisa_localidade & "*' OR "
End If

If Nz(Me.pesquisa_país, "") <> "" Then
    strWhere = strWhere & "[PAÍS] LIKE'*" & Me.pesquisa_país & "*' OR "
End If

If Nz(Me.pesquisa_firma, "") <> "" Then
    strWhere = strWhere & "[EMPRESA] LIKE'*" & Me.pesquisa_firma & "*' OR "
End If

If strWhere <> "" Then
    strWhere = Left(strWhere, Len(strWhere) - 5) 'Remove os OR extra
    Me.subformA.Form.Filter = strWhere
    Me.subformA.Form.FilterOn = True
Else
    Me.subformA.Form.Filter = ""
    Me.subformA.Form.FilterOn = False
    Me.subformA.Requery
End If
        MsgBox "Não corresponde na base de dados", vbOKOnly + vbInformation + vbDefaultButton1
      End If
End If

End Sub

Olá.
Testei, e tem um End If a mais e deu error 3075.
Se pesquisar madeira dá o aviso       error 3075  erro de sintaxe na cadeia na expressão de consulta '[ESPECIALIDADE] LIKE ' *madeira*'.

Contudo reconfigurei a base de dados.
No formulário PESQUISAR, ao
Private Sub pesquisa_especialidade_Click()
   Me.lista_especialidade.Requery
End Sub
atualiza a lista.

No formulário FILTRAR eliminei o botão pesquisar para ao
Private Sub pesquisa_especialidade_Click()
   Me.subformA.Requery
End Sub
não atualiza o subform.
É imprescindível o botão Pesquisar?

Queria também mudar o botão Exportar para Excel para o formulário FILTAR, mas dá erro em q.SQL = Me.subformA.RowSource
Como corrigir?
Obrigado.

Muita bagunçada ae;

No form FILTRAR;

Código:

Private Sub strFiltra()
Dim strWhere As String

If Nz(Me.pesquisa_especialidade, "") <> "" Then
    strWhere = strWhere & "[ESPECIALIDADE] LIKE '*" & Me.pesquisa_especialidade & "*' AND "
End If

If Nz(Me.pesquisa_localidade, "") <> "" Then
    strWhere = strWhere & "[LOCALIDADE] LIKE '*" & Me.pesquisa_localidade & "*' AND "
End If

If Nz(Me.pesquisa_país, "") <> "" Then
    strWhere = strWhere & "[PAÍS] LIKE '*" & Me.pesquisa_país & "*' AND "
End If

If Nz(Me.pesquisa_firma, "") <> "" Then
    strWhere = strWhere & "[EMPRESA] LIKE '*" & Me.pesquisa_firma & "*' AND "
End If

If strWhere <> "" Then
    strWhere = Left(strWhere, Len(strWhere) - 5) 'Remove os AND extra
    Me.subformA.Form.Filter = strWhere
    Me.subformA.Form.FilterOn = True
    Me.subformA.Requery
Else
    Me.subformA.Form.Filter = ""
    Me.subformA.Form.FilterOn = False
    Me.subformA.Requery
End If
End Sub

Private Sub pesquisa_especialidade_AfterUpdate()
Call strFiltra
End Sub

Private Sub pesquisa_firma_AfterUpdate()
Call strFiltra
End Sub

Private Sub pesquisa_localidade_AfterUpdate()
Call strFiltra
End Sub

Private Sub pesquisa_país_AfterUpdate()
Call strFiltra
End Sub


Para exportar não necessita de abrir querydefs;

http://dl.dropboxusercontent.com/u/771097/CONTACTOS%20base%20de%20dados%20%20-%2032%2664bits%20-%20com%20dados%20-%20v2_ODL.zip

Obrigado, está tudo certo.

segue exemplo, acho que é iso que voce precisa....


Creditos:   Paulo R. Robilotta

Gostava de saber mais sobre o significado dos códigos de access. Há algum livro ou pdf aconselhável?

Alguém podia me ajudar, estou com um problema parecido, mas como meu formulario é muito diferente não sei se é possível adaptar as situações.

Se é eu não consegui.

Hospedei um exemplo la no outro post.

Segue link:

https://www.maximoaccess.com/t26122-como-modificar-o-codigo-pra-pesquisar-em-2-colunas-em-uma-caixa-de-listagem#185391