[Resolvido]Atualizar os dados em subformulário como se estivesse redigitando o campo

Olá, gostaria de ajuda para resolver a questão abaixo:

Em um subformulário tenho campos que são capturados através do .VALUE

Assim sendo, quando estou digitando o nome do produto, no evento após atualizar ele me traz o valor pago nesse produto pela última vez.

O que preciso é fazer com que apos clicar em um determinado botão, os campos desse subformulário, especificamento o de produto, pudesse fazer algo que atualizasse os outros campos que estão amarrados a ele através do evento após atualizar.

já tentei o Recalc e Refresh, porém sem sucesso.


Agradeço desde já

Acesse o campo do produto, altere o escopo do evento "após atualizar" de Private para Public.

No seu botão, então basta usar o código

Código:

Me!NomeControleSubFormNoFormPrincipal.Form.CampoDoProduto_AfterUpdate

Boa noite Damasceno!

deu certo, apenas quando estou selecionando a linha do sub.
Gostaria de saber como ele atualiza todas as linhas que tem preenchimento com apenas um toque no botão, sem ter que selecionar um a um.


agradeço a disposição

Faltou dizer então que seu subformulário é do tipo contínuo ou folha de dados, onde esse tipo exibe vários registros ao mesmo tempo.

Nesse caso, no seu botão do formulário principal, tenha um código que use recordset para fazer loop em todos os registros do subformulário, com um código que faça a mesma coisa que o evento após atualizar do seu campo faz.

Por exemplo: digamos que no evento após atualizar de um campo no subformulário chamado "numero" você especifique no campo "par_impar" seu o número é par ou é impar.

Código:

Private Sub numero_AfterUpdate()
   
    If Me!numero.Value Mod 2 = 0 Then
        Me!par_impar.Value = "par"
    Else
        Me!par_impar.Value = "impar"
    End If

End Sub

No botão do seu formulário principal seria usado o seguinte código (que, em parte, faz o que o código do evento após atualizar faz)

Código:

Public Sub SeuBotao_Click()

    Dim objRS As DAO.Recordset
   
    Set objRS = Me!controleSubFormulario.Form.Recordset
   
    If objRS.RecordCount > 0 Then
       
        Call objRS.MoveFirst
        Do
       
            Call objRS.Edit
                If objRS!numero.Value Mod 2 = 0 Then
                    objRS!par_impar.Value = "par"
                Else
                    objRS!par_impar.Value = "impar"
                End If
            Call objRS.Update
            Call objRS.MoveNext
       
        Loop Until objRS.EOF
       
    End If
   
    Set objRS = Nothing

End Sub

Cara ainda sou leigo em vba, mas acho que está quase lá.

No evento após atualizar do meu subformulário que está na combox [produto] está assim:

Ean.Value = produto.Column(0)
vendaultimo.Value = produto.Column(2)
Me.data_atual.Value = produto.Column(3)


Meu botão ficou desse jeito, mas está dando algo errado.

Dim objRS As DAO.Recordset

Set objRS = Me!SUB_Det_lista_Vendas.Form.Recordset

If objRS.RecordCount > 0 Then

Call objRS.MoveFirst
Do

Call objRS.Edit
Ean.Value = produto.Column(0)
vendaultimo.Value = produto.Column(2)
Me.data_atual.Value = produto.Column(3)

Call objRS.Update
Call objRS.MoveNext

Loop Until objRS.EOF

End If

Set objRS = Nothing

Cara ainda sou leigo em vba, mas acho que está quase lá.

Nesse caso, anexe aqui seu banco de dados para uma ajuda certeira.

Damasceno, acho que do jeito que fiz no bd dá para ver onde estou errando.

Te agradeço mais uma vez.

Segue o Link:

https://www.dropbox.com/s/wntwndvbar0es8u/atualizar_sub%20-%20Copia.zip?dl=0

Baixe o anexo e teste

Códigos utilizados

Botão no formulário principal

Código:

Dim objRS1 As DAO.Recordset
    Dim objRS2 As DAO.Recordset
    
    Set objRS1 = Me!SUB_Det_lista_Vendas.Form.Recordset

    If objRS1.RecordCount > 0 Then
    
        Set objRS2 = CurrentDb.OpenRecordset("SELECT tblCad_Produto.ean, [Cs_precomedio-exclusivo-final-1].Último " & _
                                             "FROM tblCad_Produto INNER JOIN [Cs_precomedio-exclusivo-final-1] ON tblCad_Produto.ean = [Cs_precomedio-exclusivo-final-1].ean;", , 4)

        If objRS2.RecordCount > 0 Then

            Call objRS1.MoveFirst
            Do

                Call objRS1.Edit
                    objRS1!ean.Value = objRS1!produto.Value
                    objRS1!vendaultimo.Value = fncBuscaValor(objRS1!produto.Value, objRS2)
