[Resolvido]Renomear arquivo com o nome da Pasta

Boa tarde galera!

Preciso de uma enorme ajuda de vocês.

Vamos la, trabalhava com um sistema que armazenava as notas fiscais conforme salvava o registro para determinado fornecedor.

o grande problema é que criava uma pasta com o código de registro ex: 92892 e dentro desta pasta estava o PDF com o nome de origem.

tendo com base que o código 92892 é um código que ele utilizava para salvar o registro, pensei em colocar o PDF da nota com o mesmo nome, ou seja, eu tenho  no diretório "C:\Documentos\NotasFiscais\" existem varias pastas dentro delas o PDF da nota, preciso de uma forma de renomear o PDF para o mesmo nome da pasta


minha intenção em fazer essa informação que eu conseguirei referenciar o registro convertido para nota fiscal correta.

Obs. cada pasta contem apenas 1 PDF
O nome da Pasta não se repete.

Vê aqui

https://www.maximoaccess.com/t32939-exibir-relatorio-em-formato-pdf

https://www.maximoaccess.com/t8788-resolvidoajuda-com-pdf

https://www.maximoaccess.com/t22148-resolvidocriar-pdf

Bom dia grande toyebom, olhei os exemplos que você mandou ai mas nao consegui encontrar nenhum que tivesse uma correlação...
As vezes pelo fato de eu não conhecer muito a linguagem VB não consegui identificar como que eu utilizaria aqueles códigos para fazer oque eu pedi ajuda, desculpe
alguém pode me mandar um exemplo de como eu deveria fazer para arrumar essa questão?

Bom dia,

A pasta e o pdf já existem e você os renomeará ou você dará os nomes no momento da criação de ambos?

ja existe tanto a pasta quanto o PDF, ai oque eu preciso é buscar o nome da pasta e renomear no PDF
lembrando que só tem 1 PDF dentro de cada pasta

Certo, mais perguntas:

O caminho da pasta é conhecido? Está no local onde seu bd está? Você tem permissões para acessar e alterar a pasta/arquivos? No caso do PDF, o nome do arquivo é conhecido/tem um padrão ou o nome pode variar de uma pasta para outra?

O caminho da pasta é conhecido? SIM
Está no local onde seu bd está? SIM
Você tem permissões para acessar e alterar a pasta/arquivos? Sim
No caso do PDF, o nome do arquivo é conhecido/tem um padrão ou o nome pode variar de uma pasta para outra? O nome dos PDF varia, porem todos começam com essa nomenclatura "LIQUIDACAO_"

Boa tarde,

Coloque isso em um botão ou em uma função, como preferir:

Código:

    Dim strName As String
    Dim strFile As String
    Dim strPath As String
    Dim lngCount As Long
   
    strPath = CurrentProject.Path & "\NFs\" & Me.txtNf & "\"
    strFile = Dir(strPath & "LIQUIDACAO_*.pdf")
    Do While Len(strFile) > 0
        lngCount = lngCount + 1
        strName = txtNf & ".pdf"
       
        Name strPath & strFile As strPath & strName
       
        strFile = Dir
    Loop
   
    MsgBox "Arquivo alterado com sucesso!", vbInformation, "Alteração"

Onde o trecho CurrentProject.Path & "\NFs\" & Me.txtNf & "\" foi um diretório que eu criei aqui para testar. Sendo que o campo txtNf é o campo que contem o número da NF (no seu exemplo 92892) que é o nome da pasta que contém o arquivo pdf. Substitua este trecho pelo caminho correto onde está a pasta da nf.

Abraço.

ja vou testar e lhe falo.

CassioFabre eu testei o comando que voce me mando mas ele rodou porem nao ficou com o nome da pasta, logo eu voltei o mesmo codigo que voce havia passado, se nao for pedir muito estou enviando uma imagem bem como o MDB que eu criei para executar, também nele contem uma tabela onde contem o caminho com o nome de todas as pastas que contem os PDF dentro...
acredito que de para fazer uma busca nas pastas que estao na tabela

o caminho do MDB é: https://www.4shared.com/file/CTJJ3OKhgm/Nota.html
o caminho da imagem é: https://www.4shared.com/photo/ethZ1Hixgm/CaminhoOndeEstaoAsNotas.html

Boa tarde,

Substitua o código do botão pelo abaixo e veja se funciona:

Código:

    Dim rs As Recordset
    Set rs = CurrentDb.OpenRecordset("nota")

    Dim strName As String
    Dim strFile As String
    Dim strPath As String
    Dim lngCount As Long
   
    Do While Not rs.EOF
        strPath = rs!CaminhoNomePasta & "\"
        strFile = Dir(strPath & "LIQUIDACAO_*.pdf")
       
        Do While Len(strFile) > 0
            lngCount = lngCount + 1
            strName = Right(rs!CaminhoNomePasta, 5) & ".pdf"
           
            Name strPath & strFile As strPath & strName
           
            strFile = Dir
        Loop
       
        rs.MoveNext
    Loop

msgbox "Atualização completa!", vbInformation, "Atualização"

CassioFabre, Muito Obrigado Amigo! deu certinho!!!
vc salvou o meu dia!
mais uma vez obrigado a todos do MAXIMOACCESS e em espeical a voce CassioFabre!

CassioFabre, Uma ultima coisa, no MDB que eu anexei na tabela Nota tem um campo NomeNota que eu queria colocar antes do nome do PDF ou então o nome do PDF deveria ficar da mesma forma que o campo NumeroNota

se vc puder você poderia me dizer como que eu faço?

o MDB encontra-se neste caminho: https://www.4shared.com/file/2DeZrdiUgm/Nota__1_.html

Substitua o código que passei pelo seguinte:

Código:

    Dim rs As Recordset
    Set rs = CurrentDb.OpenRecordset("nota")

    Dim strName As String
    Dim strFile As String
    Dim strPath As String
    Dim lngCount As Long
   
    Do While Not rs.EOF
        strPath = rs!CaminhoNomePasta & "\"
        strFile = Dir(strPath & "LIQUIDACAO_*.pdf")
       
        Do While Len(strFile) > 0
            lngCount = lngCount + 1
            strName = rs!NomeNota & Right(rs!CaminhoNomePasta, 5) & ".pdf"
           
            Name strPath & strFile As strPath & strName
           
            strFile = Dir
        Loop
       
        rs.MoveNext
    Loop

msgbox "Atualização completa!", vbInformation, "Atualização"

Certíssimo Obrigadão ai!