[Resolvido]Cores de acordo com a tarefa

Bom dia meus amigos,

Recentemente aqui no fórum eu consegui adaptar um código a minha necessidade, porém, ficou faltando apenas as cores das tarefas que eu preciso que sejam exibidas. É tipo um Planejador de atividades, com um calendário que mostra pro usuário quando ocorrerá determinado evento, onde, quando o evento for status = 0 ou 5 significam  "A REALIZAR" e os demais "NÃO REALIZADOS".

1. Como faço para que cada linha saia em uma cor diferente, dependendo do status da tarefa? Sendo "A REALIZAR" na cor AZUL e "NÃO REALIZADOS" na cor VERMELHA?

BD em anexo para que possam analisar.


Att

Kellyton

Boa tarde

Código:

Private Sub PrintArray()
    On Error GoTo ErrorHandler
    Dim strCtlName As String, i As Integer
   
    For i = LBound(myArray) To UBound(myArray)
        strCtlName = "txt" & CStr(i + 1)
        Controls(strCtlName).Tag = i
        Controls(strCtlName) = ""
        Controls(strCtlName) = myArray(i, 2)
        If InStr(1, myArray(i, 2), "A REALIZAR") > 0 Then
            Controls(strCtlName).ForeColor = vbBlue
        ElseIf InStr(1, myArray(i, 2), "NÃO REALIZADOS") > 0 Then
            Controls(strCtlName).ForeColor = vbRed
        Else
            Controls(strCtlName).ForeColor = 0
        End If
    Next i
   
ExitSub:
    Exit Sub
ErrorHandler:
    MsgBox "erro no print"
    Resume ExitSub
End Sub

Boa tarde Amigo,

Fiz da forma que passou, porém, o resultado foi que o texto inteiro ficou em azul agora, veja abaixo:



A linha que está realçada em amarelo deve ficar em azul e as demais em vermelho no exemplo acima.

Não tinha enviado dados representativos mas mais que uma cor não será possível

Alexandre, vc sabe se é possível executar isso de outra forma então?

Uma listview seria possível alterar as cores de cada linha dependendo do resultado conforme mencionei?

nunca trabalhei com listview mas pode explorar
Por mim, pensava em colocar caixas de texto para o máximo possível necessário
Caso possam ser muitas, pensaria em caixa de listagem

Obrigado

Estava pensando na caixa de listagem, mas não consegui evoluir nas suas propriedades, tão pouco ele tem formatação condicional..

Rs

Boa tarde
A caixa de listagem pode pintar as linhas apenas em branco com letras pretas ou em preto com letras brancas

Boa tarde @Alexandre,

Obrigado pelo teu apoio, vamos seguir e ver se alguém tem mais alguma ideia de como poderia fazer para exibir no planejamento as cores das tarefas.

Forte abraço

Boa noite, kasa1982
Altere a caixa de texto
Propriedades > Dados > Formato de Texto > Rich Text

No código

Código:

Private Sub LoadArray()
    Dim rs As DAO.Recordset, rsFiltered As DAO.Recordset, strSQL As String, i As Integer

    strSQL = "SELECT * from agenda order by agenda.[data dia]"
    Set rs = CurrentDb.OpenRecordset(strSQL)
   
    If Not rs.BOF And Not rs.EOF Then
        For i = LBound(myArray) To UBound(myArray)
            If myArray(i, 1) Then
                rs.Filter = "[data dia]=" & myArray(i, 0)
                Set rsFiltered = rs.OpenRecordset
                Do While (Not rsFiltered.EOF)
                    Dim concluir As String
                    If rsFiltered![Concluído] = True Then
                        concluir = "A REALIZAR"
                        myArray(i, 2) = myArray(i, 2) & vbNewLine & vbNewLine _
                        & "<font color=blue>" & rsFiltered![Data Dia] & " - " _
                        & rsFiltered![Data Hora] & vbNewLine _
                        & rsFiltered![Evento] & vbNewLine _
                        & rsFiltered![ClienteNome] & " | " _
                        & rsFiltered![processo] & vbNewLine _
                        & rsFiltered![Detalhe] & vbNewLine _
                        & concluir & "</font>" & vbNewLine & vbNewLine
                    Else
                        concluir = "NÃO REALIZADO"
                        myArray(i, 2) = myArray(i, 2) & vbNewLine & vbNewLine _
                        & "<font color=red>" & rsFiltered![Data Dia] & " - " _
                        & rsFiltered![Data Hora] & vbNewLine _
                        & rsFiltered![Evento] & vbNewLine _
                        & rsFiltered![ClienteNome] & " | " _
                        & rsFiltered![processo] & vbNewLine _
                        & rsFiltered![Detalhe] & vbNewLine _
                        & concluir & "</font>" & vbNewLine & vbNewLine
                    End If
                    rsFiltered.MoveNext
                Loop
            End If
        Next i
    End If
    rsFiltered.Close
    rs.Close

    Set rsFiltered = Nothing
    Set rs = Nothing
End Sub

Alexandre, boa noite

BINGO amigo, obrigado, eu havia esquecido completamente do 'rich text', veja como ficou o resultado final.

Estou dando como concluído o tópico.

disponibilizem a agenda para estudos amigos