[Resolvido]filtrar um relatório

Olá.
Tenho a BD

Queria também aplicar um filtro para o relatório e vi este procedimento:
https://support.microsoft.com/pt-br/kb/145591

Mas não consigo fazer. Alguma ajuda?
Obrigado.

Olá Pedro, estou no telemóvel e não posso ver.
No entanto pode descrever o que pretnde (qual os limites para filtro)
Existem excelentes exemplos aqui no fórum, ja tentou uma "busca"?
Abraço

Já fiz uma busca, mas não achei.
Fiz o procedimento conforme este site:
https://support.microsoft.com/pt-br/kb/145591  (traduzido para português)

Use o AutoRelatório: Tabular Assistente para criar um novo relatório com base na tabela Customers. Feche e salve o relatório como rptCustomers.
Use o AutoFormulário: Tabular Assistente para criar um novo formulário baseado na tabela clientes. Feche e salve o formulário como frmFilterForm.
Abra frmFilterForm no modo de Design. Aumente o tamanho da seção de rodapé do formulário para que ele pode conter três botões de comando.
Criar um botão de comando no rodapé do formulário e defina suas propriedades da seguinte maneira:
      Name:     cmdOpenReport
      legenda:  Open Report
      OnClick:  [Event Procedure]


Defina o OnClick [procedimento de evento] da seguinte forma:

      Private Sub cmdOpenReport_Click()
        If Me.Filter = "" Then
          MsgBox "Apply a filter to the form first"
        Else
          DoCmd.OpenReport "rptCustomers", A_PREVIEW, , Me.Filter
        End If
      End Sub

Crie um segundo botão no rodapé do formulário e defina suas propriedades da seguinte maneira:
      Name:     cmdClearFilter
     legenda:  Clear Filter
      OnClick:  [Event Procedure]


Defina o OnClick [procedimento de evento] da seguinte forma:

      Private Sub cmdClearFilter_Click()
        Me.Filter = ""
      End Sub

Crie um terceiro botão no rodapé do formulário e defina suas propriedades da seguinte maneira:
      Name:     cmdClose
      legenda:  Close
      OnClick:  [Event Procedure]


Defina o OnClick [procedimento de evento] da seguinte forma:

      Private Sub cmdClose_Click()
        DoCmd.Close acForm, Me.Form.Name
      End Sub

Defina as seguintes propriedades para o formulário frmFilterForm:
      OnOpen:  [Event Procedure]
      OnClose: [Event Procedure]


Defina OnOpen e OnClose do formulário [procedimento de evento] da seguinte forma:

      Private Sub Form_Open(Cancel as Integer)
        Me.Filter = ""
      End Sub


      Private Sub Form_Close()
        DoCmd.Close acReport, "rptCustomers"
      End Sub

Alterne o formulário para o modo formulário.
Na barra de ferramentas, clique no botão Filtrar por formulário para definir um filtro e, em seguida, clique no botão Aplicar filtro para aplicar o filtro.
Clique no botão Abrir relatório no formulário. Um relatório deve aparecer com o mesmo filtro foi aplicado ao formulário.


Fiz os botões o resto não, não percebo ...

Qual a origem do relatório (tabela ou consulta) ?

Como pretende filtrar ( campo data, código artigo, armazem, conta cliente)?

Abraço

tabela (como no site)
campo especialidade
Ao escolher especialidade, apresentar um relatório de vários contactos com essa especialidade.
É possível?

Olá,
1) já tem o relatório feito?
2) Se sim qual é o nome?
3) Está no exemplo postado?
4) Pretende filtrar por especialidade, e o que deve mostras de que tabela.

Abraço

http://dl.dropboxusercontent.com/u/771097/base%20de%20dados_v2%20-%2032%2664bits%20%281%29_OLD.zip

Ao escolher especialidade, apresentar um relatório de vários contactos (tabela contactos, todos os campos) com essa especialidade.
Tenho o relatório Especialidades.

Abraço.

Olá Pedro
A estrutura (modelagem) das tabelas de dados é importante.
As relações também, veja:


Verifique as modificações na tabela de dados, segue o meu teste com reporte
lista_especialidades.zip
Abraço

Olá.
Queria era selecionar uma especialidade e aparecer só esses contactos.
Vi este exemplo mas não consigo aplicar:
https://support.microsoft.com/pt-br/kb/145591
Não sei como fazer filtro.

