[Resolvido]Enviar SMS com Pushbullet

Olá,

Encontrei a solução abaixo para enviar SMS com o API do Pushbullet.
Alguém sabe converter isso num modulo VBA?

dirceuresende.com/blog/como-utilizar-a-api-do-pushbullet-para-enviar-torpedos-sms-no-c-php-java-ou-pelo-sql-server-com-clr


Acredito que esse codigo de arquivo json deve ser o caminho mais fácil:
(texto do link acima)

O comando padrão para enviar SMS pelo cURL é esse:

Código:

curl --header "Access-Token: seu_access_token" --header "Content-Type: application/json" --request POST -k --data-binary @"C:\Users\dirceu\Desktop\push_message.json" https://api.pushbullet.com/v2/ephemerals



push_message.json

{
 "push": {
   "conversation_iden": "+5566677778888",
   "message": "Teste de Mensagem com cURL",
   "package_name": "com.pushbullet.android",
   "source_user_iden": "seu_token_usuario",
   "target_device_iden": "seu_token_dispositivo",
   "type": "messaging_extension_reply"
 },
 "type": "push"
}

No comando cURL utilizei um arquivo externo (push_message.json) para armazenar as informações da solicitação que vou enviar. Você pode fazer com que a sua linguagem de programação crie esse arquivo em tempo de execução, utilize o caminho do arquivo recém criado no parâmetro –data-binary e apague-o após a execução.

Acredito que essa solução através do cURL é bem genérica e pode ser utilizada por qualquer linguagem de programação que te permita executar arquivos binários no servidor, seja C#, PHP, Java, Ruby, etc.

Então... na minha saga, consegui fazer o access mandar SMS pelo pushbullet...

Tenho um código que funciona num botão.
Esse botão compila o arquivo json, e executa o comando num bat.

Mas quando eu jogo o mesmo código em uma Function, não funciona por nada desse planeta.
Diz que não encontra a função.

????

O que eu preciso é:

abrir o formulario: movimento
verificar a caixinha (sim/não) do sms: se sim, enviar o sms (aquela função que não roda), e depois desmarcar a caixinha.

se não, ir ao próximo registro.

E fazer isso do primeiro ao ultimo registro.

O form chama MOVIMENTO
O campo sim/não chama SENDSMS

O código que roda no comando de clique do botão (que eu não consigo fazer funcionar como função) é:
>>> quando eu coloco o codigo em uma Private Function dentro do form MOVIMENTO (lá no visual basic) ele não acha a function... quando eu coloco em um módulo extra, ele acha a função, mas não acha as strings.. diz q nao reconheceu o Texto165, e daí pra frente se eu for tirando, é o mesmo erro.
>>> todas as strings são campos do form movimento

Código:

Private Sub Comando113_Click()

Dim str01 As String
Dim str02 As String
Dim str03 As String
Dim str04 As String
Dim str05 As String
Dim str06 As String
Dim str07 As String
Dim str08 As String
Dim str09 As String
Dim str10 As String
Dim str11 As String
Dim str12 As String
Dim str13 As String
Dim str14 As String
Dim str15 As String

str01 = Texto165
str02 = Texto167
str03 = Texto168 & SMSphone & Texto169
str04 = SMSphone
str05 = Texto169
str06 = Texto170 & SMSmessage & Texto178
str07 = SMSmessage
str08 = Texto178
str09 = Texto171
str10 = Texto173
str11 = Texto174
str12 = Texto175
str13 = Texto176
str14 = Texto177
str15 = Texto172

Open "F:\bd\pushmessage.json" For Output As #1
   Print #1, str01; ""
   Print #1, str02; ""
   Print #1, str03; ""
   Print #1, str06; ""
   Print #1, str09; ""
   Print #1, str10; ""
   Print #1, str11; ""
   Print #1, str12; ""
   Print #1, str13; ""
   Print #1, str14; ""
   Print #1, str15; ""
  
