Sair do form campo obrigatório

Olá

Preciso que ao sair do form seja sempre preenchido um campo, campo obrigatório, e se não preencher não grava.

tenho o seguinte código, mas não funcionou ao colocar ao sair . . .

Código:

Private Sub QuestionarioEfetuado_Exit(Cancel As Integer)
If IsNull(Me.ActiveControl) Then
MsgBox "Campo Obrigatório", vbQuestion, "Atenção Operador(a) "
DoCmd.CancelEvent
End If
End Sub

Obrigado

Um bem hajam... Saúde para todos.

fico de carona

Bom dia,

Vê se dá certo este:


If IsNull(nomedoseucampo) Or nomedoseucampo= "" Or nomedoseucampo.Value = 0 Then
MsgBox "nomedoseucampo é de preenchimento obrigatório.", vbOKOnly + vbCritical, "Atenção"
Me.nomedoseucampo.SetFocus
Exit Sub
End If

pensei que tinha um controle para todos para não precisar escrever todos, em uma só vez o sistema já identificar

Boa tarde

Poste só o formulário e a tabela da mensagem Nº 1

PS - Qual é a versão do seu Office ?

Olá

Por mim esta resolvido, pois a ideia era mesmo esta... Em relação a dúvida acrescida do amigo crysostomo, fico a tentar perceber se dou como resolvido ?

Obrigado

Pessoal

Aqui está minha contribuição antes de fechar o tópico:

Código:


'Código para colocar no botão fechar do formulário
'Ali onde tem Me.idcliente, verifica se não é nulo, se for nulo, não executa o código pois o formulário está em branco.

Private Sub btnFechar_Click()

If Not IsNull(Me.idcliente) Then ' Deve ser a primeira caixa de texto a ser preenchida ao adicionar um registro.
   If Not TestaCampos Then
      Exit Sub
   Else
      DoCmd.Close
   End If
Else
      DoCmd.Close
End If
End Sub


' O código abaixo vai na página de VBA do formulário.

Código:


'Com o formulário em modo design, clique numa caixa de texto e na aba [b]Outras[/b] da folha de propriedade e
'vá até a ultima propriedade  (Marca) em VBA (Tag) (Meu Office é o 2010).
'Podemos escolher qual caixa de texto é obrigado ser preenchida e para isso colocamos um (t) sem os parênteses, nessa propriedade, na
'folha de dados.
'O código abaixo irá verificar somente as caixas de texto que tem o  (t)  na Marca

Private Function TestaCampos() As Boolean
    Dim I As Integer
    Dim strMsg As String
    Dim strTitle As String
      
    TestaCampos = True

    'inicia o loop pelos controle do formulário
    'a contagem começa em zero (0) até  x-1
    For I = 0 To Me.Count - 1
        'se o controle tem a marca(tag) = t então
        If Me(I).Tag = "t" Then
            'se o campo está vazio então
            If IsNull(Me(I)) Or Me(I) = "" Then
                'emite mensagem acompanhado do nome do controle
                strMsg = "É obrigatório o preenchimento do campo '" & Me(I).Name & "'!"
                strTitle = "Campo em Branco"
                MsgBox strMsg, 48, strTitle
                'move o foco para o controle
                Me(I).SetFocus
                TestaCampos = False
                Exit Function
            End If
        End If
    Next I

End Function


Espero que gostem

{ }'s

Balem

Boa dica,

Vou fazer os meus teste aqui, essa eu não sabia ainda.

Obrigado.