[Resolvido]Criar modulo para deixar texto em TxtBox em negrito

Prezados boa tarde a todos.

Estou batendo cabeça na criação de um módulo para deixar o texto que está dentro da caixa de texto em negrito ou não, vai depender da vontade do usuário final.

No Evento duplo click da caixa de texto fiz o seguinte...

Código:

Private Sub A1_DblClick(Cancel As Integer)
If Me.A1 <> "" Then
Me.A1.FontBold = True
End If
End Sub

Ao dar um duplo click na caixa de texto...o conteúdo fica em negrito.

Para voltar ao normal, no evento Ao apertar do mouse...

Código:

Private Sub A1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
If Me.A1 <> "" Then
Me.A1.FontBold = False
End If
End Sub

Ao clicar na caixa de texto o mesmo volta ser texto normal.


Porém, são 96 caixas de textos e isso de apenas um formulário ( tenho mais 3 com os mesmos campos ) !!

A nomenclatura vai de: A1 a A16, B1 a B16, C1 a C16.......F1 A F16

E como eu disse, são 4 formulários com os mesmo campos ( nomenclatura iguais ( A1..B1...C1..D1..E1..F1), tabelas distintas ), então temos....96 x 4= 384 caixas de textos.

Há como montar / Desenvolver uma rotina / módulo para isso, para deixar em negrito ou não o conteúdo da caixa de texto ?

Olá Silvio,

Em um módulo, copie e cole a função abaixo:

Código:


Public Function fnFonteBold(nForm As Form)
Dim ctl As Control

    For Each ctl In nForm.Controls
        If TypeOf ctl Is TextBox Then
            ctl.FontBold = True
        End If
       
        If TypeOf ctl Is ComboBox Then
            ctl.FontBold = True
        End If
       
       
        If TypeOf ctl Is ListBox Then
            ctl.FontBold = True
        End If
     
    Next

End Function





E no evento que pretende executar, faça a seguinte instrução:

Call fnFonteBold(Me)

A função irá verificar quais os Tipos de Controles existentes no formulário e ira formatar o texto em negrito.


Espero ter ajudado

Boa sorte

Como eu já tava desenvolvendo o exemplo, resolvi continuar, deixo-o aqui

No evento ao carregar do seu formulário, cole:

Código:

Call fncMontaEventos(Me)

Em um módulo global use o código abaixo
Código principal

Código:

Public Sub fncMontaEventos(frm As Form)

    Dim ctl As Control
    
    For Each ctl In frm.Controls
        If ctl.ControlType = acTextBox Then
            If ctl.Name Like "[A-F][1-9]" Or ctl.Name Like "[A-F]1[0-6]" Then
                ctl.OnDblClick = "=fncNegrita([ActiveControl])"
                ctl.OnMouseDown = "=fncNegrita([ActiveControl],0)"
            End If
        End If
    Next ctl

End Sub

Public Function fncNegrita(ctl As Control, Optional booNegrita As Boolean = True)

    If booNegrita Then
        ctl.FontBold = ctl.Value <> ""
    Else
        ctl.FontBold = False
    End If

End Function

Bom dia Alexandre e Ivan !

Show de bola os dois exemplos

Agradeço o tempo e a boa vontade em me auxiliar.

Abraços

Silvio bom dia,
Obrigado pelo retorno.
Sucesso.

Valeu IvanJr.

Sucesso, Silvio.
Sucesso, Alexandre.

Em tempo...

Subi o mesmo para o repositório de exemplos aqui do fórum.