Close #1

Call Shell("F:\File\[ SoldiHamann ADV ]\[ SOCIEDADE SOLDIHAMANN ]\DB BP\bat\strcm.bat", 1)

End Sub



Já me falaram (o santo Ivan que tem me ajudado) pra fazer com recordset, mas essa pessoa loira que vos escreve não teve discernimento para conseguir compilar algo que não explodisse o computador de tanto erro.

Olá Anna,

Uma vez que já consegue mandar uma mensagem, será melhor partilhar a base de dados:para se
testar:

a) a parte enviar com botão (que funciona)
b) Parte que está adaptar e que não funciona a function.

Assim fica mais fácil para ajudar.

Abraço

Segue abaixo anexo para download.

O comando roda, no form MOVIMENTO, no botão send SMS

Preciso que o codigo no botao (Comando 113) seja executado numa macro, e que ele pesquise os registros em movimento que tenham a caixinha de SendSMS clicada como verdadeira, e depois que enviar a msg, tirar o clique dali, salvar, e passar pro proximo registro, e refazer.

Algo assim:

Open form movimento no 1º registro
Se SendSMS = verdadeiro então
executar codigo (o cod do comando 113), e depois atualizar o sendsms para falso, daí ir ao proximo registro
senão ir ao próximo registro e verificar se sendsms = verdadeiro

e assim fazer em tds os registros.

Olá Anna,

O "tratamento" que tem nas caixas de texto (configurar campos e remover acentuação) poderia ser em código, mais fácil e vai ser assim.
Na minha opinião, a solução vai na origem dos dados a processar ser filtrado por uma consulta (sendsms = vrdadeiro) com os restantes campos necessários ("conversation_iden", "message"), creio que o restante será sempre igual.


Confirme se é isso.

Depois será fazer como já referiu, via recordeset correr os registos (já filtrados e prontinhos da consulta).
A unica questão via ser como aplicação se vai comportar com o "disparo" da shell com o "batch.
Mas uma coisa de cada vez.

Só vou dar seguimento na segunda feira, se algum colega quiser ajudar, toda ajuda é bem-vinda.

Abraço

O problema de fazer tudo isso é que eu não sei programar.. rs

Usei um bat porque tive problema com as aspas do codigo
Usei os campos (pra concatenar e remover acentuação) porque é o que eu sei fazer rsrs aí ele exporta o json direitinho

Já sobre usar consulta...

Eu não consegui fazer o SMS funcionar dessa forma.
Preciso do form aberto (o que dificulta o recordset, pelo que li), e ele envia o que está naquele registro.

O ideal seria:

abrir o form no 1º registro
verifica se está para enviar o sms (sim/nao)
se sim, enviar e desmarcar
se não, avançar ao proximo registro

aí refazer isso até o ultimo registro.

O bat e o json nao funcionam sem a tela aberta do registro da mensagem a ser enviada.

Olá Anna,

Compreendo, mas aos poucos vai aprender, está no fórum certo

Não confirmou-se minha questão da mensagem anterior sobre os campos que alteram.

Pergunto ainda:

A) pode partilhar o bat
B) sabe se o ficheiro Json pode ter todas as mensagens a enviar num só ficheiro de uma só vez? Se sim, partilhe exemplo com dois ou mais registos para se verificar a "formatação"

Abraço

Oi!

Ainda não consegui resolver.
O bat só faz abrir o CMD e executar o comando de enviar o json

Necessário ser um único Json por sms.

Usei as orientações do Dirceu
dirceuresende.com/blog/como-utilizar-a-api-do-pushbullet-para-enviar-torpedos-sms-no-c-php-java-ou-pelo-sql-server-com-clr/

O código no CMD que o bat roda é:

Código:

curl --header "Access-Token: seu_access_token" --header "Content-Type: application/json" --request POST -k --data-binary @"C:\Users\dirceu\Desktop\push_message.json" https://api.pushbullet.com/v2/ephemerals