Olá Pedro, veja se atende:
lista_especialidades_reporte.zip
Abraço

Olá, como tenho várias especialidades para ver, pus caixa de combinação e dá-me debug:
Private Sub cmdReporte_Click()
   If Len(Me.cxcomboESPECIALIDADES & "") = 0 Then 'verifica se escolheu especialidade
       MsgBox "Escolha a especialidade", vbInformation
       Exit Sub
   Else
                             DoCmd.OpenReport "Relatório ESPECIALIDADES", A_PREVIEW, , "[ESPECIALIDADE] = " & Me.cxcomboESPECIALIDADES
   End If
End Sub

Run time error 3464: dados incorretos na expressão de critérios.
Sabe qual a expressão correta?

Estou a ler isto:
https://www.maximoaccess.com/t7356-resolvidobotao-abrir-relatorio-de-uma-caixa-de-combinacao

Private Sub cmdReporte_Click()
   If Len(Me.cxcomboESPECIALIDADES & "") = 0 Then 'verifica se escolheu especialidade
       MsgBox "Escolha a especialidade", vbInformation
       Exit Sub
   Else
       DoCmd.OpenReport "Relatório ESPECIALIDADES", A_PREVIEW, , "[CONTACTOS]![ESPECIALIDADE] = [Forms]![frmFilterForm]![cxcomboESPECIALIDADES]"
   End If
End Sub

Assim não aparece nada.
Pode ajudar?

Abraço

Olá Pedro, vamos manter o tópico coerente.
Nada de atalhos para outros tópicos.

1) O exemplo da mensagem nº 10 funcionou? é o que pretende?

2) Está com dificuldade em adaptar ao seu projecto?
Poste o que tem fica mais fácil para analisar

Abraço

Olá.
O exemplo da mensagem 10 funcionou.
Mas como tenho muitas especialidades a melhor opção era ter uma caixa de combinação, que ao selecionar a especialidade carpintaria,p.exemplo , me mostrasse todos os contactos de carpintaria.

mando a BD, tem o form filtro, mas dá debug.
Não sei como fazer o código certo....

Abraço

Olá, faltou a base de dados.
Abraço

ok

Faltava criar um relatório, para uma especialidade -> vários contactos.
Tentei mas não dá o efeito pretendido.

Um pitaco;

http://dl.dropboxusercontent.com/u/771097/base%20de%20dados_v3%20aplicar%20FILTRO_OLD.zip

Código:

Private Sub cxcomboESPECIALIDADES_AfterUpdate()
'coloca a especialidade na caixa oculta
'a especialidade está na coluna Nº1 da combobox, porque começa sempre por zero
    Me.txtEspecialidade.Value = Me.cxcomboESPECIALIDADES.Column(1)
End Sub

Private Sub ListaEspecialidade_AfterUpdate()
'coloca a especialidade na caixa oculta
'a especialidade está na coluna Nº1 da lista, porque começa sempre por zero
    Me.txtEspecialidade.Value = Me.ListaEspecialidade.Column(1)
End Sub

Private Sub cmdReporte_Click()
    If Len(Me.ListaEspecialidade & "") = 0 Then 'verifica se escolheu especialidade
        MsgBox "Escolha a especialidade", vbInformation
        Exit Sub
    Else
        DoCmd.OpenReport "Relatório ESPECIALIDADES", A_PREVIEW, , "[ESPECIALIDADE] = '" & Me.txtEspecialidade.Value & "'"
    End If
End Sub

Private Sub cmdReporte2_Click()
If Len(Me.cxcomboESPECIALIDADES & "") = 0 Then 'verifica se escolheu especialidade
        MsgBox "Escolha a especialidade", vbInformation
        Exit Sub
    Else
        DoCmd.OpenReport "Relatório ESPECIALIDADES", A_PREVIEW, , "[ESPECIALIDADE] = '" & Me.txtEspecialidade.Value & "'"
    End If
End Sub

Olá JPaulo,
Pitaco, sempre bem vindo.
Aguardamos retorno do colega.
Abraço a todos

Olá.
Fiz como o mestre J.Paulo apresentou e deu certo.
Muito agradecido.

solve

Olá Pedro, obrigado pelo retorno.
Os utilizadores do fórum agradecem.
Abraço a todos

Fico feliz.

Obrigado pelo retorno o forum agradece.