'                Me.data_atual.Value = produto.Column(3)
                Call objRS1.Update
                Call objRS1.MoveNext

            Loop Until objRS1.EOF

        End If
        
        Call objRS2.Close: Set objRS2 = Nothing
        
    End If

    Set objRS = Nothing

Função auxiliar

Código:

Private Function fncBuscaValor(produto, objRecordSet As DAO.Recordset)

    Call objRecordSet.MoveFirst
    
    Do
    
        If produto = objRecordSet!ean.Value Then
            fncBuscaValor = objRecordSet.Fields(1).Value
            Exit Function
        End If
        
        Call objRecordSet.MoveNext
        
    Loop Until objRecordSet.EOF
    
    fncBuscaValor = 0

End Function

Bom dia Damasceno!

Os códigos rodaram como eu queria, porém o campo de Data atual, que equivale a data de última compra do produto, não atualiza.(essa label confunde, vou trocar).
Já tentei entender o procedimento para ver se conseguia resolver sozinho, mas infelizmente ainda não possuo os conhecimentos necessários.
Você pode me ajudar novamente?

Abraço

Infelizmente não sei como ajudá-lo nessa parte. O evento "após atualizar" da caixa de combinação "produto" não tem essa instrução, assim como não possui uma quarta coluna (no caso - Column(3)). Nem a fonte do registro do subformulário possui um campo específico para receber este valor.

(essa label confunde, vou trocar)

então aguardo

Desculpe, acho que na correria de resolver o problema eu não havia preparado corretamente o arquivo.

Agora está na tabela da sub, e também nas consultas.
Deixei também pronto para a coluna 3

segue o anexo para analise.

Códigos utilizados...

Botão no formulário principal (ajuste na sql do objrs2, na interação com a função auxiliar fncBuscaValor, e adição do objrs1.data_ultimo)

Código:

Dim objRS1 As DAO.Recordset
    Dim objRS2 As DAO.Recordset
   
    Set objRS1 = Me!SUB_Det_lista_Vendas.Form.Recordset

    If objRS1.RecordCount > 0 Then
   
        Set objRS2 = CurrentDb.OpenRecordset("SELECT tblCad_Produto.ean, [Cs_precomedio-exclusivo-final-1].Último, [Cs_precomedio-exclusivo-final-1].ÚltimoDeMáxDedata " & _
                                            "FROM tblCad_Produto INNER JOIN [Cs_precomedio-exclusivo-final-1] ON tblCad_Produto.ean = [Cs_precomedio-exclusivo-final-1].ean;", , 4)

        If objRS2.RecordCount > 0 Then

            Call objRS1.MoveFirst
            Do

                Call objRS1.Edit
                    objRS1!ean.Value = objRS1!produto.Value
                    objRS1!vendaultimo.Value = fncBuscaValor(1, objRS1!produto.Value, objRS2)
                    objRS1!data_ultimo.Value = fncBuscaValor(2, objRS1!produto.Value, objRS2)
                Call objRS1.Update
                Call objRS1.MoveNext

            Loop Until objRS1.EOF

        End If
       
        Call objRS2.Close: Set objRS2 = Nothing
       
    End If

    Set objRS = Nothing

Função auxiliar (adição de um novo parâmetro chamado bytCampo)

Código:

Private Function fncBuscaValor(bytCampo As Byte, produto, objRecordSet As DAO.Recordset)

    Call objRecordSet.MoveFirst
   
    Do
   
        If produto = objRecordSet!ean.Value Then
            fncBuscaValor = objRecordSet.Fields(bytCampo).Value
            Exit Function
        End If
       
        Call objRecordSet.MoveNext
       
    Loop Until objRecordSet.EOF
   
    fncBuscaValor = 0

End Function

Boa tarde Damasceno!

Vou inserir o código no meu projeto e depois retorno para informar como ficou.
Agradeço muito pela sua ajuda.
Espero poder entender o código e aprender como assim como vocês.
Abraço

Bom dia Damasceno!

Funcionou perfeitamente.
Te agradeço muito pela ajuda.

Forte abraço

O fórum agradece o retorno. Sucesso.