Só consigo enviar um sms por vez mesmo...

Olá,

Obrigado pela informação, esse tópico está muito bem explicado.
Quanto à documentação da API, podemos encontrar aqui:
docs.pushbullet.com

Se tiver um tempinho vou fazer um exemplo para correr o resgistos para gerar de uma só vez para os "marcados"

Não confirmou foi a minha questão da mensagem nº 5, (a informação que altera registo a registo, exemplificada a vermelho).

Abraço

Não entendi a dúvida... acho que já bati tanto a cabeça com isso que to lerda.. rsrs

Olá,



Pergunto se a "informação" que altere em função de cada registo que é para enviar SMS (torpedo) é a que está assinalada a vermelho.
Qual os campos a que corresponde da tabela.

Abraço

Entendi.

Esse texto é o JSON.

Ele é gerado assim:

Código:

Public Sub Comando113_Click()

Dim str01 As String
Dim str02 As String
Dim str03 As String
Dim str04 As String
Dim str05 As String
Dim str06 As String
Dim str07 As String
Dim str08 As String
Dim str09 As String
Dim str10 As String
Dim str11 As String
Dim str12 As String
Dim str13 As String
Dim str14 As String
Dim str15 As String


str01 = Texto165
str02 = Texto167
str03 = Texto168 & SMSphone & Texto169
str04 = SMSphone
str05 = Texto169
str06 = Texto170 & SMSmessage & Texto178
str07 = SMSmessage
str08 = Texto178
str09 = Texto171
str10 = Texto173
str11 = Texto174
str12 = Texto175
str13 = Texto176
str14 = Texto177
str15 = Texto172


Open "F:\File\[ SoldiHamann ADV ]\[ SOCIEDADE SOLDIHAMANN ]\DB BP\bat\json\pushmessage.json" For Output As #1
   Print #1, str01; ""
   Print #1, str02; ""
   Print #1, str03; ""
   Print #1, str06; ""
   Print #1, str09; ""
   Print #1, str10; ""
   Print #1, str11; ""
   Print #1, str12; ""
   Print #1, str13; ""
   Print #1, str14; ""
   Print #1, str15; ""
  
Close #1


Call Shell("F:\File\[ SoldiHamann ADV ]\[ SOCIEDADE SOLDIHAMANN ]\DB BP\bat\strcm.bat", 1)

End Sub


Os campos estão no form Movimento (a maioria deles bem miudinho, escondido, só pra fazer o arquivo gerar o codigo mesmo)

O telefone ele pega do campo SMSphone
A mensagem do campo SMSmessage

Aí exporta tudo desse jeito, e o bat roda o codigo de enviar...

Eu sei que está parecendo um frankenstein meu codigo.. rs
Mas é que eu não sei fazer, e fui fazendo na unha mesmo...

(lembrando que aqui é uma advogada criando uma solução em vba)

Olá Anna,

Está no fórum certo para aprender.
A solução pode ser via recordset correr registo a registo e gerar o ficheiro para chamar.
Estou sem tempo de momento, mas uma vez que disponibilizou a sua base, assim que me seja possivel irei fazer exemplo.
Se algum colega aqui do fórum tiver com mais disponibilidade toda a ajuda é bem-vinda.

Abraço

Eu já tentei fazer esse recordset... confesso que não consegui de jeito nenhum....

O simples, será fazer primeiro uma consulta, já a filtrar apenas os que são para enviar.
Veja este tópico (para estudar):
https://www.maximoaccess.com/t31608-resolvidofor-each-while-ou-for-to-formulario-continuo

Não ficará esquecido, mas estou sem PC com Access a fazer outras tarefas.

Abraço

Olá Anna,

No seu projeto (pode ser no disponibilizou) onde tem:

Código:

Private Sub Comando113_Click()

Dim str(1 To 15) As String

