[Resolvido]Buscar arquivo em uma pasta especifica

Bom dia pessoal tenho um formulario no meu sistema onde o usuario clica em um botão e ele abre um arquivo PDF que contém o mesmo nome do campo código por exemplo campo código igual a PP30010057 o BD vai buscar na pasta( Arquivos de Desenhos ) o arquivo com nome PP30010057.pdf o problema que o pessoal no nome do arquivo pdf estão adicionando mais textos exemplo PP30010057 versão 3 atualizado em 11042023.pdf, desta forma o botão que criei não consegue mais achar o arquivo e me retorna erro, alguém poderia me ajudar como faço para que este botão abra o arquivo de forma que ele busque apenas partes do texto ?

Segue abaixo o código que estou usando no evento ao clickar no botão:

Private Sub Comando60_Click()

MsgBox Me!Código, vbInformation, "Abrir o Arquivo"
Application.FollowHyperlink ("C:\Sistema AFS\Arquivos de Desenhos\" & (Me!Código) & ".pdf")


End Sub


Tentei também com este outro código abaixo mas da a msg de arquivo não encontrado não consegui achar ainda onde estou errando:

Private Sub Comando60_DblClick(Cancel As Integer)

Dim caminho As String, nomeArquivo As String, parteNomeArquivo As String

' Insira a pasta onde o arquivo em PDF está localizado
caminho = "C:\Sistema AFS\Arquivos de Desenhos"

' Insira a parte do nome do arquivo que você sabe
parteNomeArquivo = "Me!Código"

' Localizar o arquivo com base na parte do nome do arquivo
nomeArquivo = Dir(caminho & "*" & parteNomeArquivo & "*.pdf")

' Verificar se o arquivo foi encontrado
If nomeArquivo = "" Then
MsgBox "Arquivo em PDF não encontrado."
Else
' Abrir o arquivo em PDF
Shell "C:\Program Files (x86)\Adobe\Acrobat Reader DC\Reader\AcroRd32.exe " & caminho & nomeArquivo, vbNormalFocus
End If


End Sub

Desde já agradeço a ajuda de todos !!

Olá

Claro que sim;

Código:

Private Sub SeuBotão_Click()
Dim ObterFicheiro As Variant
Dim j As Integer

j = 1
'obter todos os ficheiros PDF de uma pasta
ObterFicheiro = Dir("C:\temp\Sistema AFS\Arquivos de Desenhos\*.pdf")
'faz um loop aos ficheiros
    Do While Len(ObterFicheiro) > 0
'se encontrar algum ficheiro com as 10 primeiras letras iguais ao campo Código no formulario, abre o PDF
        If Left(ObterFicheiro, 10) = Me.Código.Value Then
            Application.FollowHyperlink ("C:\temp\Sistema AFS\Arquivos de Desenhos\" & ObterFicheiro)
            Exit Sub
        End If
'se não encontrar volta a procurar no loop
    j = j + 1
    ObterFicheiro = Dir()
    Loop
End Sub

Boa tarde JPaulo,
O código que voce mandou não funcionou, mas ele foi de grande ajuda pra mim encontrar os caminhos das pedras muitp obrigado !!

Segue código abaixo funcionando caso alguém esteja com o mesmo problema que o meu:


Private Sub Comando80_Click()
Dim caminho As String, nomeArquivo As String, parteNomeArquivo As String
   
   ' Insira a pasta onde o arquivo em PDF está localizado
   caminho = "C:\Sistema AFS\Arquivos de Desenhos\"
   
   ' Insira a parte do nome do arquivo que você sabe
   parteNomeArquivo = Me.Código
   
   ' Localizar o arquivo com base na parte do nome do arquivo
   nomeArquivo = Dir(caminho & parteNomeArquivo & "*.pdf")
   
   ' Verificar se o arquivo foi encontrado
   If nomeArquivo = "" Then
       MsgBox "Arquivo em PDF não encontrado."
   Else
       ' Abrir o arquivo em PDF
       Do Until nomeArquivo = ""
           Application.FollowHyperlink (caminho & nomeArquivo)
           nomeArquivo = Dir()
       Loop
   End If
   

End Sub

Estou vendo aqui como faço para colocar este tópico como resolvido, mais uma vez muito obrigado JPaulo, Abraços !!