[Resolvido]Importar dados do ficheiro .txt

Caros amigos,

Em primeiro quero dar os meus parabéns ao forum e a todos os participantes e agradecer toda a ajuda que me têm dado.

Esta é a primeira vez que tenho necessidade de ajuda mais focalizada, pois desta vez não consigo encontrar a resposta aqui no forum.

Tentei adaptar o exemplo do JPaulo, para importar dados de um ficheiro de texto, mas necessito que a tabela tenha vários campos, e o resultado foi um erro de "execução de SQL".

Anexo um print do erro, se for necessário algo mais, por favor não hesitem.

boas
eu também nunca fiz mas coloque o seu código que duas cabeças pensam melhor que uma, que assim vai ser dificil obter ajuda.
cumps
acao

Obrigado acao pela resposta, segue o código que utilizei.

Código:

Option Compare Database
Option Explicit
Private Sub Comando86_Click()
   
    Call ImportaSemDelimitadores
   
End Sub

Public Sub ImportaSemDelimitadores()
'By JPaulo ® Maximo Access
Dim Delimitador As String
Dim DB As Database
Dim fnum As Integer
Dim LinhaDoTexto, LinhaDoTextoTemp As String
Dim InstrucaoSQL As String
Dim Posicao As Integer
Dim QtdDeRegistros As Long
Dim ArquivoTexto As String
Dim strBanco As Databases
Dim strTabela As String

    ArquivoTexto = "I:\Gestão Intermodal\PTLEI\MarcacoesLeixoes.txt" 'caminho do arq de texto
    strTabela = "tabMarcacoesLeixoes" 'nome da tabela no banco
   
    Delimitador = vbTab 'defina aqui qual o delimitador que não quer importar
   
    If Delimitador = "<space>" Then Delimitador = " "
    If Delimitador = "<tab>" Then Delimitador = vbTab

    fnum = FreeFile
    On Error GoTo NoTextFile
    Open ArquivoTexto For Input As fnum

    On Error GoTo NoDatabase
    Set DB = CurrentDb
    On Error GoTo 0

    Do While Not EOF(fnum)
        Line Input #fnum, LinhaDoTexto
               
          If Len(LinhaDoTexto) > 0 Then
          If Left(LinhaDoTexto, 4) Like "4530" Then
            LinhaDoTextoTemp = Mid(LinhaDoTexto, 11, 255)
            LinhaDoTexto = LinhaDoTextoTemp
          End If
            InstrucaoSQL = "INSERT INTO " & _
                strTabela & " VALUES ("
            Do While Len(LinhaDoTexto) > 0
                Posicao = InStr(LinhaDoTexto, Delimitador)
                If Posicao = 0 Then
                    InstrucaoSQL = InstrucaoSQL & _
                        "'" & LinhaDoTexto & "', "
                    LinhaDoTexto = ""
                Else
                    InstrucaoSQL = InstrucaoSQL & _
                        "'" & Left$(LinhaDoTexto, Posicao - 1) & _
                        "', "
                    LinhaDoTexto = Mid$(LinhaDoTexto, Posicao + Len(Delimitador))
                End If
            Loop

            InstrucaoSQL = Left$(InstrucaoSQL, Len(InstrucaoSQL) - 2) & ")"

            On Error GoTo SQLError
            DB.Execute InstrucaoSQL
            On Error GoTo 0
            QtdDeRegistros = QtdDeRegistros + 1
       
        End If
    Loop

'Aqui vai o código para excluir
DB.Execute "Delete Nome From tabMarcacoesLeixoes"


    Close fnum
    DB.Close
    MsgBox "Inseridas " & Format$(QtdDeRegistros) & " Linhas"
    Exit Sub

NoTextFile:
    MsgBox "Erro na abertura do Arquivo de Texto."
    Exit Sub

NoDatabase:
    MsgBox "Erro na abertura do Banco."
    Close fnum
    Exit Sub

SQLError:
    MsgBox "Erro na execusão do SQL '" & _
        InstrucaoSQL & "'"
    Close fnum
    DB.Close
    Exit Sub
End Sub


boas
estive a dar uma vista de olhos ao teu codigo e falta os campos da tabela

= ("INSERT INTO nomedatabela (nomecampo1, nomecampo2, ....etc) values ('" & valorcampo1 & "', " & valorcampo2 &", ...etc);")

nos valores se forem texto ou datas colocas entre '" e se for numerico colocas apenas entre " ou se for numerico fora de variavel ou caixa de texto,etc colocas sem ' e sem " .

