[Resolvido]Constant expression required.

Ola a todos,

Eu achei um codigo na internet que funciona com logout ou timer, que eu adaptei para fechar o access automaticamente de acordo com o valor que eu estipular.

O codigo funciona perfeitamente, mas seu eu quiser alterar o valor do tempo do timer eu so consigo mudando o codigo e para isso eu preciso ter acesso excluivo do arquivo. (o arquivo eh usado por varias pessoas na empresa)

O que eu queria fazer era que o valor do codigo fosse um valor de um campo em uma tabela, assim se eu quisesse mudar o timer eu mudaria sem problemas.

a linha do codigo que determina o tempo do timer eh:

Const IDLEMINUTES = 1
sendo que o 1 eh = hum minuto

Eu queria usar algo tipo:

Const IDLEMINUTES = me.out
onde out seria o campo do formulario ligado a tabela

so que qdo eu modifico o codigo eu receboa mensagem...

constant expression required...

Sera que alguem pode me ajudar?

Obrigado

Bom dia, Ioconte
Se puder disponibilizar em formato 2003

Ola,

Segue a versao 2003.

Obrigado

Bom dia, Ioconte

Utilize este módulo, em substituição do existente

Private Sub Form_Timer()
' running the IdleTimeDetected subroutine.

Dim TempoEspera As Integer
Static PrevControlName As String
Static PrevFormName As String
Static ExpiredTime

Dim ActiveFormName As String
Dim ActiveControlName As String
Dim ExpiredMinutes

On Error Resume Next

' Get the active form and control name.

TempoEspera = DLookup("Out", "TvX10out")
ActiveFormName = Screen.ActiveForm.Name
If Err Then
ActiveFormName = "No Active Form"
Err = 0
End If

ActiveControlName = Screen.ActiveControl.Name
If Err Then
ActiveControlName = "No Active Control"
Err = 0
End If

' Record the current active names and reset ExpiredTime if:
' 1. They have not been recorded yet (code is running
' for the first time).
' 2. The previous names are different than the current ones
' (the user has done something different during the timer
' interval).

If (PrevControlName = "") Or (PrevFormName = "") _
Or (ActiveFormName <> PrevFormName) _
Or (ActiveControlName <> PrevControlName) Then
PrevControlName = ActiveControlName
PrevFormName = ActiveFormName
ExpiredTime = 0
Else
' ...otherwise the user was idle during the time interval, so
' increment the total expired time.
ExpiredTime = ExpiredTime + Me.TimerInterval
End If

' Does the total expired time exceed the TempoEspera?
ExpiredMinutes = (ExpiredTime / 1000) / 60
If ExpiredMinutes >= TempoEspera Then


' ...if so, then reset the expired time to zero...
ExpiredTime = 0
' ...and call the IdleTimeDetected subroutine.
IdleTimeDetected ExpiredMinutes
End If
End Sub

Muito Obrigado Alexandre!

Funcionou perfeitamente!

Agradeco a ajuda.