str01 = Texto165
str02 = Texto167
str03 = Texto168 & SMSphone & Texto169
str04 = SMSphone
str05 = Texto169
str06 = Texto170 & SMSmessage & Texto178
str07 = SMSmessage
str08 = Texto178
str09 = Texto171
str10 = Texto173
str11 = Texto174
str12 = Texto175
str13 = Texto176
str14 = Texto177
str15 = Texto172

Open "F:\File\[ SoldiHamann ADV ]\[ SOCIEDADE SOLDIHAMANN ]\DB BP\bat\json\pushmessage.json" For Output As #1
   Print #1, str01; ""
   Print #1, str02; ""
   Print #1, str03; ""
   Print #1, str06; ""
   Print #1, str09; ""
   Print #1, str10; ""
   Print #1, str11; ""
   Print #1, str12; ""
   Print #1, str13; ""
   Print #1, str14; ""
   Print #1, str15; ""
  
Close #1

Call Shell("F:\File\[ SoldiHamann ADV ]\[ SOCIEDADE SOLDIHAMANN ]\DB BP\bat\strcm.bat", 1)

End Sub

Altere por:

Código:

Private Sub Comando113_Click()
'ahteixeira 2019 maximoaccess
    Open "F:\File\[ SoldiHamann ADV ]\[ SOCIEDADE SOLDIHAMANN ]\DB BP\bat\json\pushmessage.json" For Output As #1
       Print #1, "{"
       Print #1, Space(2) & Chr(34) & "push" & Chr(34) & ": {"
       Print #1, Space(4) & Chr(34) & "conversation_iden" & Chr(34) & ": " & Chr(34) & "+" & Texto86 & Chr(34) & ","
       Print #1, Space(4) & Chr(34) & "message" & Chr(34) & ": " & Chr(34) & "Proc. " & Me.Combinação40 & " | " & Texto195 & " | push @username" & Chr(34) & ","
       Print #1, Space(4) & Chr(34) & "package_name" & Chr(34) & ": " & Chr(34) & "com.pushbullet.android" & Chr(34) & ","
       Print #1, Space(4) & Chr(34) & "source_user_iden" & Chr(34) & ": " & Chr(34) & "xxxx_user_ident" & Chr(34) & ","
       Print #1, Space(4) & Chr(34) & "target_device_iden" & Chr(34) & ": " & Chr(34) & "xxxxxx_device_iden" & Chr(34) & ","
       Print #1, Space(4) & Chr(34) & "type" & Chr(34) & ": " & Chr(34) & "messaging_extension_reply" & Chr(34)
       Print #1, Space(2) & "}" & ","
       Print #1, Space(2) & Chr(34) & "type" & Chr(34) & ": " & Chr(34) & "push" & Chr(34)
       Print #1, "}"
    Close #1
    
    Call Shell("F:\File\[ SoldiHamann ADV ]\[ SOCIEDADE SOLDIHAMANN ]\DB BP\bat\strcm.bat", 1)
End Sub

e teste se continua a funcionar.

Caso funcione os cmpos que tem ao lado direito pode eliminar e estudar.
Será a partir deste código que será feito via recordset.

Abraço

Funcionou.

