[Resolvido]Parcelas Semanais ou Quinzenais

Pessoal estou com uma dúvida estou criando um parcelamento automático conforme escolha através do campo o "Tipo de Parcelamento ", sei que tem varios topicos referente a mensais que já consegui resolver, porém pela minha falta de conhecimento não consegui arrumar o parcelamento de forma Semanal ou Quinzenal que seria basicamente isso o código:

Código:

If Me.TipodeParcelamento = "Semanal" Then
'Gera Alugueis a receber'
  Set db = CurrentDb() 'usa o banco atual
  Set rs = db.OpenRecordset("ReciboAcordos") 'Abre a tabela
  ProximaData = DateAdd("d", 1, [DataInicial]) 'recebe os meses a partir da data inicio

For I = 1 To Me.QtdeParcelas ' faz um loop
 rs.AddNew
 rs("CódAcordo") = Me.Código
 rs("Parcela") = I
 rs("QtdeParcelas") = Me.QtdeParcelas
 rs("Total") = TotalDivida
 rs("Situação") = ""
 rs("Usuario") = Me.Usuario
 rs("Vencimento") = DateAdd("d", 7 - 1, (ProximaData)) 'Faz calculo das datas de vencimento
 rs.Update

Next
rs.Close
db.Close
Me.ReciboAcordos_subformulário.Requery
End If

Porém este código não está funcionando corretamente, digamos que sejam 2 parcelas a serem geradas a partir da data inicial 01/05/19, na opção semanal, a lógica seria acrescentar + 7 dias a data inicial + 7 dias para próxima parcela gerada. o código nesta forma consegui gerar a 1 parcela para 7 dias mais.. ou seja tipo 08/05/19 (01/05 + 7 dias) porém as 2 parcela está saindo com a mesma data. Alguém saberia como me ajudar ?

Obs. Com base neste criarei ai o Quinzenal que trocaria o 7 dias por 15 no caso...

Desde já obrigado !

Olá Leonardo,

Foi a "olho", teste assim:

Código:

If Me.TipodeParcelamento = "Semanal" Then
    'Gera Alugueis a receber'
      Set db = CurrentDb() 'usa o banco atual
      Set rs = db.OpenRecordset("ReciboAcordos") 'Abre a tabela
      ProximaData = [DataInicial]  'inicaliza
   
    For I = 1 To Me.QtdeParcelas ' faz um loop
        ProximaData = DateAdd("d", 7, ProximaData) 'adiciona 7 dias
        rs.AddNew
        rs("CódAcordo") = Me.Código
        rs("Parcela") = I
        rs("QtdeParcelas") = Me.QtdeParcelas
        rs("Total") = TotalDivida
        rs("Situação") = ""
        rs("Usuario") = Me.Usuario
        rs("Vencimento") = ProximaData
        rs.Update
    Next
    rs.Close
    db.Close
    Me.ReciboAcordos_subformulário.Requery
End If


Abraço

Aeeeeee !! Fechou era isso mesmo ! Muito obrigado ! Abração !

Olá Leonardo Favale,

Obrigado pelo retorno, o fórum agradece.

Abraço