[Resolvido]Consulta Acréscimo para duas tabelas Pai e Filho

Pessoal boa tarde,

eu preciso muito de ajuda nesse caso! O que estou tentando fazer é automatizar as solicitações de reposição de estoque.

Por exemplo:

eu tenho uma lista de materiais em meu depósito e temos determinado a quantidade mínima de cada item. Ao atingir o estoque mínimo ou zerar o estoque queria gerar uma solicitação de compra para repor esses itens identificado. Meu problema não está no critério de reposição, mas como gerar esse acréscimo nas tabelas "solicitação de compras" e "Itens Solicitação" uma vez que eles possuem relacionamento Pai-Filho.

Seria mais ou menos assim:

Estoque

Item   Mínimo  Saldo Atual   Reposição
x            3             1                  2
y            4             5                  0
z            10            8                 2


Ai identificando o quanto preciso comprar através da variavel "Reposição", queria criar uma solicitação com os itens de acordo com o critério.


*Tabela Solicitações de compra*

Nova solicitação nº: 00441
                       data: xx/xx/xxxx
                      Área: xxxxxxxxx

*Tabela Itens Solicitação*

Itens Solicitação

Solicitação   Item      quantidade
00441            x                2
00441            z                 2


Como que eu posso gerar esse acréscimo? Criar um novo registro na tabela "Solicitação de Compras" e na tabela "Itens Solicitações" e não perder esse vínculo?

Obrigado a todos desde já.

Uma ação que deve disparar outra? Caso clássico de triggers/macros de dados.

Se outro usuário não montar um exemplo até amanhã, montarei um exemplificando.

Pessoal alguma ajuda quanto a minha?

Por não conhecer sua estrutura, achei mais prático montar um exemplo com recordset. Deixo em anexo

Código do botão que gera solicitação

Código:

Dim objRSEstoque As DAO.Recordset
    Dim objRSTemp As DAO.Recordset
    Dim lngNumGerado As Long
   
    Rem abrindo a tabela estoque filtrando os itens em que a reposicao é maior que 0
    Rem além de tabela, a origem destes dados pode ser uma consulta
    Set objRSEstoque = CurrentDb.OpenRecordset("select item, reposicao from Estoque where reposicao > 0;", 8, 4)
   
    Rem se existem registros
    If Not objRSEstoque.EOF Then
   
        Rem abro a tabela solicitação de compras
        Set objRSTemp = CurrentDb.OpenRecordset("Solicitação de Compras", , 8)
       
        Rem preparo a inserção de um registro
        Call objRSTemp.AddNew
       
            Rem caso as informações
            objRSTemp("ddata").Value = Date
            objRSTemp("area").Value = "Automatico"
           
            Rem salvo o id gerado em uma variável
            lngNumGerado = objRSTemp("id").Value

        Rem salvo o registro
        Call objRSTemp.Update
       
       
        Rem fecho a tabela solicitações
        Call objRSTemp.Close: Set objRSTemp = Nothing
       
        Rem abro a tabea itens solicitação
        Set objRSTemp = CurrentDb.OpenRecordset("Itens Solicitação", , 8)
   
        Rem marco o inicio de um loop
        Do
       
            Rem preparo a inserção de um novo registro
            objRSTemp.AddNew
                Rem caso as informações
                objRSTemp("solicitação").Value = lngNumGerado
                objRSTemp("item").Value = objRSEstoque("item").Value
                objRSTemp("quantidade").Value = objRSEstoque("reposicao").Value
            Rem salvo o registro
            Call objRSTemp.Update
       
            Rem vou para o próximo item da tabela estoque que abri filtrada
            Call objRSEstoque.MoveNext
       
        Rem marco o fim do loop
        Rem enquanto não ler todos os registros da tabela estoque que abri filtrada
        Loop Until objRSEstoque.EOF
       
        Rem fecho a tabela itens
        Call objRSTemp.Clone: Set objRSTemp = Nothing
   
    End If
   
    Rem fecho a tabela estoque
    Call objRSEstoque.Close: Set objRSEstoque = Nothing

Ivan muito obrigado era exatamente isso que eu estava precisando!

Tópico resolvido!

O fórum agradece o retorno. Sucesso.