Fiz uma alteração (o meu db tinha sofrido alterações desde o exemplo, e corrigi o nome dos campos SMSphone e

Código:

Private Sub Comando113_Click()
'ahteixeira 2019 maximoaccess
    Open "F:\File\[ SoldiHamann ADV ]\[ SOCIEDADE SOLDIHAMANN ]\DB BP\bat\json\pushmessage.json" For Output As #1
       Print #1, "{"
       Print #1, Space(2) & Chr(34) & "push" & Chr(34) & ": {"
       Print #1, Space(4) & Chr(34) & "conversation_iden" & Chr(34) & ": " & Chr(34) & "+" & SMSphone & Chr(34) & ","
       Print #1, Space(4) & Chr(34) & "message" & Chr(34) & ": " & Chr(34) & SMSmessage & Chr(34) & ","
       Print #1, Space(4) & Chr(34) & "package_name" & Chr(34) & ": " & Chr(34) & "com.pushbullet.android" & Chr(34) & ","
       Print #1, Space(4) & Chr(34) & "source_user_iden" & Chr(34) & ": " & Chr(34) & "x" & Chr(34) & ","
       Print #1, Space(4) & Chr(34) & "target_device_iden" & Chr(34) & ": " & Chr(34) & "x" & Chr(34) & ","
       Print #1, Space(4) & Chr(34) & "type" & Chr(34) & ": " & Chr(34) & "messaging_extension_reply" & Chr(34)
       Print #1, Space(2) & "}" & ","
       Print #1, Space(2) & Chr(34) & "type" & Chr(34) & ": " & Chr(34) & "push" & Chr(34)
       Print #1, "}"
    Close #1
    
    Call Shell("F:\File\[ SoldiHamann ADV ]\[ SOCIEDADE SOLDIHAMANN ]\DB BP\bat\strcm.bat", 1)
    
Call CurrentDb.Execute("update movimento set SendSMS = false")

End Sub


Esse último comando que eu coloquei (Call CurrentDb.Execute("update movimento set SendSMS = false")) nem sempre funciona...
é para depois de enviar o sms, remover o clique no SendSMS

Olá Anna,

Já entendeu como funciona, com base nesse codigo irei demonstrar como fazer para todos.

Quanto à ultima questão, não devemos misturar perguntas, mas tente :
SendSMS = false
me.requery

Abraço

Olá Anna,

Estou de volta a preparar o prometido.
Estava a ver o código e o que você tinha feito e não incluí o tratamento de acentaução.
É necessário remover a acentuação, ou está a funcionar bem.

Abraço

No meu cod eu fiz o tratamento da acentuação com aqueles 500 campos que vc viu rs
É que SMS nao aceita acentos

Olá Anna, foi esquecimento,

Muito bem, vamos já corrigir isso:
1) Copie o código da mensagem nº 2 partilhada pelo colega chsestrem no tópico abaixo:
https://www.maximoaccess.com/t17659-retirar-acentuacao-de-uma-tabela-preenchida

2) Crie um Módulo novo, pode dar o nome mod_retiraAcentos e cole o código copiado, salve o modulo.

3) Onde queremos retirar os acentos, fazemos a chamada da função TiraAcento([CampoQueTemAcentos])

No seu caso no código da mensagem n. 17, onde tem:

Print #1, Space(4) & Chr(34) & "message" & Chr(34) & ": " & Chr(34) & SMSmessage & Chr(34) & ","

altere por:

Print #1, Space(4) & Chr(34) & "message" & Chr(34) & ": " & Chr(34) & TiraAcento(SMSmessage) & Chr(34) & ","

e teste

Abraço

Testado. Funcionou!

Olá Anna,

Tive que fazer uma ligeira alteração no formulario "movimento" de forma a gravar na tabela os campos SMSphone e SMSmessage.
Também criei um botão para quando está a criar um registo preencher automaticamente os valores pre-definidos que podem ser alterados.

Criei uma consulta (qyr_movimentos_sms) com os dados prontinhos para usar no Recordset, poderia ser diretamente no código, mas assim creio ficar mais fácil para alteração e estudo.
Para o envio, criei um formulario (frm_EnviarSMS) com o seguinte código no botão:

Código:

