[Resolvido]Ir para registro específico de um campo no form

Boa madrugada a todos!

Eu pesquisei aqui no forum dentre outros, mas não encontrei nada específico para o que eu preciso.

- Tenho uma tabela "tblFornecedor", um formulário "frmFornecedor" e um campo "CNPJ";
- Preciso que o formulário vá para o registro onde o Me!txtCNPJ sejá igual ao campo [CNPJ] na tabela. Vejam o código:


Private Sub CNPJ_BeforeUpdate(Cancel As Integer)
   Dim testecnpj, testefornec As String

   testecnpj = Me!CNPJ
   testefornec = Nz(DLookup("[CNPJ]", "tblFornecedor", "[CNPJ]='" & Me!CNPJ & "'"), 0)
   
   If IsNull(Me!CNPJ) Or Me!CNPJ = "" Then
       MsgBox "CNPJ Requerido...", vbInformation, "Aviso"
       Cancel = True
   ElseIf fncCnpjValido(Me!CNPJ) = False Then
       MsgBox "CNPJ inválido...", vbInformation, "Aviso"
       Cancel = True
   ElseIf testefornec <> 0 Then
       If MsgBox("Este fornecedor já está cadastrado, deseja atualizar o cadastro?", _
       vbQuestion + vbYesNo + vbDefaultButton1, "Confirmação") = vbYes Then
         
           'AQUI QUE NÃO ESTOU CONSEGUINDO IR PARA O REGISTRO

           DoCmd.GoToRecord acDataForm, , acGoTo, testecnpj

       Else:
           Cancel = True
       End If
   End If
End Sub

não montei ele mas vê esse

Código:

DoCmd.GoToRecord , , acGoTo, testecnpj


DoCmd.GoToRecord , , acGoTo, testecnpj


Não deu amigo, "Erro em tempo de execução 2498, A expressão que você inseriu corresponde ao tipo de dados errado para um dos argumentos"

Na verdade eu preciso que ao digitar o CNPJ, seja feita uma busca na tabela, se encontrar, abrir o formulario no registro para atualização.

Alguém pode me ajudar?!

Boa noite;
Utilizo dessa forma:

Código:

Dim Tabela As DAO.Recordset
Dim F As String

Set Tabela = Me.RecordsetClone

F = "[SeuCampo]='" & Me.SeuCampo & "'"
    With Tabela
        'verifica se já está cadastrado
        .FindFirst F
        'se encontrou então
        If Not .NoMatch Then
            'Desfaz o registro
            Me.Undo
            MsgBox "Registo repetido", vbCritical, "Atenção"
            'exibe o registro já cadastrado
            Me.Bookmark = .Bookmark
          End If
    End With
    Tabela.Close
 Set Tabela = Nothing


Desculpa a demora para responder, eu estava tentando resolver outras coisas e tinha deixado de lado este form.

Eu estou começando agora e estou tenho muita dificuldade, mas o seu codigo foi perfeito!

Muito Obrigado, Fernando Bueno!

Obg

Tem de marcar o Resolvido

Desculpa, kkkkkk

Está resolvido sim, obrigado"