PS: coloca breakpoints para depurares o cod.


se não for isto dame mais inf como tabela e ficheiro doc.
logo à noite talvez tenha mais tempo dou outra vista de olhos.

edit:acrescentar Inf.
não deste retorno.
vê também este exemplo.
http://www.macoratti.net/dica16.htm

cumps
acao

Obrigado pela dica, amanha já vou testar.

Bom dia,

Mas a instrução SQL está neste trecho de código, corrige-me se eu estiver errado.

InstrucaoSQL = "INSERT INTO " & _
strTabela & " VALUES ("
Do While Len(LinhaDoTexto) > 0
Posicao = InStr(LinhaDoTexto, Delimitador)
If Posicao = 0 Then
InstrucaoSQL = InstrucaoSQL & _
"'" & LinhaDoTexto & "', "
LinhaDoTexto = ""
Else
InstrucaoSQL = InstrucaoSQL & _
"'" & Left$(LinhaDoTexto, Posicao - 1) & _
"', "

Onde ele diz para inserir na tabela (strTabela) "As String" os valor maiores que 0 do ficheiro de texto.

Bom dia amigos;

Peço desculpa a todos por ainda não ter visto este tópico.

Aqui vai o simples;


Para mais campos, terá 1º de definir o delimitador, por exemplo:

No seu .txt, tem a seguinte informação:

JPaulo;Rui Sousa;Alexandre Neves

Isto representa 3 campos na sua tabela...

Então no código tem de alterar:

Onde está "Delimitador = vbTab"
Passará a ser Delimitador = ";"

Teste e retorne.

Obrigado pelo retorno, todavia não resulta na medida em que a separação dos dados é feita por um tab.

Anexo parte da bd + txt, por forma a facilitar.


Import_TXT_MultiCamp

Lamento;

Com esse ficheiro, este código não funciona.

Terá de ser um código, que faça um Replace dos espaços para delimitadores fixos, para indicar quais as colunas que estão vazias.

Esperamos que alguma fera se atente e que tenha tempo disponível.

boas
este é o ficheiro original?
não o converteste para .txt?
não tens noutro formato?
os campos que não têm valores numca vao ter dados?
cumps
acao

boas
amigo está feito
vê se é isto?

http://dl.dropbox.com/u/65238129/MaximoAccess/Import_TXT_MultiCamps.7z

cumps
acao

Gostava de ver, mas esse Seven Zip pede password.

Boas,

pois falta a pass

Mas só a possibilidade de estar resolvido este problema, já é uma luz

boas
não coloquei a pass para ser o solicitador o primeiro a visualizar, mas como ele não ainda não deu feedback, aqui fica para quem quiser consultar.

pass:«forummaximo»

Código:

Private Sub cmdImpDoc_Click()
Dim Delimitador As String
Dim fnum As Integer
Dim LinhaDoTexto As String
Dim Posicao As Integer
Dim ArquivoTexto As String
Dim vContador As Byte
Dim vStrigValor As String