Private Sub cmdEnviarSMS_Click()

    Dim DB As DAO.Database
    Dim RS As DAO.Recordset
    Set DB = CurrentDb
            
    Set RS = DB.OpenRecordset("qyr_movimentos_sms")     'abre a consulta previamente criada
    
    If RS.RecordCount = 0 Then                          'se não encontra registos avisa e sai
        MsgBox "Nao existe registos para processar.", vbInformation, ""
        Exit Sub
    End If
    
    RS.MoveFirst                                        'coloca-se no 1º registro

    Do While Not RS.EOF                                 'percorre todos os registros
    
        '-----------inicio do que ja fazia individualmente----------------
        Open "F:\File\[ SoldiHamann ADV ]\[ SOCIEDADE SOLDIHAMANN ]\DB BP\bat\json\pushmessage.json" For Output As #1
           Print #1, "{"
           Print #1, Space(2) & Chr(34) & "push" & Chr(34) & ": {"
           Print #1, Space(4) & Chr(34) & "conversation_iden" & Chr(34) & ": " & Chr(34) & "+" & RS("SMSphone") & Chr(34) & ","
           Print #1, Space(4) & Chr(34) & "message" & Chr(34) & ": " & Chr(34) & TiraAcento(RS("SMSmessage")) & Chr(34) & ","
           Print #1, Space(4) & Chr(34) & "package_name" & Chr(34) & ": " & Chr(34) & "com.pushbullet.android" & Chr(34) & ","
           Print #1, Space(4) & Chr(34) & "source_user_iden" & Chr(34) & ": " & Chr(34) & "xxxx_user_iden" & Chr(34) & ","
           Print #1, Space(4) & Chr(34) & "target_device_iden" & Chr(34) & ": " & Chr(34) & "xxxx__device_iden" & Chr(34) & ","
           Print #1, Space(4) & Chr(34) & "type" & Chr(34) & ": " & Chr(34) & "messaging_extension_reply" & Chr(34)
           Print #1, Space(2) & "}" & ","
           Print #1, Space(2) & Chr(34) & "type" & Chr(34) & ": " & Chr(34) & "push" & Chr(34)
           Print #1, "}"
        Close #1
    
        Call Shell("F:\File\[ SoldiHamann ADV ]\[ SOCIEDADE SOLDIHAMANN ]\DB BP\bat\strcm.bat", 1)
        '-----------Fim do que ja fazia individualmente----------------
        
        DoEvents                                        'manda executar eventos
        
        RS.Edit                                         'edita registo
        RS("SendSMS") = False                           'muda SendSMS para falso
        RS.Update                                       'atualiza registo
        RS.MoveNext                                     'move para proximo registo
    Loop
        
    RS.Close: Set RS = Nothing                          'fecha recordeset e limpa da memoria
    DB.Close: Set DB = Nothing                          'fecha base dados e limpa da memoria

    MsgBox "Envio concluido!", vbInformation, ""
End Sub

Segue o meu teste:
cld.pt/dl/download/9099bb66-30ba-4f6d-a55f-3f309900ae00/SoldiHamannDB_rev.zip

Abraço

Resolvido!

Assim que tiver um tempinho eu vou fazer um manual e colocar no repositório!

Muito obrigada a quem dispôs de um tempinho para me ajudar!

Olá Anna,

Obrigado pelo retorno, o fórum agradece.

Abraço

olá. seria possivel disponibilizar o arquivo pra gente?

Vamos aos códigos:


Constantes:

localW é a pasta onde meus arquivos estão no computador

Public Const localW As String = indicar a pasta que quiser onde estarão meus arquivos
Observe que dentro dessa pasta devo ter uma pasta chamada SYS\JSON onde os arquivos e JSON e BAT do código serão salvos

PUSHBULLET strings
Public Const accessT As String = "00000"
Public Const userId As String = "0000000"
Public Const userDev As String = "00000"

Para saber como conseguir essas informações, segui o passo a passo indicado pelo Dirceu:
https://www.dirceuresende.com/blog/como-utilizar-a-api-do-pushbullet-para-enviar-torpedos-sms-no-c-php-java-ou-pelo-sql-server-com-clr/



Recordset:
Está num botão no form frm_EnviarSMS

