[Resolvido]Existe alguma tabela com os erros do MS ACCESS?

Boa tarde pessoal! Dessa vez, minha dúvida é meio extranha, pois não vi outros com a mesma, rs.
É o seguinte: ja li um pouco sobre tratamento de erros no VBA, porém, gostaria de saber se existe (e onde conseguir) uma tabela que mostre todos os erros do VBA, como por exemplo: Quando tentamos excluir um registro de uma tabela que está relacionado com outra, da aquele erro ja conhecido "O registro não pode ser excluído pois a tabela "tal" tem regidtros relacionados a ela".
Nessa caso, se houver uma tabela com a descrição do erro e seu número será muito mais fácio tratá-lo e de forma personalizada. Pois poderão haver outros motivos de um registro não poder ser excluído.
Desde ja, grato a todos.

Tratar os erros é essencial

http://allenbrowne.com/ser-23b.html
........................................................

Sub CriarTabelaDeErros()
Dim dbs As Database, tdf As TableDef, fld As Field
Dim rst As Recordset, lngCódigo As Long
Const conErroAplObjeto = "Erro definido pelo aplicativo ou definido pelo objeto"

' Cria tabela Erros com campos NúmeroDoErro e 'DescriçãoDoErro.
Set dbs = CurrentDb

Set tdf = dbs.CreateTableDef("Erros")
Set fld = tdf.CreateField("NúmeroDoErro", dbLong)
tdf.Fields.Append fld
Set fld = tdf.CreateField("DescriçãoDoErro", dbText, 255)
tdf.Fields.Append fld
dbs.TableDefs.Append tdf
' Abre conjunto de registros na tabela Erros.
Set rst = dbs.OpenRecordset("Erros")
' Executa loop pelos primeiros 1000 códigos de erro 'do Visual Basic.
For lngCódigo = 1 To 1000
On Error Resume Next
' Provoca cada um dos erros.

Err.Raise lngCódigo
DoCmd.Hourglass True
' Pula os códigos de erro que geram erros 'definidos pelo aplicativo ou pelo objeto.
If Err.Description <> conErroAplObjeto Then
' Adiciona cada código e seqüência de erro à ' tabela Erros.
rst.AddNew
rst!NúmeroDoErro = Err.Number
rst!DescriçãoDoErro = Err.Description
rst.Update
End If
' Limpa objeto Err.
Err.Clear
Next lngCódigo
' Fecha o conjunto de registros.

rst.Close
DoCmd.Hourglass False
MsgBox "Tabela de erros criada"
End Sub


Boa sorte.

João Rodrigues (JR)

É exatamente isso que eu procurava, muito obrigado mestre Vieira.

Obrigado. Sempre que precisar, estamos aí.