Como faço para pingar o IP de dentro de um formulário?

Olá!

veja se te ajuda:

""":usandoaccess.com.br/dicas/wmi-e-environ-gerenciando-windows-e-hardware.asp?id=1"""
Copie e cole o endereço no seu navegador

Sucesso

Código:

Sub TestePing()
' Origem: http://www.vbaexpress.com/forum/showthread.php?42466-Pinging-IP-addresses-in-Access-2007

    Dim strComputer As String
    strComputer = "127.0.0.0"   ' IP ou nome máquina para testar
    
    If Not SystemOnline(strComputer) Then
        MsgBox "Não foi possível atingir a máquina: " & strComputer, vbOKOnly, ""
        '....outras instruções que pretenda
    Else
        '....outras instruções que pretenda
        MsgBox "Online", vbOKOnly, ""
    End If
End Sub


Function SystemOnline(ByVal ComputerName As String)
' This function returns True if the specified host could be pinged.
' HostName can be a computer name or IP address.
' The Win32_PingStatus class used in this function requires Windows XP or later.
' Standard housekeeping
' Origem: http://www.vbaexpress.com/forum/showthread.php?42466-Pinging-IP-addresses-in-Access-2007
    
    Dim colPingResults As Variant
    Dim oPingResult As Variant
    Dim strQuery As String
    
    ' Define the WMI query
    strQuery = "SELECT * FROM Win32_PingStatus WHERE Address = '" & ComputerName & "'"
    
    ' Run the WMI query
    Set colPingResults = GetObject("winmgmts://./root/cimv2").ExecQuery(strQuery)
    
    ' Translate the query results to either True or False
    For Each oPingResult In colPingResults
        If Not IsObject(oPingResult) Then
            SystemOnline = False
        ElseIf oPingResult.StatusCode = 0 Then
            SystemOnline = True
        Else
            SystemOnline = False
        End If
    Next
End Function