[Resolvido]Erro no filtro usando LEFT JOIN, WHERE e GROUP BY

Boa noite a todos do Maximoaccess.

Estou tendo dificuldade em montar um filtro usando LEFT JOIN, WHERE e  GROUP BY.
Quando carrego o formulário a listbox e preenchida, mas ao digitar na caixa de testo, o filtro não funciona.
Como poderia resolver isso. Estarei deixando o arquivo em anexo.

Boa tarde,
dê-nos mais detalhes, como por exemplo, qual formulário?
E a filtragem é ao digitar ou apenas ao clicar em um botão?

Boa tarde.
A filtragem, e ao digitar. No arquivo tem o formulário de busca com o nome fmEntradaFiltro, nele tem uma caixa de listagem e duas caixas de texto.
Na caixa de listagem está carregando 2 tabelas juntas.
Queria que ao digitar em alguma caixa de texto, ocorrece a filtragem.

E todos aqueles códigos, o único objetivo é realizar a filtragem?
Se sim, iremos reduzir consideravelmente.

Não entende os loops, pois se for para filtrar, não são necessários.

Sim, apenas filtragem.

Bom dia, vamos lá!

Apague todo o código do formulário em questão.

Com o VBA do formulário limpo, copie e cole a sub que carregar a lista:

Código:

Private Sub subCarregalista(Optional filtro As String)
Dim strSql As String

'Sub que popula a caixa de listagem
'Recebe um parâmetro opcional "filtro".
'Caso não passe o parâmetro, ela retornará todos os registros

'Inicio a composição da SQL
strSql = "SELECT tbEntrada.ID, tbEntrada.Nome, Sum(tbEntradaSub.ValorTotal) AS ValorTotal"
strSql = strSql & " FROM tbEntrada LEFT JOIN tbEntradaSub ON tbEntrada.ID = tbEntradaSub.IDEntrada"

'Verifico se foi passado valor para o filtro
'Caso haja valor (diferente de "") concateno o paramêtro filtro ao variável strSql
If filtro <> "" Then
    strSql = strSql & filtro
End If

'Passo o valor da variável strSql para a propriedade RowSource da caixa de listagem concatenando com a agrupação e ordenação
Me.Lista.RowSource = strSql & " GROUP BY tbEntrada.ID, tbEntrada.Nome ORDER BY tbEntrada.ID;"

End Sub

No evento Ao abrir do formulário:

Código:

'Chamo a sub que carega a lista sem passar parâmetros, assim ela irá
'popular com todos os registros a lista
Call subCarregalista

Evento Ao alterar da caixa de texto tx1:
 

Código:

'Conto os caracteres da textbox tx1 e caso tenha mais de zero, monto a cláusula WHERE
'filtrando ID passando como parâmetro para a sub
'Caso não tenha nenhuma caracter, apenas chamo a sub sem passar parâmetro, assim ela irá
'carregar a lista com todos os registros
If Len(Me.tx1.Text) > 0 Then
    Call subCarregalista(" WHERE tbEntrada.ID = " & Me.tx1.Text)
Else
    Call subCarregalista
End If

Evento Ao aterar da caixa de texto tx2:

Código:

'Conto os caracteres da textbox tx2 e caso tenha mais de zero, monto a cláusula WHERE
'filtrando Nome, usando o operador LIKE para que a filtragem seja por qualquer parte do campo
'e passo como parâmetro para a sub.
'Caso não tenha nenhuma caracter, apenas chamo a sub sem passar parâmetro, assim ela irá
'carregar a lista com todos os registros
If Len(Me.tx2.Text) > 0 Then
    Call subCarregalista(" WHERE tbEntrada.Nome LIKE '*" & Me.tx2.Text & "*'")
Else
    Call subCarregalista
End If

Teste e nos retorne por gentileza.

E caso queira se aprofundar nesse assunto de filtragens, não deixe de assistir minha
videoaula sobre o tema no meu canal do Youtube. Acesse aqui.

Boa tarde. Marcelo David

Nossa ficou incrivel.
Vou ver os videos, e assinar alguns cursos do link que vc deixou.
Muito obrigado pela atenção, e pelo codigo.

Grato pelo retorno meu amigo!