[Resolvido]Inserir dados em mais de uma tabela

Ola colegas,

Tenho um formulário com um subformulário e um botão que insere dados em uma determinada tabela
como faço para que um unico botão insira dados do formulário em uma tabela e do subformulario em outra tabela ?


estou usando esse código para inserir dados do formulario na tabela

Código:

Dim dbs As DAO.Database
Dim rst As DAO.Recordset
Set dbs = CurrentDb
Set rst = dbs.OpenRecordset("tblPedido")
rst.AddNew



rst!IdPedido = Me.CodVenda

rst!idClente = Me.txtCliente

rst!TipoDesconto = Me.custovenda

rst.Update

Como fazer para que nesse mesmo código eu consiga inserir os dados do subformulário em outra tabela ?

Up!!!

poste as tabelas e campos envolvidos

Tenho um formulário de orçamento que grava dados na tabela "tblOrcamento" e o mesmo tem um subformulário que grava dados na tabela "tblOrcamentodet", neste formulário tenho um botão denominado "Gerar Pedido",quando o mesmo é acionado envia os dados da tabela "tblOrcamento"
para a tabela "tblPedido" e os dados do subform "tblOrcamentodet" para a tabela "tblPedidodet", e depois abre o formulário Pedido direto no registro que foi gerado do orçamento, mais já tentei de tudo e não consigo fazer funcionar, segue para download o DB para que melhor entenda e possa me ajudar


Download DB - https://www.dropbox.com/s/g75rz1w66d6h1po/Database.rar?dl=0


PRINT

Brother, agora com esses detalhes, tive uma idéia ou sugestão.

Se a única diferença entre as tabelas é o status que muda de orçamento para pedido.

Poderia criar um campo sim/não, com o nome "confirma pedido?".

Em seguida bastaria gerar uma consulta pedido confirmado e depois o relatório.

Mas vou verificar o BD.

Abraços

Agradeço Cleverson pela sua atenção,

mais eu gostaria de jogar os dados da tabela de orçamento para a tabela de pedido
e da mesma forma com o detalhe do orçamento para o detalhe do pedido se puder me ajudar
desde já agradeço pela atenção dispensada

Consegui chegar a este ponto, porem quando o formulário Pedido abre não carrega os dados do subform ?
o que ha de errado com o código ?

Código:

Private Sub btpedido_Click()


Dim dbs As DAO.Database
Dim rst As DAO.Recordset
Dim rs As DAO.Recordset
Dim tbl As DAO.Recordset



cpopedido.SetFocus
cpopedido.Text = "Orçamento"
txt_Status.SetFocus
txt_Status.Text = "Pedido"
tx.SetFocus


Set dbs = CurrentDb
Set rst = dbs.OpenRecordset("tblPedido")
Set tbl = dbs.OpenRecordset("tblPedidodet")
Set rs = Frm_VendasSub.Form.RecordsetClone

 
  rst.AddNew
   
     
      rst!id_Orcamento = Me.CodVenda
      rst!IdCliente = Me.txtCliente
      rst!TipoDesconto = Me.custovenda
      rst!orcdet_Contato = Me.Texto73
      rst!orc_Data = Me.txt_data
      rst!orc_Pedido = Me.txt_Status

    rst.Update
    rst.Close

Do While Not rs.EOF
 
 
  tbl.AddNew
 
      'rst!idPedido = rs!idPedido
      tbl!idPedidodet = rs!idOrcamentodet
      tbl!idMedicamento = rs!idMedicamento
      tbl!orcdet_Quantidade = rs!orcdet_Quantidade
      tbl!Desconto = rs!Desconto
      tbl!orcdet_Paciente = rs!orcdet_Paciente
     
  tbl.Update
  rs.MoveNext
Loop

tbl.Close
rs.Close
Set tbl = Nothing
Set rs = Nothing


DoCmd.OpenForm "frm_Pedido"

Forms!frm_Pedido.Filter = "id_Orcamento = " & Me!idOrcamento
Forms!frm_Pedido.FilterOn = True




End Sub

Alguem me ajuda por favor !!!

Help me !!!

Bom dia....

Substitua os campos que estão nesse código abaixo, pelos teus campos. É só adaptar as tuas necessidades.

Código:

Private Sub bt_gerarPedido_Click()
Dim dbOrc As Database, rs1, rs2, rs3 As DAO.Recordset

    If MsgBox("Deseja Gerar Caixa  desse Orçamento?", vbYesNo + vbQuestion, Me.Caption) = vbNo Then
    Me.Undo
        DoCmd.CancelEvent
            MsgBox "Não foi gerado caixa !", vbInformation, Me.Caption
           
            Exit Sub
                Else
   
        Set dbOrc = CurrentDb
       
        Set rs1 = dbOrc.OpenRecordset("tblcaixa") 'substitua a tabela aqui
           
        With rs1
       
        .AddNew
        ![IDOrcamento] = Me.IDOrcamento      ' substituir esse campo
        ![DataPagamento] = Me.DataOrcamento ' substituir esse campo
        ![Proprietario] = Me.Proprietario ' substituir esse campo
        ![Telefone] = Me.Telefone ' substituir esse campo
        ![Celular] = Me.Celular ' substituir esse campo
        ![Animal] = Me.Animal ' substituir esse campo
        ![Valor] = Me.Valorf  ' substituir esse campo
        ![IdProp] = Me.IdProp ' substituir esse campo
        .Update
       
        End With
       
       
        Set rs2 = dbOrc.OpenRecordset("SELECT * FROM TblSubOrcamento WHERE Idorcamento=" & Me.IDOrcamento)
        Set rs3 = dbOrc.OpenRecordset("tblsubcaixa") ' substituir tabela
       
     
        While (Not rs2.EOF)
            With rs3
                .AddNew
                ![IdCaixa] = DMax("idcaixa", "tblcaixa") ' substituir esse campo
                ![IDOrcamento] = rs2![IDOrcamento] ' substituir esse campo
                ![Servico] = rs2![Servico] ' substituir esse campo
                ![Custo] = rs2![Custo] ' substituir esse campo
                ![Qtd] = rs2![Qtd] ' substituir esse campo
                ![Tcusto] = rs2![TotalProc] ' substituir esse campo
                .Update
                rs2.MoveNext
            End With
        Wend
       
        rs1.Close
        Set rs1 = Nothing
       
        rs2.Close
        Set rs2 = Nothing
       
        rs3.Close
        Set rs3 = Nothing
       
        Set dbOrc = Nothing
       
      'limpa a tblorcamento no orçamento especifico que gerou o caixa, evitando duplicatas na tbl
      DoCmd.RunCommand acCmdSelectRecord
      DoCmd.RunCommand acCmdDeleteRecord
     
      DoCmd.Close acForm, "frmorcamento" ' substituir o formulário
      DoCmd.OpenForm "frmcaixa"  ' substituir o formulário
       
     
     
     
    End If
End Sub

Muito obrigado Silvio pela LUZ

Funcionou perfeitamente muito obrigado mesmo