[Resolvido]Suprimir o erro de registro não encontrado

utilizo o exemplo abaixo para ter opção de pegar mais de uma informação das colunas no Dlookup,


Private Sub Comando522_Click()

Dim Campos As Variant
Campos = Split(DLookup("[Desenho_ipdp] & ';' & [Atualizar]", "tbl_IPDP", "Desenho_ipdp=" & txtdesenho), ";")

MsgBox "Resultado: " & Campos(0) & " " & Campos(1)

End Sub

gostaria de sugestões para suprimir o erro para registro não encontrado, ou seja quero que minha msgbox retorne Zero ou vazio como resultado

ja usei NZ... on error resume next...

Olá,

Substitua o código atual por este:

Código:



On Error GoTo trata_erro

Dim sSQL        As String
Dim rs          As DAO.Recordset
Dim sResult     As String

    sResult = "Resultado: "
    
    sSQL = Empty
    sSQL = sSQL & " SELECT Desenho_ipdp, Atualizar FROM tbl_IPDP"
    sSQL = sSQL & " WHERE  Desenho_ipdp = " & txtdesenho & ""
    Set rs = CurrentDb.OpenRecordset(sSQL)
    
    If Not rs.EOF Then
        If Not IsNull(rs("Desenho_ipdp")) Then
            sResult = sResult & " Desenho: " & rs("Desenho_ipdp")
        End If
            
        If Not IsNull(rs("Atualizar")) Then
            sResult = sResult & " Atualizar: " & rs("Atualizar")
        End If
    Else
        sResult = "Registro não localizado."
    End If
    
    MsgBox "" & sResult & ""

    rs.Close
    Set rs = Nothing
    
    Exit Sub

trata_erro:
    MsgBox "Erro gerado: " & Err.Number & " - " & Err.Description & "", vbCritical, "Erro"
    Exit Sub

End Sub



VEja se é isso que precisa.

Boa sorte

[]'s

FIM

É bem elaborada nuu...

funciona muito bem, vou usar!

obrigado pela força

É =>Nois...rss
VAleu...o fórum agradece...
Abraços

Acrescentando, com dlookup seria

Código:

Private Sub Comando522_Click()

Dim Campos As Variant

Campos = Nz(DLookup("[Desenho_ipdp] & ';' & [Atualizar]", "tbl_IPDP", "Desenho_ipdp=" & txtdesenho), "")

if Campos = "" then
   MsgBox 0
else
   Campos = Split(Campos, ";")
   MsgBox "Resultado: " & Campos(0) & " " & Campos(1)
End if

End Sub