'variaveis passar dados campos tabela
Dim vContentor As String
Dim vPrevisaoIn As String
Dim vC20 As String
Dim vC40 As String
Dim vTNS As String
Dim vTipo As String
Dim vTemp As String
'Dim vFrio As Boolean
Dim vIMO As String
Dim vCarregado As String
Dim vDescarregado As String
Dim vBkgs As String
Dim vMercadoria As String
Dim vNavio As String
Dim vData As String
Dim vWO As String
'Dim vParaComboio As Boolean
'Dim vDataCarga As Date
'Dim vDoc As String
'Dim vuser As String
'Dim vDataRegisto As Date

    ArquivoTexto = "D:\MarcacoesLeixoes.txt" 'caminho do arq de texto

   
    Delimitador = vbTab 'defina aqui qual o delimitador que não quer importar
   
  If Delimitador = "<space>" Then Delimitador = ";"
    If Delimitador = "<tab>" Then Delimitador = vbTab

    fnum = FreeFile
 
    Open ArquivoTexto For Input As fnum
    Dim comImp As New ADODB.Command
    Dim rstImp As New ADODB.Recordset

    On Error GoTo errImportacao
    comImp.ActiveConnection = CurrentProject.Connection
 
 

    Do While Not EOF(fnum)
        Line Input #fnum, LinhaDoTexto
          vContador = 0
          If Len(LinhaDoTexto) > 0 Then
          If Mid(LinhaDoTexto, 1, 9) <> "Contentor" Then
         
         
            Do While Len(LinhaDoTexto) > 0
                Posicao = InStr(LinhaDoTexto, Delimitador)
                If Posicao = 0 Then
                 
                    LinhaDoTexto = ""
                Else
                vStrigValor = Left$(LinhaDoTexto, Posicao - 1)
                vContador = vContador + 1
                    LinhaDoTexto = Mid$(LinhaDoTexto, Posicao + Len(Delimitador))
                    Select Case vContador
                    Case 1
                    vContentor = vStrigValor
                    Case 2
                    vPrevisaoIn = vStrigValor
                    Case 3
                    vC20 = vStrigValor
                    Case 4
                    vC40 = vStrigValor
                    Case 5
                    vTNS = vStrigValor
                    Case 6
                    vTipo = vStrigValor
                    Case 7
                    vTemp = vStrigValor
                    Case 8
                    vIMO = vStrigValor
                    Case 9
                    vCarregado = vStrigValor
                    Case 10
                    vDescarregado = vStrigValor
                    Case 11
                    vBkgs = vStrigValor
                    Case 12
                    vMercadoria = vStrigValor
                    Case 13
                    vNavio = vStrigValor
                    Case 14
                    vData = vStrigValor
                    Case 15
                    vWO = vStrigValor
                    End Select
                  End If
               
            Loop
           
          If vContentor <> "" Then
            comImp.CommandText = "Insert Into tabMarcacoesLeixoes (Contentor, PrevisaoIn, C20, C40, TNS, Tipo, Temp, IMO, Carregado, " & _
            "Descarregado, Bkgs, Mercadoria, Navio, Data, Wo) Values ('" & vContentor & "', '" & vPrevisaoIn & "', '" & vC20 & _
            "', '" & vC40 & "', '" & vTNS & "', '" & vTipo & "', '" & vTemp & "', '" & vIMO & "', '" & vCarregado & "', '" & vDescarregado & _
            "', '" & vBkgs & "', '" & vMercadoria & "', '" & vNavio & "', '" & vData & "', '" & vWO & "');"

            comImp.CommandType = adCmdText: Set rstImp = comImp.Execute
            End If
End If
End If
         
       
     
    Loop
    MsgBox "Importaçao de ficheiro concluída com sucesso.", _
vbApplicationModal + vbInformation + vbOKOnly, _
"Importaçao OK"


Saida:

Set rstImp = Nothing
Set comImp = Nothing
Exit Sub
errImportacao:
With Err
If .Number <> 0 Then
MsgBox "Houve um erro durante a Importaçao  do ficheiro no botão cmdImpDoc.", _
vbExclamation + vbOKOnly + vbApplicationModal, "Erro"
.Number = 0
GoTo Saida
End If
End With

End Sub

cumps
acao

Perfeito, parabéns até mesmo pelo trabalho que deu.

Nota 10.

Só falta o retorno final do Rui e o Resolvido no tópico.

Bom dia,

Peço desculpa pela demora na resposta, mas tive um problema com o meu pc que já está resolvido.

Agradeço imenso a ajuda de todos, graças aos "experts" tenho o problema resolvido.


Amigo acao, um muito obrigado especial por todo o trabalho, ficou 6 estrelas, está a funcionar na perfeição

Agora vou dar o tópico como resolvido.

boas

Perfeito, parabéns até mesmo pelo trabalho que deu.

Nota 10.

JPaulo, nota 10!, nota 10 é mediocre.
você da decada de sessenta e faz-me isto! nessa decada só saíram boas fornadas.
como chegou a este valor?
não usou os criterios de você nao querer o u não conseguir fazer.

não subestime para não ser subestimado.

cumps
acao

boas

boas


Perfeito, parabéns até mesmo pelo trabalho que deu.

Nota 10.


JPaulo, nota 10!, nota 10 é mediocre.
você da decada de sessenta e faz-me isto! nessa decada só saíram boas fornadas.
como chegou a este valor?
não usou os criterios de você nao querer o u não conseguir fazer.

não subestime para não ser subestimado.

cumps
acao

amigo JPaulo
quero deixar-lhe aqui um pedido de desculta.
verifiquei que é de praxe aqui no forum usar-se a frase:
«Nota 10» para classificar um trabalho razoavel ou bom.
embora eu ache que deveria ser 15 ou 20 mas não é isto que está em discussão,
por isso peço-lhe desculpas pelo meu post injusto perante a sua apreciação.
espero que compreenda e aceite as minhas desculpas.
cumps
acao