O seguro morreu de velho

E aí, já fez backup hoje?

Depois de um tempo criando e também lendo relatos (inclusive no fórum), compreendi que backups salvam vidas (risos). Como todo seguro, torcemos para nunca precisarmos e por não querer e até achar que não precisamos, achamos que é inútil fazer. Mas vai por mim, um dia um backup pode salvar horas, meses ou anos de trabalho/informação. Dito isto, é sempre bom ter um à mão.

O código/exemplo abaixo (que está em VBScript) não é voltado para arquivos quando em produção, mas para arquivos quando em desenvolvimento. Cansado de ficar no CONTROL+C e CONTROL+V enquanto desenvolvia, resolvi organizar a coisa. Ao clicar com o botão direto, basta optar por enviar para backup que uma cópia do arquivo zipada pelo WinRar será criada em uma pasta local chamada "bkp", com carimbo de data e hora (yyyymmdd hhnnss). O código pode ser acessado e modificado à vontade no bloco de notas ou numa ferramenta qualquer da sua preferência. E vale para qualquer arquivo (um arquivo de texto que está sendo digitado, uma base de dados que está sendo estruturada, um front-end montado etc etc)



Para habilitar, basta salvar o arquivo "Backup.vbs" na pasta SendTo (Windows+R -> Comando: shell:SendTo) e pronto.

Código:

Option Explicit

Dim strLocal
Dim strObjeto
Dim strDirWinRar
Dim objFso
Dim objShl
Dim booPastaLocal

booPastaLocal = True

set objFso = CreateObject("Scripting.FileSystemObject")

strDirWinRar = fncDirWinRAR

if strDirWinRar = "" then
    call msgbox("WinRar não detectado.")
    set objFso = nothing
    call WScript.Quit
else
    strDirWinRar = """" & strDirWinRar & """ a -ep1 -ibck"
end if

'if booPastaLocal then
    strLocal = left(WScript.Arguments(0),instrrev(WScript.Arguments(0),"\"))
'else
'    strLocal = ""
'end if

strObjeto = mid( WScript.Arguments(0), instrrev( WScript.Arguments(0), "\") + 1)

if instr(strObjeto, ".") > 0 then
    strObjeto = mid( strObjeto, 1, instrrev( strObjeto, ".") - 1)
elseif strObjeto = "bkp" then
    msgbox "Pasta proibida."
    call WScript.Quit
else
    strDirWinRar = strDirWinRar & " -r"
end if

if not objFso.folderexists(strLocal & "bkp") then call objFso.createfolder(strLocal & "bkp")
set objFso = nothing
strLocal = strLocal & "bkp\" & strObjeto & " - " & year(date)

select case len(month(date))
    case 1: strLocal = strLocal & "0" & month(date)
    case 2: strLocal = strLocal & month(date)
end select

select case len(day(date))
    case 1: strLocal = strLocal & "0" & day(date)
    case 2: strLocal = strLocal & day(date)
end select

strLocal = strLocal & " "

select case len(hour(time))
    case 1: strLocal = strLocal & "0" & hour(time)
    case 2: strLocal = strLocal & hour(time)
end select

select case len(minute(time))
    case 1: strLocal = strLocal & "0" & minute(time)
    case 2: strLocal = strLocal & minute(time)
end select

select case len(second(time))
    case 1: strLocal = strLocal & "0" & second(time)
    case 2: strLocal = strLocal & second(time)
end select

strLocal = strLocal & ".rar"
Set objShl = CreateObject("WScript.Shell")
Call objShl.Run(strDirWinRAR & " """ & strLocal & """ """ & WScript.Arguments(0) & """", 0, "false")
Set objShl = Nothing

Function fncDirWinRAR()
' ----------------------------------------------------------------
' Propósito : Retornar o caminho do arquivo WinRAR.exe
' ----------------------------------------------------------------

    Dim objWS
    Dim strResultado

    Set objWS = CreateObject("WScript.Shell")
    
    strResultado = objWS.RegRead("HKEY_LOCAL_MACHINE\" & _
                                 "SOFTWARE\" & _
                                 "Microsoft\" & _
                                 "Windows\" & _
                                 "CurrentVersion\" & _
                                 "App Paths\" & _
                                 "WinRAR.exe\Path") & "\WinRAR.exe"
    

    if not objFso.fileexists(strResultado) then strResultado = ""
    Set objWS = Nothing
    fncDirWinRAR = strResultado

End Function

Olá amigo Ivan Damasceno,

Parabéns, gostei

Criei mais uma entrada que copia sempre para a mesma pasta (que por sua vez está a sincronizar na nuvem)


Abraço

Showw, mestre Alvaro.
Obrigado por retornar e por compartilhar a adaptação.

Show de bola!

Damasceno, boa noite.

Quando você menciona que serve até para artigo de texto, significa que serve para o Word também?

Também serve para ser usado em um arquivo em Excel?

Abs.

Serve para qualquer tipo de arquivo que está sendo alterado constantemente e que temos a preocupação por não perder progresso e o controle das alterações.

É a simples automatização da ação de copiar um arquivo e salvá-lo em outro local.

Amigo, boa noite

Agora funcionou perfeitamente, obrigado.

Eu não gosto do WinRar e por isso eu uso o compactador nativo da Microsoft. Esse recurso funciona para esse compactador da Microsoft?

Obrigado.

Nunca usei o windows 11 para tentar adaptá-lo ao compactador nativo. Talvez num futuro próximo.

Boa tarde.

Esse compactador nativo do Windows 11 é o mesmo nativo do Windows 10.
Chama-se Pasta Compartada.

Pensei que fosse outro com mais funções.

Nesse caso, por se tratar do compactador nativo do windows, não vale apena adequá-lo ao exemplo. Mas é possivel e nada impede que você o faça pois no fórum tem exemplos de como usar o compactador do windows via código.

Na minha opinião não compensa usar o compactador nativo já que ele exibe o processo de compactação na tela e não tem função para executar o processo em segundo plano (na barra de notificação, por exemplo, como faz o exemplo deste tópico usando o winrar), ou bloquear com senha ou impedir edição diretamente no arquivo zipado.

Olá a todos,

Na minha opinião, quêm não gosta do WinRar (que é pago) faz mais sentido adaptar para o 7-zip (Open Source e gratuito).
Na empresa que trabalho é o que está disponivel para todos os utilizadores, e é o que eu pessoalmente utizo em casa.
Não tenho tido muito tempo, mas assim que me seja possível vou adaptar para o 7-Zip.

Damasceno, Grande exemplo, mais uma vez parabéns.

Muito bom obrigado por compartilhar com o fórum!!!