[Resolvido]Dúvida - Distribuição de Valores

Caros, bom dia!

Estou com uma dúvida, possuo duas tabelas no Access uma com valores padrões já definidos EX:

Nome
Gustavo
Guilherme
João
José
..
..

Outra tabela onde irei copiar algumas informações do Excel e colar nela, EX:

Dados Numéricos
123
1234
321
215
1245
1218
1285
..
..

O que eu gostaria de fazer é o seguinte, sempre que eu colar essas informações dos dados numéricos, e apertar um botão ou automaticamente, seja realizada uma distribuição desses valores usando o nome das pessoas, EX:

Dados Numéricos | Nome
123 | Gustavo
1234 | Guilherme
321 | João
215 | José
1245 | Gustavo
1218 | Guilherme
1285 | João
.. | ..

Existe a possibilidade disso ser feito? Eu sou um leigo ainda para trabalhar com esse tipo de informação no Access.

Se alguém puder me auxiliar a realizar esse procedimento, ficárica muito grato!

Desde já agradeço!

Eu até consigo fazer essa "Distribuição" porém os registros de números ficam replicando em cada nome.

INSERT INTO tbl_DISTRIBUIÇÃO ( Numero, Nome, [Data] )

SELECT tbl_Numeros.Numero, tbl_Nomes.Nome, tbl_Numeros.[Data]

FROM tbl_Numeros, tbl_Nomes;


Quando realizo esse comando ele preenche a nova tabela "Distribuição" porém ele replica o número para cada nome, EX:

tbl_Numeros
123
456
789
321
654
987


tbl_Nomes
João
José
Pereira

Após a execução do código a tbl fica assim:

tbl_DISTRIBUIÇÃO
123|João
123|José
123|Pereira
456|João
456|José
456|Pereira



Mas o que eu queria que realmente acontecesse era:

tbl_DISTRIBUIÇÃO
123|João
456|José
789|Pereira
321|João
654|José
987|Pereira

Zuugg,

Por que, por meio de consulta não vejo como cruzar os registros e realizar a distribuição que você deseja, sem que a carga que vem do excel com os valores tenham já definido uma chave que representa a pessoa a quem o valor deve ser atribuído.

Uma possibilidade que vejo seria você elaborar uma lógica em VBA criando dois recordsets e para cada valor de um realizar o insert na tabela pegando um único valor do outro recordset.

Philipp, boa tarde!

Eis a questão, ainda não entendo muito bem a sintaxe de um recordset pra conseguir criar um que atenda minhas necessidades no momento.

Sabe dizer se existe alguma outra forma de realizar essa distribuição que estou querendo fazer?

Grato!

Zuug, somente se seu excel já vinhesse definido para cada valor a quem deve pertencer, pois assim, você poderia usar como chave primaria para atribuir extamente aquele valor ao seu respectivo usuário.

Tente postar seu BD ou ao menos as partes pertinentes dele para que alguém do fórum possa analisar e te sugerir uma solução.

Philipp,

Em anexo a base de dados que estou tentando realizar esses testes.

Ela quase que exatamente igual ao exemplo que disse acima.

Existem duas tabelas, uma já pré definida (Nomes) outra que vai receber informações do excel (Números) e uma terceira que seria pra fazer a distribuição desses números.

Bom dia,

Código:

Sub DistribuiNumeros()
    '''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
    '  código criado por Alexandre Neves, do Fórum MaximoAccess                                                '
    '''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
    Dim RstNumeros As DAO.Recordset, RstNomes As DAO.Recordset, RstDistribuicao As DAO.Recordset
   
    CurrentDb.Execute "DELETE * FROM tbl_Distribuição"
    Set RstNumeros = CurrentDb.OpenRecordset("tbl_Numeros")
    Set RstNomes = CurrentDb.OpenRecordset("tbl_Nomes")
    Set RstDistribuicao = CurrentDb.OpenRecordset("tbl_Distribuição")
    Do While Not RstNumeros.EOF
        RstDistribuicao.AddNew
        RstDistribuicao("Numeros") = RstNumeros("Numeros")
        RstDistribuicao("Nomes") = RstNomes("Nomes")
        RstDistribuicao("DataRegistro") = RstNumeros("DataRegistro")
        RstDistribuicao.Update
        RstNumeros.MoveNext
        RstNomes.MoveNext
        If RstNomes.EOF Then RstNomes.MoveFirst
    Loop
    Set RstNumeros = Nothing: Set RstNomes = Nothing: Set RstDistribuicao = Nothing
End Sub

Olá Alexandre, bom dia!

O código funcionou perfeitamente, muito obrigado pelo auxilio!

Consegui até entender melhor a sintaxe para utilização do recordset, vai me ajudar bastante!

Obrigado também Philipp, pois o código postado pelo Alexandre atende a lógica proposta por você quanto a criação dos VBA com os recordset.


Valeu mestres!