O código a seguir é o recordset completo para gerar todos os SMS marcados, mas caso não queira, basta ler a parte  em que ele fala o que faz individualmente.
Os únicos campos que ele precisa são SendSMS (verdadeiro ou falso), SMSphone e SMSmessage que podem estar em qualquer tabela que vocês criarem, lembrando que SMS são mensagens de até 140 caracteres.

O campo SendSMS deve estar marcado como verdadeiro, porque ao final será editado para falso.
Crie uma consulta com esses campos em que o SendSMS seja verdadeiro, e nomeie qyr_movimentos_sms.

Código:

Public Sub cmdEnviarSMS_Click()

    Dim db As DAO.Database
    Dim rs As DAO.Recordset
    Set db = CurrentDb
            
    Set rs = db.OpenRecordset("qyr_movimentos_sms")     'abre a consulta previamente criada
    
    If rs.RecordCount = 0 Then                          'se não encontra registos avisa e sai
        AutoCloseMsgBox "Não há SMS para enviar!", "Atenção!", 3
        Exit Sub
    End If
    
    rs.MoveFirst                                            'coloca-se no 1º registro

    Do While Not rs.EOF                                 'percorre todos os registros
    
    Sleep (1500)
    

    
    
    
        '-----------inicio do que ja fazia individualmente----------------
        
        Open localW & "sys\json\pushmessage.json" For Output As #1
           Print #1, "{"
           Print #1, Space(2) & Chr(34) & "push" & Chr(34) & ": {"
           Print #1, Space(4) & Chr(34) & "conversation_iden" & Chr(34) & ": " & Chr(34) & "+" & rs("SMSphone") & Chr(34) & ","
           Print #1, Space(4) & Chr(34) & "message" & Chr(34) & ": " & Chr(34) & TiraAcento(rs("SMSmessage")) & Chr(34) & ","
           Print #1, Space(4) & Chr(34) & "package_name" & Chr(34) & ": " & Chr(34) & "com.pushbullet.android" & Chr(34) & ","
           Print #1, Space(4) & Chr(34) & "source_user_iden" & Chr(34) & ": " & Chr(34) & userId & Chr(34) & ","
           Print #1, Space(4) & Chr(34) & "target_device_iden" & Chr(34) & ": " & Chr(34) & userDev & Chr(34) & ","
           Print #1, Space(4) & Chr(34) & "type" & Chr(34) & ": " & Chr(34) & "messaging_extension_reply" & Chr(34)
           Print #1, Space(2) & "}" & ","
           Print #1, Space(2) & Chr(34) & "type" & Chr(34) & ": " & Chr(34) & "push" & Chr(34)
           Print #1, "}"
        Close #1
        
        Sleep (500)
        
        'escrever bat
            Open localW For Output As #2
            Print #2, "start cmd.exe /c curl --header " & Chr(34) & "Access-Token: " & accessT & Chr(34) & "  --header " & Chr(34) & "Content-Type: application/json" & Chr(34) & " --request POST -k --data-binary @" & Chr(34) & localW & "sys\json\pushmessage.json" & Chr(34) & " https://api.pushbullet.com/v2/ephemerals"
            Close #2
            Sleep (500)
    
            Call Shell(localW & "sys\strcm.bat", 1)
        
        Sleep (1500)
        
        '-----------Fim do que ja fazia individualmente----------------
        
        DoEvents                                        'manda executar eventos
        
        rs.Edit                                         'edita registo
        rs("SendSMS") = False                           'muda SendSMS para falso
        rs.Update                                       'atualiza registo
        rs.MoveNext                                     'move para proximo registo
    Loop
        
    rs.Close: Set rs = Nothing                          'fecha recordeset e limpa da memoria
    db.Close: Set db = Nothing                          'fecha base dados e limpa da memoria

    AutoCloseMsgBox "SMS enviados!", "Concluído", 3
    
    DoCmd.Close acForm, "frm_EnviarSMS"
    
End Sub